---enzymekinetics.nlogo

NETLOGO

breeds [
  substrate    ;; green turtles that bind with enzyme
  enzyme       ;; red turtles that bind with and catalyze substrate
  inhibitor    ;; yellow turtle that binds to enzyme, but does not react  
  product      ;; blue turtle generated from enzyme catalysis
]

turtles-own [
  partner      ;; holds the turtle this turtle is complexed with,
               ;; or nobody if not complexed
]

globals [
  ticks           ;; keeps track of how much time has passed
  substrate-added ;; keeps track of how much substrate has been added
  v               ;; rate of complex formation at each time step
  Kc
  Kd
  Kr
]

to startup
  setup-mm-plot
end

;; observer procedure to set up model
to setup 
  set-current-plot "Concentrations"
  clear-plot
  clear-turtles                    ;; clears screen -- don't use ca so MM plot doesn't clear
  set ticks 0
  set substrate-added 0
  set v 0
  add enzyme 150                   ;; starts with constant number of enzymes
  add substrate volume             ;; add substrate based on slider
  set Kc 80
  set Kd 62
  set Kr 30
end

;; observer procedure to add molecules to reaction
to add [kind amount]
  cct amount
    [ set breed kind
      setxy (random-float screen-size-x)
            (random-float screen-size-y)
      set partner nobody
      setshape ]
  if kind = substrate
    [ set substrate-added substrate-added + amount ]
end

;; procedure that assigns a specific shape to a turtle, and shows
;; or hides it, depending on its state
to setshape
  ifelse breed = enzyme
    [ set color red
      ifelse partner = nobody
        [ set shape "enzyme" ]
        [ ifelse (breed-of (partner) = substrate)
            [ set shape "complex" ]
            [ set shape "inhib-complex" ] ] ]
    [ ifelse breed = substrate
        [ set color green
          set shape "substrate"
          set hidden? (partner != nobody) ]
        [ ifelse breed = inhibitor
            [ set color yellow
              set shape "inhibitor"
              set hidden? (partner != nobody) ]
            [ if breed = product
                [ set color blue
                  set shape "substrate"
                  set hidden? false ] ] ] ]
end

;; main procedure
to go
  set ticks (ticks + 1)
  ask turtles [ move ]                ;; only non-complexed turtles will move
  ask enzyme [ form-complex ]         ;; enzyme may form complexes with substrate or inhibitor
  ask substrate [ react-forward ]     ;; complexed substrate may turn into product
  ask enzyme [ dissociate ]           ;; or complexes may just split apart
  calculate-velocity                  ;; calculate V for use in the Michaelis-Menten curve
  plot-concentrations                 ;; plots variables
  if pause? and (ticks >= 30)
    [ stop ]
end

to move  ;; turtle procedure
  if partner = nobody
    [ fd 1
      rt random-float 360 ]
end

;; An enzyme forms a complex by colliding on a patch with a substrate
;; or inhibitor.  If it collides with an inhibitor, it always forms
;; a complex.  If it collides with a subtrate, Kc is its percent chance
;; of forming a complex.
to form-complex  ;; enzyme procedure
  if partner != nobody [ stop ]
  set partner random-one-of (other-turtles-here with [partner = nobody])
  if partner = nobody [ stop ]
  if partner-of partner != nobody [ set partner nobody stop ]  ;; just in case two enzymes grab the same partner
  ifelse (((breed-of partner) = substrate) and ((random-float 100) < Kc))
     or ((breed-of partner) = inhibitor)
    [ set (partner-of partner) self
      setshape
      ask partner [ setshape ] ]
    [ set partner nobody ]
end 

;; substrate procedure that controls the rate at which complexed substrates
;; are converted into products and released from the complex
to react-forward
  locals [old-partner]
  if (partner != nobody) and (random-float 1000 < Kr)
    [ set breed product
      set partner-of partner nobody
      set old-partner partner
      set partner nobody
      setshape
      ask old-partner [ setshape ] ]
end

;; enzyme procedure that controls the rate at which complexed turtles break apart
to dissociate
  locals [old-partner] 
  if partner != nobody
    [ if (breed-of partner = substrate) and (random-float 1000 < Kd)
      [ set partner-of partner nobody
        set old-partner partner
        set partner nobody
        setshape
        ask old-partner [ setshape ] ] ]
end

to calculate-velocity
  locals [initial-conc current-conc]
  set initial-conc substrate-added
  set current-conc count substrate with [partner = nobody]
  set v (initial-conc - current-conc) / ticks
end

;;; plotting procedures

to plot-concentrations
  set-current-plot "Concentrations"
  set-current-plot-pen "Substrate"
  plot count substrate with [partner = nobody]
  set-current-plot-pen "Complex"
  plot count enzyme with [partner != nobody]
  set-current-plot-pen "Product"
  plot count product
end

to setup-mm-plot
  set-current-plot "Michaelis-Menten Curve"
  clear-plot
end

