configure.in

fortran并行计算包

#! /bin/sh
dnl
dnl Caching is usually WRONG for systems with cross-mounted file systems
dnl (the cache file may correspond to a different system).  Since configure
dnl is not on a performance-critical path, go for robustness over speed.
dnl
define([AC_CACHE_LOAD], )dnl
define([AC_CACHE_SAVE], )dnl
dnl
dnl
AC_INIT()
AC_PREREQ(2.52)
AC_CONFIG_AUX_DIR([.])
 
AC_ARG_ENABLE(echo, 
[--enable-echo                      - Turn on strong echoing.  The default 
                                     is enable=no.] ,set -x)
 
AC_ARG_ENABLE(softerror, 
[--enable-softerror                 - Turn on soft error, i.e. instead of 
                                     issuing MSG_ERROR, MSG_WARN + exit 0 
                                     are used.  The default is enable=no.],
, enable_softerror=${slog2_enable_softerror:-no})

AC_ARG_ENABLE(swingcheck, 
[--enable-swingcheck                - Turn on the Swing checking code. 
                                     The default is enable=yes],
, enable_swingcheck=yes)
 
AC_ARG_ENABLE(jdb,
[--enable-jdb                       - Turn on the use of jdb to run the GUI.
                                     The default is enable=no],
,enable_jdb=no)

# Find the home directory if not specified
if test "X$srcdir" != "X." -a -s $srcdir/bin/jumpshot.in ; then
    top_srcdir_abs=$srcdir
else
    PAC_GETWD(top_srcdir_abs,./bin/jumpshot.in)
fi
 
if test -z "$top_srcdir_abs" ; then
    top_srcdir_abs=`pwd`
fi

if test ! -d "$top_srcdir_abs" ; then
    PAC_MSG_ERROR($enable_softerror, [*** $top_srcdir_abs is not a valid directory - cannot continue])
fi

AC_SUBST(top_srcdir_abs)

# Determine this package's name based on its directory name
changequote(,)dnl
tmpname="`echo $top_srcdir_abs | sed -e 's%\(.*\)/\([^/]*\)%\2%'`"
pkgname="`echo $tmpname | sed -e 'y%abcdefghijklmnopqrstuvwxyz/%ABCDEFGHIJKLMNOPQRSTUVWXYZ_%'`"
changequote([,])dnl
if test "x$pkgname" = "x" ; then
    pkgname="SLOG-2/Jumpshot-4"
fi
 
echo "Configuring $pkgname with $ac_configure_args"
#
# Cannot use JAVA_HOME here in this configure.in.
# Because JAVA_HOME is used in Blackdown's .java_wrapper in jdk117_v3
# Using JAVA_HOME here would mistakenly set some variable in .java_wrapper
# when .java_wrapper is invoked.  i.e. causes mysterious error in tests.
AC_ARG_WITH(java, 
[--with-java=JRE_TOPDIR             - The path of the top-level directory of 
                                     the Java installation.  If this option 
                                     or with-java2 is not given, configure
                                     will try to locate java for you.  Also, 
                                     with-java2 option overwrites the 
                                     with-java option to set JRE_TOPDIR.],
JRE_TOPDIR=$withval, JRE_TOPDIR="")
 
AC_ARG_WITH(java2, 
[--with-java2=JRE_TOPDIR            - The path of the top-level directory of 
                                     the Java installation.  If this option 
                                     or with-java is not given, configure will
                                     try to locate java for you.  Also, 
                                     with-java2 option overwrites the 
                                     with-java option to set JRE_TOPDIR.],
JRE_TOPDIR=$withval, )

AC_ARG_WITH(jvmflags, 
[--with-jvmflags=JVMFLAGS           - supply java virtual machine flags, e.g. 
                                     -Xms32m -Xmx256m.],
JVMFLAGS="$withval", )

AC_ARG_WITH(trace_libdir,
[--with-trace-libdir=TRACE_LIBDIR   - The path to the user-defined
                                     TRACE-API shared library, i.e.
                                     libTraceInput.so/TraceInput.dll.
                                     This option creates 2 extra utility 
                                     programs: traceprint and traceTOslog2.],
TRACE_LIBDIR=$withval, )

AC_ARG_WITH(trace_name,
[--with-trace-name=TRACE_NAME       - The new name prefix that replaces 
                                     the word trace in the utility programs
                                     traceprint and traceTOslog2.],
TRACE_NAME=$withval, )

dnl
dnl Set non-standard autoconf/GNU install directory variables, i.e. docdir 
dnl
AC_ARG_WITH(docdir,
[--with-docdir=dir                  - Specify the documentation directory.],,
with_docdir='${prefix}/doc')

#
# Set the defaults for directories that are not included in configure's
if test -n "$with_docdir" ; then
    docdir=$with_docdir
else
    docdir='${prefix}/doc'
fi
AC_SUBST(docdir)

# Fixup for make
MAKE=${MAKE:-make}
PAC_MAKE_IS_GNUMAKE
PAC_MAKE_IS_BSD44
PAC_MAKE_IS_OSF
PAC_MAKE_VPATH
# If we are relying on VPATH and no VPATH is set, then we must exit
if test ! -s bin/jumpshot.in -a -z "$VPATH" ; then
    AC_MSG_ERROR([No virtual MAKE path command found.
	You may need to set your make command.
	The GNU make (sometimes available as gnumake) can be used.])
fi
AC_SUBST(MAKE)

