---graze1.nlogo

NETLOGO

globals [biomass-unit days dollars grazecountdown mcal]
breeds [cow]
patches-own [biomass]
turtles-own [energy] ; as Mcal

to setup
    ca
    set biomass-unit 2.5 ; each increment of biomass (0-10) is valued at this many lbs. dry weight 
    ifelse start-patches-even?
        [ask patches [set biomass 4]]
        [ask patches [set biomass (random 4.0) * 2]]
    if update-patches?
    [ask patches [update-patches]]
    setup-plot
    setup-histogram
end

to go
   ask patches [grow-grass-and-weeds
               cycle-plants]
   if update-patches?
   [ask patches [update-patches]]
   plot-biomass
   histo-patches
   set days days + 1
   set grazecountdown grazecountdown - 1
   wait 0.5
   if any turtles 
       [ ask cow [graze] ]
end

to cycle-plants ;; patch procedure representing mortality and new establishment
      if biomass <= .3 [
      if ( random 100 ) < 5
        [ set biomass 0 ]
                       ]
        
      if biomass = 0 [  
      if ( random 100 ) < 3
        [ set biomass 1 ]
                     ]
end

to update-patches ;; patch procedure

    if biomass <= 2 [set pcolor 68] 
    if biomass > 2 [set pcolor 66]
    if biomass > 6 [set pcolor 64]
    if biomass > 8 [set pcolor 44]
    if biomass <= 0 [set pcolor brown] 
end

to cattle-in
    set-default-shape cow "cow"
    create-custom-cow num-cows  ;; create the cows, then initialize their variables
          [ 
    set color black
    set energy 0
    setxy (random screen-size-x) (random screen-size-y) ; spreads them around
    rt random 360
          ] 
    set grazecountdown grazeperiod   
end

to cattle-out
    ask turtles [die]
    set grazecountdown 0
end

;;;;; GRAZING PROCEDURES

to graze  ;; daily cow procedure
   if grazecountdown <= 0 [die]
   repeat (.4 / bitesize) [move bite]
   check-fill
   gain
end     
                       
to move                                
    rt random 50 - random 50 fd 1
    repeat selectivity
        [
    if biomass < 1 or biomass > 8 [fd 3]
        ]
end

to bite
       ifelse biomass < 1 or biomass > 8 
       [  set energy energy + (biomass * biomass-unit * bitesize * .4)] ; less energy: .4 Mcal per lb.
       [  set energy energy + (biomass * biomass-unit * bitesize * .7)] ; more energy: .7 Mcal per lb.
       set biomass (biomass * (1 - bitesize)) ; patch loses biomass in proportion to bitesize   
end

to check-fill
    repeat (1.6 / bitesize) [if energy < 20 [move bite]] ; attempt to harvest 20 Mcal
end

to gain
    set dollars dollars + (((energy - 5) / 7) * .4) 
    ;assumes 5 Mcal for maintenance
    ;assumes 7 Mcal needed for pound of $.40 gain
    set mcal energy; records the energy harvest of last cow
    set energy 0
end

;;;;; PLANT GROWTH

to grow-grass-and-weeds ;; patch procedure
    if biomass < 7.5 ;; stage at which growth slows
    [set biomass biomass + (((precision (biomass ^ .667) 2) / 40) * grassrate)] 
    ; gives about 2.5% daily growth with grassrate 1.0
    if biomass >= 7.5 
    [set biomass biomass + (((10 - biomass) / 40) * grassrate)]
end

;;;; PLOTTING PROCEDURES

to setup-plot
    set-current-plot "ecology and economy"
    set-current-plot-pen "avg-biomass"
    set-plot-y-range 0 10
    set-current-plot-pen "dollars per week"
    set-plot-y-range 0 10
end

to setup-histogram
    set-current-plot "patch biomass histogram"
    ;set-plot-x-range 0 10
    set-plot-y-range 0 100
    set-histogram-num-bars 11
end

to plot-biomass 
    set-current-plot "ecology and economy"
    set-current-plot-pen "avg-biomass"
    plot mean values-from patches [biomass]
    set-current-plot-pen "dollars per week"
    plot dollars / (days + .001) * 7
end

to histo-patches
    set-current-plot "patch biomass histogram"
    histogram patches [ biomass ]  ; using the default plot pen
end

; ***NetLogo Model Copyright Notice***

; Copyright 2003 by Peter Donovan. All rights reserved.

; Permission to use, modify, or redistribute this model is hereby granted,
; provided that both of the following requirements are followed:
; a) this copyright notice is included.
; b) this model will not be redistributed for profit without permission
;    from Peter Donovan.
; Contact Peter Donovan ([e-mail]) for appropriate licenses
; for redistribution for profit.

; To refer to this model in academic publications, please use: 
; Donovan, Peter. (2003).  NetLogo Grazing Model # 1. 
; http://managingwholes.com/models/graze1.htm.
@#$#@#$#@
GRAPHICS-WINDOW
324
10
664
350
8
8
20.0
1
10
0
0

CC-WINDOW
324
547
664
677
Command Center

BUTTON
20
10
85
43
setup
setup
NIL
1
T
OBSERVER

BUTTON
89
11
149
44
run
go
T
1
T
OBSERVER

MONITOR
159
12
216
61
days
days
0
1

SLIDER
20
153
154
186
num-cows
num-cows
0
100
10
1
1
NIL

BUTTON
20
47
129
80
advance 1 day
go
NIL
1
T
OBSERVER

BUTTON
19
189
122
236
cattle in
cattle-in
NIL
1
T
OBSERVER

PLOT
19
393
664
543
ecology and economy
days
NIL
0.0
365.0
0.0
10.0
true
true
PENS
"avg-biomass" 1.0 0 -8716033 true
"dollars per week" 1.0 0 -65536 true

MONITOR
225
12
310
61
dollars
dollars
2
1

PLOT
19
247
311
384
patch biomass histogram
<= seedlings      dormant =>
# patches
0.0
10.0
0.0
100.0
true
false
PENS
"default" 1.0 1 -16777216 true

SLIDER
19
83
153
116
grassrate
grassrate
0
3.0
1.0
0.1
1
NIL

SLIDER
159
153
311
186
grazeperiod
grazeperiod
0
100
10
1
1
NIL

MONITOR
237
188
311
237
recovery
0 - grazecountdown
0
1

BUTTON
126
189
233
236
cattle out
cattle-out
NIL
1
T
OBSERVER

MONITOR
231
65
309
114
$ per day
dollars / days
2
1

SWITCH
324
359
467
392
update-patches?
update-patches?
0
1