2402ci.asm

包含93C46存储数字

;********************************************************************************
;* 24C04读写 3位数码管显示显示开机的次数，断电保持功能                          *
;硬件连接：数码管数据P0,数码管控制P2,24C02控制SDAP3.7 SCLP3.6   		*                 
;开机， 数码管显示开机次数数字, 断电重新开机,数字保持，加一      		*
;********************************************************************************
;*  日期:  2007-3-25                                                            *
;*  版本:  3.0                                                                  *
;*  作者:  深圳学林电子有限公司     专业8051单片机教学站                        *
;*  邮箱: [e-mail]                                                       *
;*  网站： http://www.51c51.com     http://www.8951.com    更多例程请登陆网站   *
;********************************************************************************
;*  硬件：此程序在本公司xlisp系列单片机实验仪运行通过                           *
;********************************************************************************
;* 【版权】 Copyright(C)深圳学林电子有限公司 www.51c51.com  All Rights Reserved *
;* 【声明】 此程序仅用于学习与参考，引用请注明版权和作者信息！                  *
;********************************************************************************
         SDA  BIT  P3.7        ;定义24C02数据线
         SCL  BIT  P3.6       ;定义24C02时钟线
         TEMP      EQU  30H
         DISSTART  EQU  40H    ;显示单元首地址
         LED_DATA  EQU  P0     ;数码管数据口定义
;-----------------------------------------------------
         ORG 0000H
         AJMP MAIN
         ORG 0030H
;-----------------------------------------------------
MAIN:
         MOV  SP,#60H
         MOV  P0,#0FFH
         MOV  P2,#0FFH
         MOV  TEMP,#00H
         ACALL  READ_DATA
         CALL  CONVT
         CALL  PLAY
         MOV  A,TEMP
         INC  A
         ACALL  WRITE_DATA
M_LOOP:
         MOV  A,TEMP
         CALL  CONVT
         CALL  PLAY
         JMP  M_LOOP
;-----------------------------------------------------
;写1字节数据子程序
;-----------------------------------------------------
WRITE_DATA:
         MOV R0,#00h         ;数据写入首地址
         MOV B,A
         LCALL WRITE_BYTE    ;将计数值写入24C02
         RET
;-----------------------------------------------------
;读1字节数据子程序
;-----------------------------------------------------
READ_DATA:
         MOV R0,#00H         ;读取的首地址
         LCALL READ_BYTE     ;读EEPROM
         CALL STOP
         MOV TEMP,A
         RET
;---------------------------------------------------------
;代码变换 (HEX TO BCD)
;---------------------------------------------------------
CONVT:
         MOV  A,TEMP
         MOV  B,#100
         DIV  AB
         MOV  DISSTART+2,A     ;百位存放在DISSTART＋2
         MOV  A,#10
         XCH  A,B
         DIV  AB
         MOV  DISSTART+1,A     ;十位存放在DISSTART＋1
         MOV  DISSTART,B       ;个位存放在DISSTART
         MOV  A,DISSTART+2
         JNZ  CONVT_END
         MOV  DISSTART+2,#0AH   ;百位为0，关闭百位显示
         MOV  A,DISSTART+1
         JNZ  CONVT_END
         MOV  DISSTART+1,#0AH
CONVT_END:
         RET
 ;----------------------------------------------------
 ;写操作子程序
 ;输入参数: R0---要写入的地址，B---要写入的数据
 ;----------------------------------------------------
WRITE_BYTE:
         CALL START
         MOV A,#0A0H
         CALL  SENDBYTE
         CALL  WAITACK
         MOV A,R0
         CALL SENDBYTE
         CALL  WAITACK
         MOV A,B
         CALL SENDBYTE
         CALL  WAITACK
         CALL STOP
         RET
 ;----------------------------------------------------
 ;读操作子程序
 ;输入参数：R0---要读的字节地址,
 ;输出参数: A---结果
 ;----------------------------------------------------
READ_BYTE:
         CALL START
         MOV A,#0A0H
         CALL SENDBYTE
         CALL  WAITACK
         MOV A,R0
         CALL SENDBYTE
         CALL  WAITACK
         CALL START
         MOV A,#0A1H
         CALL SENDBYTE
         CALL  WAITACK
         CALL  RCVBYTE
         RET
;-----------------------------------------------------
;从IIC总线上接收一个字节数据
;出口参数：A---接收数据存放在A中
;-----------------------------------------------------
RCVBYTE:
         MOV R7,#08        ;一个字节共接收8位数据
         CLR  A
         SETB  SDA         ;释放SDA数据线
R_BYTE:
         CLR  SCL
         NOP
         NOP
         NOP
         NOP
         SETB SCL          ;启动一个时钟周期，读总线
         NOP
         NOP
         NOP
         NOP
         MOV C,SDA         ;将SDA状态读入C
         RLC A             ;结果移入Ａ
         SETB  SDA         ;释放SDA数据线
         DJNZ R7,R_BYTE    ;判断8位数据是否接收完全？
         RET
;----------------------------------------------------
;向IIC总线发送一个字节数据
;入口参数：A---待发送数据存放在A中
;----------------------------------------------------
SENDBYTE:
         MOV R7,#08
S_BYTE:
         RLC A
         MOV SDA,C
         SETB SCL
         NOP
         NOP
         NOP
         NOP
         CLR SCL
         DJNZ R7,S_BYTE   ;8位发送完毕?
         RET
;-----------------------------------------------------
;等待应答信号
;等待从机返回一个响应信号
;-----------------------------------------------------
WAITACK:
         CLR  SCL
         SETB SDA       ;释放SDA信号线
         NOP
         NOP
         SETB SCL
         NOP
         NOP
         NOP
         MOV C,SDA
         JC  WAITACK    ;SDA为低电平，返回了响应信号
         CLR  SDA
         CLR  SCL
         RET
 ;----------------------------------------------------
 ;启动信号子程序
 ;----------------------------------------------------
START:
         SETB SDA
         SETB SCL
         NOP
         CLR SDA
         NOP
         NOP
         NOP
         NOP
         CLR SCL
         RET
 ;----------------------------------------------------
 ;停止信号子程序
 ;----------------------------------------------------
STOP:
         CLR SDA
         NOP
         SETB SCL
         NOP
         NOP
         NOP
         NOP
         SETB SDA
         NOP
         NOP
         CLR  SCL
         CLR  SDA
         RET
;---------------------------------------------------------
PLAY:
        MOV R0,#DISSTART      ;获得显示单元首地址
        MOV R1,#07FH          ;从第一个数码管开始
        MOV R2,#03H           ;共显示3位数码管
DISP1:
        MOV A,@R0             ;获得当前位地址
        MOV DPTR,#TAB_NU      ;获得表头
        MOVC A,@A+DPTR        ;查表获得显示数据
        MOV LED_DATA,A        ;显示数据
        MOV P2,R1             ;开始显示当前位
        MOV A,R1              ;准备显示下一位
        RR A
        MOV R1,A              ;下一位
        INC R0                ;取下一个单元地址
        LCALL DELAY2MS        ;延时 2 MS
        DJNZ R2,DISP1         ;重复显示下一个
        MOV  P2,#0FFH         ;关闭显示
        RET                   ;显示完成，返回
;---------------------------------------------------------
;延时子程序
;---------------------------------------------------------
DELAY2MS:
        MOV  R6,#10
DEL1:
        MOV  R7,#100
        DJNZ  R7,$
        DJNZ  R6,DEL1
        RET
TAB_NU:
    DB 28h,7eh,0a2h,62h,74h,61h,21h,7ah,20h,60h,0FFH
;---------------------------------------------------------
         END