queens2.pl

来自「PRl教学程序 PRl教学程序 PRl教学程序」· PL 代码 · 共 48 行

PL
48 行
字号
%   File   : queens.pl
%   Author : Neng-Fa ZHOU
%   Date   : 1998
%   Purpose: A linear-constraint program for solving the N-queens problem 


go:-
    write('N=?'),read(N),queens(N).

queens(N):-
    statistics(runtime,[Start|_]),
    once(N),
    statistics(runtime,[End|_]),
    T is End-Start,
    write('%execution time ='), write(T), write(' milliseconds'),nl.

once(N):-
    make_list(N,List),
    domain(List,1,N),
    make_list12(List,0,List1,List2),
    constrain_queens(List,List1,List2),
    labeling_ff(List),
    write(List).

make_list(0,[]):-!.
make_list(N,[_|Rest]):-
    N1 is N-1,
    make_list(N1,Rest).

make_list12([],I,List1,List2):-List1=[],List2=[].
make_list12([Q|Qs],I,List1,List2):-
    List1=[Q1|Rest1],
    List2=[Q2|Rest2],
    newDomainVar(Q1),
    newDomainVar(Q2),
    Q1 #= Q+I,
    Q2 #= Q-I,
    I1 is I+1,
    make_list12(Qs,I1,Rest1,Rest2).

newDomainVar(X):-
    domain(X,-9999,99999).

constrain_queens(List,List1,List2):-
    all_different(List),
    all_different(List1),
    all_different(List2).

⌨️ 快捷键说明

复制代码Ctrl + C
搜索代码Ctrl + F
全屏模式F11
增大字号Ctrl + =
减小字号Ctrl + -
显示快捷键?