;; allows user to plot the concentration versus the velocity on the Michaelis-Menten Curve
to do-mm-plot
  set-current-plot "Michaelis-Menten Curve"
  plotxy substrate-added v
end


; *** NetLogo Model Copyright Notice ***
;
; This model was created as part of the project:
; PARTICIPATORY SIMULATIONS: NETWORK-BASED DESIGN FOR SYSTEMS LEARNING IN
; CLASSROOMS.  The project gratefully acknowledges the support of the
; National Science Foundation (REPP program) -- grant number REC #9814682.
;
; Copyright 2001 by Uri Wilensky.  Updated 2002.  All rights reserved.
;
; Permission to use, modify or redistribute this model is hereby granted,
; provided that both of the following requirements are followed:
; a) this copyright notice is included.
; b) this model will not be redistributed for profit without permission
;    from Uri Wilensky.
; Contact Uri Wilensky for appropriate licenses for redistribution for
; profit.
;
; To refer to this model in academic publications, please use:
; Wilensky, U. (2001).  NetLogo Enzyme Kinetics model.
; http://ccl.northwestern.edu/netlogo/models/EnzymeKinetics.
; Center for Connected Learning and Computer-Based Modeling,
; Northwestern University, Evanston, IL.
;
; In other publications, please use:
; Copyright 1998 by Uri Wilensky.  All rights reserved.  See
; http://ccl.northwestern.edu/netlogo/models/EnzymeKinetics
; for terms of use.
;
; *** End of NetLogo Model Copyright Notice ***
@#$#@#$#@
GRAPHICS-WINDOW
289
10
649
391
12
12
14.0
1
10
1
1
1
0

CC-WINDOW
5
559
658
654
Command Center

BUTTON
4
41
68
74
setup
setup
NIL
1
T
OBSERVER
T
NIL

BUTTON
69
41
130
74
go
go
T
1
T
OBSERVER
T
NIL

MONITOR
289
393
355
442
Velocity
v
3
1

BUTTON
20
146
120
179
add inhibitor
add inhibitor volume
NIL
1
T
OBSERVER
T
NIL

BUTTON
20
111
120
144
add substrate
add substrate volume
NIL
1
T
OBSERVER
T
NIL

PLOT
3
181
287
359
Concentrations
time
C
0.0
50.0
0.0
50.0
true
true
PENS
"Substrate" 1.0 0 -11352576 true
"Complex" 1.0 0 -65536 true
"Product" 1.0 0 -16776961 true

PLOT
3
360
287
540
Michaelis-Menten Curve
Substrate Conc.
V
0.0
10.0
0.0
1.0
true
false
PENS
"default" 1.0 2 -16777216 true

SLIDER
133
41
287
74
volume
volume
0
1000
50
25
1
molecules

BUTTON
289
512
364
545
clear MM
setup-MM-plot
NIL
1
T
OBSERVER
T
NIL

SWITCH
289
444
390
477
pause?
pause?
1
1
-1000

BUTTON
289
478
390
511
Record V
do-MM-plot
NIL
1
T
OBSERVER
T
NIL

@#$#@#$#@
WHAT IS IT?
-----------
This model demonstrates the kinetics of single-substrate enzyme-catalysis. The interactions between enzymes and substrates are often difficult to understand and the model allows users to visualize the complex reaction.

The standard equation for this reaction is shown below.

                  Kc          Kr
        E + S <=======> E-S ------> E + P
                  Kd

Here E represents Enzyme, S Substrate, E-S Enzyme-Substrate complex, and P product.  The rate constants are Kc for complex formation, Kd for complex dissociation, Kr for catalysis.  The first step in catalysis is the formation of the E-S complex.  This can consist of either covalent or non-covalent bonding.  The rates of complex formation and dissociation are very fast because they are determined by collision and separation of the molecules.  The next step is for the enzyme to catalyze the conversion of substrate to product.  This rate is much slower because the energy required for catalysis is much higher than that required for collision or separation.

The model demonstrates several important properties of enzyme kinetics.  Enzyme catalysis is often assumed to be controlled by the rate of complex formation and dissociation, because it occurs much faster than the rate of catalysis. Thus, the reaction becomes dependent on the ratio of Kc / Kd.  The efficiency of catalysis can be studied by observing catalytic behavior at different substrate concentrations.

By measuring the rate of complex formation at different substrate concentrations, a Michaelis-Menten Curve can be plotted.  Analysis of the plot provides biochemists with the maximum rate (Vmax) at which the reaction can proceed. As can be seen from the model, this plot is linear at low levels of substrate, and non-linear at higher levels of substrate.  By examining the model, the reasons for this relationship can be seen easily.

Enzyme catalysis can also be controlled using inhibitors. Inhibitors are molecules that are structurally similar to substrate molecules that can complex with the enzyme and interfere with the E-S complex formation.  Subsequently, the shape of the Michaelis-Menten Curve will be altered. The model demonstrates the effects of inhibitors on catalysis.


