rei_22.pas

Delphi经典游戏程序设计40例.pdf 中国铁道出版社出版 含源码

unit Rei_22;

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  ExtCtrls, Menus;

type
  //  定义角色的记录类型
  TPatDt = record
    Used: Byte;
    Sban: Byte;
    Xpos: Integer;
    Ypos: Integer;
    Smov: Byte;
    Scon: Byte;
    Dtim: Byte;
    DlyS: array[1..40] of Byte;
    DlyX: array[1..40] of Integer;
    DlyY: array[1..40] of Integer;
  end;

  TRei40_22 = class(TForm)
    Timer1: TTimer;
    MainMenu1: TMainMenu;
    procedure FormCreate(Sender: TObject);
    procedure Timer1Timer(Sender: TObject);
    procedure FormClose(Sender: TObject; var Action: TCloseAction);
  private
    { Private 定义 }
    procedure MkDpat(Bmap: TBitmap; ZX: Byte);
    procedure ChMove;
    procedure ChrDZ(Znum, Xsiz, Ysiz: Byte; Dpon: Word;
      X1, Y1: Integer; Bmap: TBitmap);
    procedure PatDZ(Pnum: Byte; X1, Y1: Integer; Bmap, Zmap: TBitmap);
  public
    { Public 定义 }
  end;

const
  Yoko = 37;           //显示的横向图案数
  Tate = 27;           //显示的纵向图案数
  DYoko = Yoko * 16;   //显示的横向点数
  DTate = Tate * 16;   //显示的纵向点数
  PtFull = 16;         //全面显示（不要重叠显示）的图案数
  MaxSp = 8;           //本次使用的复合图样总数
  Mdot = 3;            //移动单位（点数）

var
  Rei40_22: TRei40_22;
  //  定义载入用、去除模版用、背景用、粉刷用与残留影像用的点阵图
  Load_Bmap: TBitmap;
  Xpat_Bmap: TBitmap;
  Back_Bmap: TBitmap;
  Make_Bmap: TBitmap;
  Bpat_Bmap: TBitmap;
  Z1_Bmap: TBitmap;
  Z2_Bmap: TBitmap;
  Z3_Bmap: TBitmap;
  Z4_Bmap: TBitmap;
  Z5_Bmap: TBitmap;
  //  定义各种变量（Byte类型、Word类型、 TRect 类型、数组类型）
  PX, PY: Byte;
  Sc: Word;
  Rect_L, Rect_B, Rect_M, Rect_D: TRect;
  ChPon: array[0..3] of TPatDt;
  //  复合图样的数组
  SpSiz: array[0..(MaxSp * 2 - 1)] of Byte = (
    1,1, 2,2, 2,2, 2,3, 1,1, 1,1, 1,1, 1,1
  );
  SpPon: array[0..(MaxSp - 1)] of Word;
  SpDat: array[0..18] of Byte = (
    0,
    28, 29, 30, 31,
    32, 33, 48, 49,
    64, 65, 80, 81, 96, 97,
    19, 20, 21, 22
   );

implementation

{$R *.DFM}

procedure TRei40_22.FormCreate(Sender: TObject);
var
  //  定义局部变量
  X, Y, n, Cn: Byte;
