---netlogo.nlogo

NETLOGO

breeds [ doves hawks ]

turtles-own [
  lifetime
]

hawks-own [
  cruise-speed
  hunt-speed
  prey-sensing-radius
  energy
  metabolism
]

doves-own [
  flockmates         ;; agentset of nearby doves
  nearest-neighbor   ;; closest one of our flockmates
  vision
  minimum-separation
  max-align-turn
  max-cohere-turn
  max-separate-turn
  normal-speed
  danger-sensing-radius
  escape-angle
  boost-speed
]

globals [ 
  deaths
  ticks 
]

;;;;;; SETUP ;;;;;;;;;;;;;;

to setup
  ca
  cct-doves population [ 
    if shade-of? red color [
      set color white
    ]
    set shape "fish"
    setup-dove-genome
  ]
  cct-hawks h-population [
    set color red
    set shape "spider"
    setup-hawk-genome
    set energy initial-energy
    set metabolism 1
  ]
  ask turtles [ 
    setxy (random-float screen-size-x)
          (random-float screen-size-y)
      rt random-float 360 
    set lifetime 0
  ]
  set ticks 0
end

to setup-dove-genome
  set vision random-normal 3 .25
  set minimum-separation random-normal 10 1
  set max-align-turn random-normal 30 7
  set max-cohere-turn random-normal 30 7
  set max-separate-turn random-normal 30 7
  set normal-speed random-normal 1 .2
  set danger-sensing-radius random-normal 3 .3
  set escape-angle random-normal 30 7
  set boost-speed random-normal 1 .25
end

to setup-hawk-genome
  set cruise-speed random-normal 1 .2
  set hunt-speed random-normal 2 .1
  set prey-sensing-radius random-normal 4 .3
end 

;;;;;; MAIN ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

to go
  set ticks ticks + 1
  ask turtles [ set lifetime lifetime + 1 ]
  ask doves [ flock escape ]
  ask hawks [ hunt hawk-death ]
  do-plots 
  
end

to do-plots
  set-current-plot "dove-life"
  set-current-plot-pen "mean"
  plot mean values-from doves [ lifetime ]
  set-current-plot-pen "min"
  plot min values-from doves [ lifetime ]
  set-current-plot-pen "max"
  plot max values-from doves [ lifetime ]
  set-current-plot "hawk-life"
  set-current-plot-pen "average"
  plot mean values-from hawks [ lifetime ]
  set-current-plot-pen "min"
  plot min values-from hawks [ lifetime ]
  set-current-plot-pen "max"
  plot max values-from hawks [ lifetime ]
end

