linksymbian.bat

来自「能够在linux系统上实现MP4的源代码」· Batch 代码 · 共 54 行

@echo off

set path=%IM_SYMB_SHARED%\gcc\bin;%IM_SYMB_SHARED%\Tools

if "%1"=="S60" set L=%IM_SYMB_S60_SDK%
if "%1"=="S80" set L=%IM_SYMB_S80_SDK%
if "%1"=="S90" set L=%IM_SYMB_S90_SDK%
if "%1"=="UIQ" set L=%IM_SYMB_UIQ_SDK%

set L=%L%\Release\armi\urel
set APP_ID=10202a2f
set EPOCLIBS=%L%\EDLL.LIB %L%\EDLLSTUB.LIB %L%\EGCC.LIB %L%\euser.lib %L%\efsrv.lib %L%\Cone.lib %L%\Msgs.lib
set L=_Release_%1\
set OBJS=%L%CodecAPI.o %L%DynamicArmCode.o %L%IDCT.o %L%Mcomp.o %L%Memory.o %L%mp4_decode.o %L%SoftIdct.o

set LDARGS=-s -e _E32Dll %L%tmp.exp --dll -o %L%tmp.dll %OBJS% %EPOCLIBS%
set DLLTARGS=-m arm_interwork --def Codec_ARM.def --dllname MyGame[%APP_ID%].dll --output-exp %L%tmp.exp

rem// generate 1st pass .exp file
dlltool %DLLTARGS%
if errorlevel 1 goto fail

rem// link 1st pass
ld %LDARGS% -u _E32Dll --base-file %L%tmp.bas
if errorlevel 1 goto fail

rem// generate 2nd pass .exp file
dlltool %DLLTARGS% --base-file %L%tmp.bas
if errorlevel 1 goto fail

rem// link 2nd pass
ld %LDARGS% -u _E32Dll -Map %L%app.map
if errorlevel 1 goto fail

rem// process by petran
petran %L%tmp.dll %L%CoreMp4.dll -nocall -uid1 0x10000079 -uid2 0x100039ce -uid3 0x%APP_ID% >nul
if errorlevel 1 goto fail

rem// finalize - make .sis packaged file

makesis Symbian\CoreMp4_%1.pkg >nul
if errorlevel 1 goto fail

echo SIS file done


goto end

:fail
@echo Failed!

:end