begin
  //  设定Form属性
  Rei40_22.Height := 480;
  Rei40_22.Width := 640;
  //  载入图案
  Load_Bmap := TBitmap.Create;
  Load_Bmap.LoadFromFile(GetCurrentDir + '\ExData\Pat_Sample.bmp');
  //  零件贴图指标数组的初始设定
  Sc := 0;
  for n := 0 to (MaxSp - 1) do
  begin
    SpPon[n] := Sc;
    Sc := Sc + SpSiz[n * 2] * SpSiz[n * 2 + 1];
  end;
  //  储存去除用点阵图
  Xpat_Bmap := TBitmap.Create;
  Xpat_Bmap.Width := 256;
  Xpat_Bmap.Height := 256;
  //  制作去除用点阵图
  Rect_L := Rect(0, 0, 256, 256);
  Xpat_Bmap.Canvas.CopyMode := cmSrcCopy;
  Xpat_Bmap.Canvas.CopyRect(Rect_L, Load_Bmap.Canvas, Rect_L);
  Xpat_Bmap.Canvas.Brush.Color := clBlack;
  Xpat_Bmap.Canvas.BrushCopy(Rect_L, Load_Bmap, Rect_L, clWhite);
  Xpat_Bmap.Canvas.CopyMode := cmMergePaint;
  Xpat_Bmap.Canvas.CopyRect(Rect_L, Load_Bmap.Canvas, Rect_L);
  //  储存粉刷用点阵图
  Bpat_Bmap := TBitmap.Create;
  Bpat_Bmap.Width := 8;
  Bpat_Bmap.Height := 8;
  //  储存残留影像用点阵图并制作残留影像图像
  Z1_Bmap := TBitmap.Create;
  Z2_Bmap := TBitmap.Create;
  Z3_Bmap := TBitmap.Create;
  Z4_Bmap := TBitmap.Create;
  Z5_Bmap := TBitmap.Create;
  MkDpat(Z1_Bmap, 3);
  MkDpat(Z2_Bmap, 6);
  MkDpat(Z3_Bmap, 8);
  MkDpat(Z4_Bmap, 10);
  MkDpat(Z5_Bmap, 12);
  //  储存背景用点阵图并制作残留影像
  Back_Bmap := TBitmap.Create;
  Back_Bmap.Width := DYoko;
  Back_Bmap.Height := DTate;
  for X := 0 to Yoko - 1 do
    for Y := 0 to Tate - 1 do
    begin
      if (X <= Yoko div 2) and (Y <= Tate div 2) then
        n := 1
      else if (X > Yoko div 2) and (Y <= Tate div 2) then
        n := 7
      else if (X <= Yoko div 2) and (Y > Tate div 2) then
        n := 13
      else
        n := 15;
      PatDZ(n, X * 16, Y * 16, Back_Bmap, Load_Bmap);
    end;
  //  储存绘制用点阵图
  Make_Bmap := TBitmap.Create;
  Make_Bmap.Width := DYoko + 32;
  Make_Bmap.Height := DTate + 32;
  //  角色用数组的初始设定
  ChPon[0].Used := 1;
  ChPon[0].Sban := 1;
  ChPon[0].Xpos := 50;
  ChPon[0].Ypos := 50;
  ChPon[0].Smov := 1;
  ChPon[0].Scon := 0;
  ChPon[0].Dtim := 3;
  ChPon[1].Used := 1;
  ChPon[1].Sban := 2;
  ChPon[1].Xpos := 510;
  ChPon[1].Ypos := 125;
  ChPon[1].Smov := 3;
  ChPon[1].Scon := 0;
  ChPon[1].Dtim := 4;
  ChPon[2].Used := 1;
  ChPon[2].Sban := 3;
  ChPon[2].Xpos := 395;
  ChPon[2].Ypos := 350;
  ChPon[2].Smov := 5;
  ChPon[2].Scon := 0;
  ChPon[2].Dtim := 8;
  ChPon[3].Used := 1;
  ChPon[3].Sban := 4;
  ChPon[3].Xpos := 50;
  ChPon[3].Ypos := 275;
  ChPon[3].Smov := 7;
  ChPon[3].Scon := 0;
  ChPon[3].Dtim := 2;
  for Cn := 0 to 3 do
    for n := 1 to 40 do
      with ChPon[Cn] do
      begin
        DlyS[n] := Sban;
        DlyX[n] := Xpos;
        DlyY[n] := Ypos;
      end;
end;

procedure TRei40_22.Timer1Timer(Sender: TObject);
var
  //  定义局部变量
  n, Cn: Byte;