to hawk-death
  set energy energy - metabolism
  if energy <= 0 [
    let mean-lifetime mean values-from hawks [lifetime]
    ;ask random-one-of hawks with [ lifetime >= mean-lifetime] [ ; one of the elder reproduces
    ;ask max-one-of hawks [ lifetime ] [ ; THE oldest reproduces
    ask random-one-of hawks [ ; random reproduction
      hatch 1 [
        set energy initial-energy
        set lifetime 0
        lt random 360
        mutate-hawk
      ]
    ]
    die
  ]
end 

to mutate-hawk 
  set cruise-speed abs (cruise-speed + plusminus cruise-speed-mrate)
  set hunt-speed abs (hunt-speed + plusminus hunt-speed-mrate)
  set prey-sensing-radius abs (prey-sensing-radius + plusminus prey-sensing-radius-mrate)
end 

to mutate-dove
  set vision abs (vision + plusminus vision-mrate)
  set minimum-separation abs (minimum-separation + plusminus minimum-separation-mrate)
  set max-align-turn abs (max-align-turn + plusminus max-align-turn-mrate)
  set max-cohere-turn abs (max-cohere-turn + plusminus max-cohere-turn-mrate)
  set max-separate-turn abs (max-separate-turn + plusminus max-separate-turn-mrate)
  set normal-speed abs (normal-speed + plusminus normal-speed-mrate)
  set danger-sensing-radius abs (danger-sensing-radius + plusminus danger-sensing-radius-mrate)
  set escape-angle abs (escape-angle + plusminus escape-angle-mrate)
  set boost-speed abs (boost-speed + plusminus boost-speed-mrate)
end

; reports +/- x
to-report plusminus [ x ]
  report ((random 2) * 2 - 1) * x
end

; reports a random number { x | lo <= x < hi }
to-report random-range-float [ lo hi ]
  report random-float 1 * (hi - lo) + lo
end 

to escape 
  let nearest-hawk min-one-of hawks in-radius danger-sensing-radius [ distance myself ]
  if (is-agent? nearest-hawk and distance nearest-hawk != 0) [
    turn-away towards nearest-hawk escape-angle
    fd boost-speed ;* (1 - distance nearest-hawk / danger-sensing-radius)
  ]  
end

to hunt
  without-interruption [
    let nearest-dove min-one-of doves in-radius prey-sensing-radius [ distance myself ]
    ifelse (nobody != nearest-dove and distance nearest-dove != 0 and energy <= 15) [
      set heading towards nearest-dove  
      fd hunt-speed
      if distance nearest-dove <= .5 [  ; dove in eating range?
        set energy energy + 20 
        set deaths deaths + 1
        ask nearest-dove [ die ]
        ask random-one-of doves [ ; spawn a new dove
          hatch 1 [
            lt random 360
            mutate-dove
            set lifetime 0
          ]
        ]
      ]
    ][ ; if not hunting or hungry
      wiggle cruise-speed
    ]
  ]
end 

to wiggle [ speed ]
  lt random 40 * 2 - 40
  fd speed
end

to flock  ;; dove procedure
  find-flockmates
  if any? flockmates
    [ find-nearest-neighbor 
      ifelse distance nearest-neighbor < minimum-separation
        [ separate ]
        [ align
          cohere ] ]
  fd normal-speed
end

to find-flockmates  ;; dove procedure
  set flockmates (doves in-radius vision) with [self != myself]
end

to find-nearest-neighbor ;; dove procedure
  set nearest-neighbor min-one-of flockmates [distance myself]
end

;;; SEPARATE

to separate  ;; dove procedure
  turn-away (heading-of nearest-neighbor) max-separate-turn
end

;;; ALIGN

to align  ;; dove procedure
  turn-towards average-flockmate-heading max-align-turn
end

to-report average-flockmate-heading  ;; dove procedure
  ;; We can't just average the heading variables here.
  ;; For example, the average of 1 and 359 should be 0,
  ;; not 180.  So we have to use trigonometry.
  ;; Theoretically this could fail if both sums are 0
  ;; since atan 0 0 is undefined, but in practice that's
  ;; vanishingly unlikely.
  report atan sum values-from flockmates [sin heading]
              sum values-from flockmates [cos heading]
end

;;; COHERE

to cohere  ;; dove procedure
  turn-towards average-heading-towards-flockmates max-cohere-turn
end

to-report average-heading-towards-flockmates  ;; dove procedure
  ;; "towards myself" gives us the heading from the other dove
  ;; to me, but we want the heading from me to the other dove,
  ;; so we add 180
  report atan mean values-from flockmates [sin (towards myself + 180)]
              mean values-from flockmates [cos (towards myself + 180)]
end

;;; HELPER PROCEDURES

to turn-towards [new-heading max-turn]  ;; dove procedure
  turn-at-most (subtract-headings new-heading heading) max-turn
end

to turn-away [new-heading max-turn]  ;; dove procedure
  turn-at-most (subtract-headings heading new-heading) max-turn
end

;; turn right by "turn" degrees (or left if "turn" is negative),
;; but never turn more than "max-turn" degrees
to turn-at-most [turn max-turn]  ;; dove procedure
  ifelse abs turn > max-turn
    [ ifelse turn > 0
        [ rt max-turn ]
        [ lt max-turn ] ]
    [ rt turn ]
end


; *** NetLogo Model Copyright Notice ***
;
; This model was originally created as part of the project: CONNECTED MATHEMATICS:
; MAKING SENSE OF COMPLEX PHENOMENA THROUGH BUILDING OBJECT-BASED PARALLEL
; MODELS (OBPML).  The project gratefully acknowledges the support of the
; National Science Foundation (Applications of Advanced Technologies
; Program) -- grant numbers RED #9552950 and REC #9632612.
;
; Copyright 1998 by Uri Wilensky. All rights reserved.
;
; Permission to use, modify or redistribute this model is hereby granted,
; provided that both of the following requirements are followed:
; a) this copyright notice is included.
; b) this model will not be redistributed for profit without permission
;    from Uri Wilensky.
; Contact Uri Wilensky for appropriate licenses for redistribution for
; profit.
;
; This model was converted to NetLogo (and was changed in the process to
; be an alternate version of the model) as part of the project:
; PARTICIPATORY SIMULATIONS: NETWORK-BASED DESIGN FOR SYSTEMS LEARNING IN
; CLASSROOMS.  The project gratefully acknowledges the support of the
; National Science Foundation (REPP program) -- grant number REC #9814682.
; Converted from StarLogoT to NetLogo, 2002.  Updated 2002.
;
; To refer to this model in academic publications, please use:
; Wilensky, U. (1998).  NetLogo Flocking model.
; http://ccl.northwestern.edu/netlogo/models/Flocking.
; Center for Connected Learning and Computer-Based Modeling,
; Northwestern University, Evanston, IL.
;
; In other publications, please use:
; Copyright 1998 by Uri Wilensky.  All rights reserved.  See
; http://ccl.northwestern.edu/netlogo/models/Flocking
; for terms of use.
;
; *** End of NetLogo Model Copyright Notice ***

