5282lite.ld

来自「opentcp_mcf5282原代码」· LD 代码 · 共 82 行

/* 5282LITE.ld - M5282LITE Linker Command File */

MEMORY 
{
	sdram		(RWX)	: ORIGIN = 0x00000000, LENGTH = 0x01000000
	vector_ram	(RWX)	: ORIGIN = 0x00000000, LENGTH = 0x00000400
	user		(RWX)	: ORIGIN = 0x00020000, LENGTH = 0x00FE0000
	sram		(RWX)	: ORIGIN = 0x20000000, LENGTH = 0x00010000
	ext_sram	(RWX)	: ORIGIN = 0x30000000, LENGTH = 0x00080000
	ipsbar		(RWX)	: ORIGIN = 0x40000000, LENGTH = 0x40000000
	flash		(RWX)	: ORIGIN = 0xF0000000, LENGTH = 0x00080000
	ext_flash	(RWX)	: ORIGIN = 0xFFE00000, LENGTH = 0x00200000
}

SECTIONS
{
	.sdram		: {} > sdram
	.vector_ram	: {} > vector_ram
	.ipsbar		: {} > ipsbar
	.sram		: {} > sram
	.ext_sram	: {} > ext_sram
	.flash		: {} > flash
	.ext_flash	: {} > ext_flash

	.text :
	{
		vectors.o (.text)
		*(.text)
		*(.rdata)
		*(.rodata)
	} > user

	.data :
	{
		__DATA_ROM = .;
		__DATA_RAM = .;
		*(.data)
		*(.sdata)
		__DATA_END = .;
	} > user

	.bss :
	{
		__BSS_START = .;
		*(.bss)
		*(.sbss)
		__BSS_END = .;
		__HEAP_START	= .;
		.				= . + (32*1024);
		__HEAP_END		= .;
		__SP_END		= .;
		.				= . + (4*1024);
		__SP_INIT		= .;
		___SP_INIT		= .;
	} > user
}


/* 
 * Memory Map information for use in source files
 */
__IPSBAR			= ADDR(.ipsbar);
___IPSBAR			= __IPSBAR;
__VECTOR_RAM		= ADDR(.vector_ram);

__SDRAM				= ADDR(.sdram);
__SDRAM_SIZE		= SIZEOF(.sdram);

__SRAM				= ADDR(.sram);
__SRAM_SIZE			= SIZEOF(.sram);
___SRAM				= __SRAM;

__EXT_SRAM			= ADDR(.ext_sram);
__EXT_SRAM_SIZE		= SIZEOF(.ext_sram);

__FLASH				= ADDR(.flash);
__FLASH_SIZE		= SIZEOF(.flash);
___FLASH			= __FLASH;

__EXT_FLASH			= ADDR(.ext_flash);
__EXT_FLASH_SIZE	= SIZEOF(.ext_flash);