dnl checking for working INSTALL
AC_PROG_INSTALL
PAC_PROG_CHECK_INSTALL_WORKS
 
CPRP=cp
MKDIR=mkdir
RM="rm -f"
MV="mv -f"
AC_SUBST(RM)

# Check if --without-java is specified
if test "$JRE_TOPDIR" = "no" ; then
    PAC_MSG_ERROR($enable_softerror, [--without-java is specified, exit!])
fi

if test $enable_jdb = "yes" ; then
    pac_JVM=jdb
#   Assume jdb is working
    is_jvm_working=yes
else
    pac_JVM=java

    JAC_CHECK_CLASSPATH
    is_jvm_working=no
    if test "x$JRE_TOPDIR" != "x" ; then
        JVM="$JRE_TOPDIR/bin/$pac_JVM"
        AC_MSG_CHECKING([if $JVM exists])
        if test -x "$JVM" ; then
            AC_MSG_RESULT(yes)
            jac_java_working=yes
        else
            AC_MSG_RESULT(no)
            jac_java_working=no
        fi
dnl
        if test "$jac_java_working" = "yes" ; then
            AC_MSG_CHECKING([if $JVM runs simple java class])
            JAC_TRY_RUN([$JVM], [$JVMFLAGS],
                        [ac_javatest/simple.class],
                        [jac_java_working=yes], [jac_java_working=no])
            if test "$jac_java_working" = "yes" ; then
                AC_MSG_RESULT(yes)
            else
                AC_MSG_RESULT(no)
            fi
        fi
dnl
        if test "$jac_java_working" = "yes" ; then
            AC_MSG_CHECKING([if $JVM runs simple jar file])
            JAC_TRY_RUNJAR([$JVM], [$JVMFLAGS],
                           [ac_javatest/simple.jar],
                           [jac_java_working=yes], [jac_java_working=no])
            if test "$jac_java_working" = "yes" ; then
                AC_MSG_RESULT(yes)
            else
                AC_MSG_RESULT(no)
            fi
        fi
dnl
        if test "$jac_java_working" = "yes" \
             -a "$enable_swingcheck" = "yes" ; then
            AC_MSG_CHECKING([if $JVM runs simple Swing class])
            JAC_TRY_RUN([$JVM], [$JVMFLAGS],
                        [ac_javatest/simple_swing.class],
                        [jac_java_working=yes], [jac_java_working=no])
            if test "$jac_java_working" = "yes" ; then
                AC_MSG_RESULT(yes)
            else
                AC_MSG_RESULT(no)
            fi
        fi
dnl
        if test "$jac_java_working" = "yes" \
              -a "$enable_swingcheck" = "yes" ; then
            AC_MSG_CHECKING([if $JVM runs simple Swing jar file])
            JAC_TRY_RUNJAR([$JVM], [$JVMFLAGS],
                           [ac_javatest/simple_swing.jar],
                           [jac_java_working=yes], [jac_java_working=no])
            if test "$jac_java_working" = "yes" ; then
                AC_MSG_RESULT(yes)
            else
                AC_MSG_RESULT(no)
            fi
        fi
dnl
        if test "$jac_java_working" = "yes" ; then
            is_jvm_working=yes
        else
            is_jvm_working=no
        fi
    fi
#
    if test "$is_jvm_working" = "no" ; then
        JAC_PATH_PROG(JVM, $pac_JVM, [
            JAC_TRY_RUN([$JVM], [$JVMFLAGS],
                        [ac_javatest/simple.class],
                        [jac_java_working=yes], [jac_java_working=no])
            if test "$jac_java_working" = "yes" ; then
                AC_MSG_RESULT(yes)
                AC_MSG_CHECKING([if $JVM runs simple jar file])
                JAC_TRY_RUNJAR([$JVM], [$JVMFLAGS],
                               [ac_javatest/simple.jar],
                               [jac_java_working=yes], [jac_java_working=no])
            fi
            if test "$jac_java_working" = "yes" \
                 -a "$enable_swingcheck" = "yes" ; then
                AC_MSG_RESULT(yes)
                AC_MSG_CHECKING([if $JVM runs simple Swing class])
                JAC_TRY_RUN([$JVM], [$JVMFLAGS],
                            [ac_javatest/simple_swing.class],
                            [jac_java_working=yes], [jac_java_working=no])
            fi
            if test "$jac_java_working" = "yes" \
                 -a "$enable_swingcheck" = "yes" ; then
                AC_MSG_RESULT(yes)
                AC_MSG_CHECKING([if $JVM runs simple Swing jar file])
                JAC_TRY_RUNJAR([$JVM], [$JVMFLAGS],
                               [ac_javatest/simple_swing.jar],
                               [jac_java_working=yes], [jac_java_working=no])
            fi
            if test "$jac_java_working" = "yes" ; then
                jac_prog_working=yes
            else
                jac_prog_working=no
            fi
        ])
#       If JVM still hasn't been found, we need to abort!
        if test "x$JVM" = "x" ; then
            PAC_MSG_ERROR($enable_softerror,
                          [No Java Virtual Machine can be found anywhere!])
        fi
        is_jvm_working=yes
    fi
fi

# CHECK the version of Java used 
# Filter out the version of JDK that causes problem
if test "$enable_jdb" = "no" ; then
    AC_MSG_CHECKING(for Java version)
    VERSION=`$JVM -fullversion 2>&1`
    case "$VERSION" in