HOW TO USE IT
--------------
Choose the values of Kc, Kd, and Kr with appropriate sliders:
- Kc controls the rate at which substrates (green) and enzymes (red) stick together so that catalysis can occur
- Kd controls the rate at which they come unstuck
- Kr controls the rate of the forward reaction by which an enzyme (red) converts a substrate (green) to a product (blue)

Having chosen appropriate values of the constants, press SETUP to clear the screen and create a constant initial number of enzyme (red) molecules. Play with several different values to observe variable effects on complex formation and catalysis.

Press GO to start the simulation.  A constant amount of enzyme (red) will be generated.  The concentrations of substrate, complex, and product are plotted in the CONCENTRATIONS window.

Experiment with using the ADD-SUBSTRATE and ADD-INHIBITOR buttons to observe the effects of adding more molecules to the system manually as it runs.  The default setting for Kr is 0, which means that no product (blue) will be generated unless you change Kr to a non-zero value.

Note that when complexes form they stop moving.  This isn't intended to be physically realistic; it just makes the formation of complexes easier to see.  (This shouldn't affect the overall behavior of the model.)

To plot the Michaelis-Menten Curve for your reaction conditions, you will have to perform several runs at different concentrations in order to measure the velocity for each run. To do this, set the PAUSE? switch ON.  When this switch is on, the model automatically stops after 30 time ticks.  Begin your assay by setting the substrate volume to zero and running the simulation.  When it stops, press RECORD V and a point will be plotted on the Michaelis-Menten Curve. Run another simulation with a higher concentration of substrate by changing the VOLUME slider, then hitting SETUP followed by GO, followed by RECORD V once the model stops.  Continue for several values of substrate concentrations until a curve is generated. If you wish to start over hit CLEAR MM to reset the plot.


THINGS TO NOTICE
----------------
Watch the rate at which the enzyme and substrate stick together. How does this affect the conversion of substrate into product? What would happen if Kd is very high and Kc is very low? If Kr were the same order of magnitude as Kd and Kc?
  
Watch the Michaelis-Menten Curve. Does it match up with the discussion of enzyme kinetics discussed above? Why does the plot initially slope upward, then flatten out?

Which variables can alter the magnitude of v?

How does the magnitude of Kd and Kr affect the smoothness of the Michaelis-Menten Curve?


THINGS TO TRY
-------------
Run the simulation with VOLUME set to various amounts. How does this affect the curve?

If Kr is MUCH greater than Kd, what affect does this have on the reaction?  How important does complex formation become in this situation?

If Kc is MUCH less than Kd, what does this mean in the real-world? How are the enzyme and substrate related under these conditions?

What effect does adding inhibitor to the model have on the plot? Is Vmax affected?


EXTENDING THE MODEL
------------------
What would happen if yellow inhibitor molecules could react to form a product? How would this affect the plot?

Inhibitors can be irreversible or reversible. That is, they can bind to an enzyme and never let go, or they can stick and fall off. Currently, the model simulates irreversible inhibitors. Modify the code so that the yellow molecules reversibly bind to the enzyme. How does this affect catalysis?

Often, the product of catalysis is an inhibitor of the enzyme. This is called a feedback mechanism. In this model, product cannot complex with enzyme. Modify the procedures so that the product is a reversible inhibitor. How does this affect catalysis with and without yellow inhibitor?

Include a slider that allows you to change the concentration of enzyme.  What affect does this have on the plot?  Vmax?  Look closely!


NETLOGO FEATURES
------------------
It is a little difficult to ensure that a reactant never participates in two reactions simultaneously.  In the future, a primitive called GRAB may be added to NetLogo; then the code in the FORM-COMPLEX procedure wouldn't need to be quite so tricky.


CREDITS AND REFERENCES
----------------------
Thanks to Mike Stieff for his work on this model.

To refer to this model in academic publications, please use: Wilensky, U. (2001).  NetLogo Enzyme Kinetics model. http://ccl.northwestern.edu/netlogo/models/EnzymeKinetics. Center for Connected Learning and Computer-Based Modeling, Northwestern University, Evanston, IL.

In other publications, please use: Copyright 2001 by Uri Wilensky.  All rights reserved.  See http://ccl.northwestern.edu/netlogo/models/EnzymeKinetics for terms of use.
@#$#@#$#@
default
true
0
Polygon -7566196 true true 150 5 40 250 150 205 260 250

complex
true
0
Polygon -65536 true false 76 47 197 150 76 254 257 255 257 47
Polygon -11352576 true false 79 46 198 148 78 254

enzyme
true
0
Polygon -65536 true false 76 47 197 150 76 254 257 255 257 47

inhib-complex
true
0
Polygon -65536 true false 76 47 197 150 76 254 257 255 257 47
Polygon -256 true false 77 48 198 151 78 253 0 253 0 46

inhibitor
true
0
Polygon -256 true false 197 151 60 45 1 45 1 255 60 255

substrate
true
5
Polygon -11352576 true true 76 47 197 151 75 256

@#$#@#$#@
NetLogo 2.1.0
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@