begin
  //  角色的移动处理作业与在Make_Bmap上的绘制作业
  ChMove;
  Make_Bmap.Canvas.CopyMode := cmSrcCopy;
  Rect_B := Rect(0, 0, DYoko, DTate);
  Rect_M := Rect(16, 16, DYoko + 16, DTate + 16);
  Make_Bmap.Canvas.CopyRect(Rect_M, Back_Bmap.Canvas, Rect_B);
  for Cn := 0 to 3 do
    with ChPon[Cn] do
      if (Used <> 0) and (Sban <> 0) then
      begin
        if Dtim <> 0 then
          for n := 5 downto 1 do
            if (DlyX[n * Dtim] <> Xpos) or (DlyY[n * Dtim] <> Ypos) then
              ChrDZ(n, SpSiz[Sban * 2], SpSiz[Sban * 2 + 1],
                SpPon[DlyS[n * Dtim]], DlyX[n * Dtim] + 16,
                DlyY[n * Dtim] + 16, Make_Bmap);
        ChrDZ(0, SpSiz[Sban * 2], SpSiz[Sban * 2 + 1],
          SpPon[Sban], Xpos + 16, Ypos + 16, Make_Bmap);
      end;
  //  将图像由Make_Bmap显示至Form上
  Rei40_22.Canvas.CopyMode := cmSrcCopy;
  Rect_D := Rect(0, 0, DYoko, DTate);
  Rei40_22.Canvas.CopyRect(Rect_D, Make_Bmap.Canvas, Rect_M);
end;

procedure TRei40_22.ChMove;
var
  //  定义局部变量
  n, Cn: Byte;
begin
  //  角色与残留影像的移动
  for Cn := 0 to 3 do
    if ChPon[Cn].Used = 1 then
    begin
      with ChPon[Cn] do
      begin
        for n := 39 downto 1 do
        begin
          DlyS[n + 1] := DlyS[n];
          DlyX[n + 1] := DlyX[n];
          DlyY[n + 1] := DlyY[n];
        end;
        DlyS[1] := Sban;
        DlyX[1] := Xpos;
        DlyY[1] := Ypos;
        if Cn = 3 then
          Sban := (Sban + 1) and 3 + 4;
        if Scon <> 0 then
          Scon := Scon - 1
        else begin
          case Smov of
            1: if Xpos < 395 then
                Xpos := Xpos + Mdot
              else begin
                Smov := 2;
                Xpos := Xpos + Mdot;
                Ypos := Ypos + Mdot;
              end;
            2: if Ypos < 125 then
              begin
                Xpos := Xpos + Mdot;
                Ypos := Ypos + Mdot;
              end
              else begin
                Smov := 3;
                Ypos := Ypos + Mdot;
              end;
            3: if Ypos < 275 then
                Ypos := Ypos + Mdot
              else begin
                Smov := 4;
                Xpos := Xpos - Mdot;
                Ypos := Ypos + Mdot;
              end;
            4: if Ypos < 350 then
              begin
                Xpos := Xpos - Mdot;
                Ypos := Ypos + Mdot;
              end
              else begin
                Smov := 5;
                Xpos := Xpos - Mdot;
              end;
            5: if Xpos > 165 then
                Xpos := Xpos - Mdot
              else begin
                Smov := 6;
                Xpos := Xpos - Mdot;
                Ypos := Ypos - Mdot;
              end;
            6: if Ypos > 275 then
              begin
                Xpos := Xpos - Mdot;
                Ypos := Ypos - Mdot;
              end
              else begin
                Smov := 7;
                Ypos := Ypos - Mdot;
              end;
            7: if Ypos > 125 then
                Ypos := Ypos - Mdot
              else begin
                Smov := 8;
                Xpos := Xpos + Mdot;
                Ypos := Ypos - Mdot;
              end;
            8: if Ypos > 50 then
              begin
                Xpos := Xpos + Mdot;
                Ypos := Ypos - Mdot;
              end
              else begin
                Smov := 1;
                Scon := 30;
              end;
          end;
        end;
      end;
    end;
end;