@#$#@#$#@
GRAPHICS-WINDOW
209
10
723
545
25
25
9.9
1
10
1
1
1
0

CC-WINDOW
5
646
947
741
Command Center

BUTTON
13
14
94
47
NIL
setup
NIL
1
T
OBSERVER
T
NIL

BUTTON
96
13
177
46
NIL
go
T
1
T
OBSERVER
T
NIL

SLIDER
12
57
192
90
population
population
1
200
108
1
1
NIL

SLIDER
738
15
913
48
h-population
h-population
0
200
21
1
1
NIL

PLOT
738
414
938
564
dove-life
NIL
NIL
0.0
10.0
0.0
10.0
true
false
PENS
"max" 1.0 0 -65536 true
"mean" 1.0 0 -16777216 true
"min" 1.0 0 -16776961 true

SLIDER
12
94
184
127
vision-mrate
vision-mrate
0
2
1.3
0.1
1
NIL

SLIDER
12
130
191
163
minimum-separation-mrate
minimum-separation-mrate
0
5
1.0
0.1
1
NIL

SLIDER
11
169
190
202
max-align-turn-mrate
max-align-turn-mrate
0
30
1
1
1
NIL

SLIDER
11
204
190
237
max-cohere-turn-mrate
max-cohere-turn-mrate
0
30
1
1
1
NIL

SLIDER
11
240
193
273
max-separate-turn-mrate
max-separate-turn-mrate
0
40
1
1
1
NIL

SLIDER
11
276
189
309
normal-speed-mrate
normal-speed-mrate
0
2
0.0
0.1
1
NIL

SLIDER
12
311
185
344
danger-sensing-radius-mrate
danger-sensing-radius-mrate
0
5
0.3
0.1
1
NIL

SLIDER
11
346
183
379
escape-angle-mrate
escape-angle-mrate
0
100
1
1
1
NIL

SLIDER
11
382
183
415
boost-speed-mrate
boost-speed-mrate
0
6
0.0
0.1
1
NIL

MONITOR
14
424
67
473
vision
mean values-from doves [ vision ]
3
1

MONITOR
69
424
126
473
min-sep