procedure TRei40_22.MkDpat(Bmap: TBitmap; ZX: Byte);
begin
  //  制作残留影像用的图案
  Bmap.Width := 256;
  Bmap.Height := 256;
  Bpat_Bmap.Canvas.CopyMode := cmSrcCopy;
  Rect_L := Rect(ZX * 8 + 32, 64, ZX * 8 + 40, 72);
  Rect_D := Rect(0, 0, 8, 8);
  Bpat_Bmap.Canvas.CopyRect(Rect_D, Load_Bmap.Canvas, Rect_L);
  Bmap.Canvas.Brush.Bitmap := Bpat_Bmap;
  Bmap.Canvas.CopyMode := cmMergeCopy;
  Rect_L := Rect(0, 0, 256, 256);
  Bmap.Canvas.CopyRect(Rect_L, Load_Bmap.Canvas, Rect_L);
  Bmap.Canvas.CopyMode := cmMergePaint;
  Bmap.Canvas.CopyRect(Rect_L, Xpat_Bmap.Canvas, Rect_L);
  Bmap.Canvas.Brush.Bitmap := Nil;
end;

procedure TRei40_22.ChrDZ(Znum, Xsiz, Ysiz: Byte; Dpon: Word;
  X1, Y1: Integer; Bmap: TBitmap);
var
  //  定义局部变量
  CDX, CDY: Byte;
  Z_Bmap: TBitmap;
begin
  //  将指定角色绘制至指定点阵图上（重叠显示、残留影像适用）
  case Znum of
    0: Z_Bmap := Load_Bmap;
    1: Z_Bmap := Z1_Bmap;
    2: Z_Bmap := Z2_Bmap;
    3: Z_Bmap := Z3_Bmap;
    4: Z_Bmap := Z4_Bmap;
    5: Z_Bmap := Z5_Bmap;
  end;
  for CDY := 0 to (Ysiz - 1) do
    for CDX := 0 to (Xsiz - 1) do
    begin
      if (X1 + CDX * 16 >= 0) and (X1 + CDX * 16 <= DYoko + 16) and
        (Y1 + CDY * 16 >= 0) and (Y1 + CDY * 16 <= DTate + 16) then
          PatDZ(SpDat[Dpon], X1 + CDX * 16, Y1 + CDY * 16, Bmap, Z_Bmap);
      Dpon := Dpon + 1;
    end;
end;

procedure TRei40_22.PatDZ(Pnum: Byte; X1, Y1: Integer; Bmap, Zmap: TBitmap);
begin
  //  将指定图案绘制至指定点阵图上（重叠显示、残留影像适用）
  PX := (Pnum and $F) * 16;
  PY := Pnum and $F0;
  Rect_L := Rect(PX, PY, PX + 16, PY + 16);
  Rect_D := Rect(X1, Y1, X1 + 16, Y1 + 16);
  if Pnum <> 0 then
    if Pnum >= PtFull then
    begin
      Bmap.Canvas.CopyMode := cmSrcPaint;
      Bmap.Canvas.CopyRect(Rect_D, Xpat_Bmap.Canvas, Rect_L);
      Bmap.Canvas.CopyMode := cmSrcAnd;
      Bmap.Canvas.CopyRect(Rect_D, Zmap.Canvas, Rect_L);
    end
    else begin
      Bmap.Canvas.CopyMode := cmSrcCopy;
      Bmap.Canvas.CopyRect(Rect_D, Zmap.Canvas, Rect_L);
    end;
end;

procedure TRei40_22.FormClose(Sender: TObject; var Action: TCloseAction);
begin
  //  将载入用、去除用、背景用与绘制用的点阵图释放掉
  Load_Bmap.Free;
  Xpat_Bmap.Free;
  Back_Bmap.Free;
  Make_Bmap.Free;
  Bpat_Bmap.Free;
  Z1_Bmap.Free;
  Z2_Bmap.Free;
  Z3_Bmap.Free;
  Z4_Bmap.Free;
  Z5_Bmap.Free;
end;

end.