---l-change_5.nlogo

NETLOGO

;;All models

globals [ num-patches counter arena-mean]
turtles-own [ acquirer-grammar-state perceived-grammar-state sample-set mylist mylist2 mylist-temp gamma ]
patches-own [arena-grammar-state]

to setup
  ca
  set num-patches screen-size-x * screen-size-y
  initialize-arena
end

to go-var ;for the variational model 
do-plots
ask turtles 
  [
    sample-arena-variational
  ]
update-colors
speak
end

to go-hybrid  ;for the hybrid variational with functional bias 
do-plots
ask turtles 
  [
    sample-arena-hybrid
  ]
update-colors
speak
end

to go-functional
  do-plots
  sample-arena-functional
  update-colors
  speak-prob
  
end

to go-deterministic
  do-plots
  sample-arena-functional
  update-colors
  speak-det
  
end

to initialize-arena 

ask patches
[
ifelse invasion? 
[
set pcolor black
    ask patch 0 0 
    [
    set pcolor white
    set arena-grammar-state 1
    ask neighbors [set pcolor white set arena-grammar-state 1]
    ]
  ]
[
ifelse (random-float 1 < initial-arena)  ;initialize arena to color and grammar-state
   [
      set pcolor white
      set arena-grammar-state 1
   ]
   [
      set pcolor black 
      set arena-grammar-state 0
   ]
]
]
ask patches
    [ sprout 1 ;use "sprout" to ensure one turtle per patch; patches create turtles
      [   
       set size .5
       set acquirer-grammar-state 0
       set color red
      ]
     ] 
end 

;;;;;;;;;;;;;;;FUNCTIONAL BIAS PROCEDURE;;;;;;;;;;;;;;;;;;
to sample-arena-functional ;observer procedure
 ask turtles 
 [
 set sample-set random-n-of (round((proportion-to-sample) * num-patches)) patches
 set acquirer-grammar-state ((count sample-set with [arena-grammar-state = 1]) / 
 ((count sample-set with [arena-grammar-state = 1]) + ((1 - alpha) * (count sample-set with [arena-grammar-state = 0])))) 

 ] 
end  

;;;;;;;;;;;;;;;;VARIATIONAL SAMPLING PROCEDURE;;;;;;;;;;;;;
to sample-arena-variational 
set gamma .02  ;this is the value from Yang 2002 used to smooth individual acquisition

   ;a random set of speakers is sampled and retained as "sample-set". 
set sample-set random-n-of (round((proportion-to-sample) * num-patches)) patches
   ;The values of "arena-grammar-state" from sample-set are put into "mylist" 
set mylist (values-from sample-set [arena-grammar-state]) 
  
 ; make a copy of "mylist" so that it can be multiplied by the number of "utterances" from each speaker
  set mylist-temp mylist  
 ;"mylist" is then expanded depending on how many "utterances" are sampled from each speaker 
   repeat (utterances - 1) 
   [
     set mylist sentence mylist-temp mylist
   ]
   
 set counter (length mylist) ;for keeping track of total # utterances per acquisition cycle
 set mylist (shuffle mylist) 
     foreach  mylist 
       [
         ifelse (random-float 1 <= ? )
         [ 
           set acquirer-grammar-state (acquirer-grammar-state + (gamma * ( 1 - acquirer-grammar-state)))
         ]
         [
           set acquirer-grammar-state ((1 - gamma ) * acquirer-grammar-state )
         ]
       ]
end

;;;;;;;;;;;;;;;;;;HYBRID SAMPLING PROCEDURE;;;;;;;;;;;;;;;;;
to sample-arena-hybrid ;observer procedure

set gamma .01  ;this is the value from Yang 2002 used to smooth individual acquisition
set mylist2 []
 ;a random set of speakers is sampled and retained as "sample-set". 
set sample-set random-n-of (round((proportion-to-sample) * num-patches)) patches
 ;The values of "arena-grammar-state" from sample-set are put into "mylist" 
 ;if invasion? = true, then neighbors are sampled
 ifelse (invasion? = true)
     [
     set mylist (values-from neighbors [arena-grammar-state]) 
     ]
     [
     set mylist (values-from sample-set [arena-grammar-state]) 
     ]
  
 ;Using the grammar state values, set "mylist2" to comprise utterances of either 1 or 0
  foreach mylist 
    [
    ifelse (random-float 1 <= ? ) 
      [set mylist2 lput 1 mylist2 ]
      [set mylist2 lput 0 mylist2 ]
    ]
     ; make a copy of "mylist2" so that it can be multiplied by the number of "utterances" from each speaker
  set mylist-temp mylist2  
     ;"mylist2" is then expanded depending on how many "utterances" are sampled from each speaker 
   repeat (utterances - 1) 
   [
     set mylist2 sentence mylist-temp mylist2
   ]
 set counter (length mylist2) ;for keeping track of total # utterances per acquisition cycle
 set mylist2 (shuffle mylist2) 
   ;introduce the bias here 
 set perceived-grammar-state ((length (filter [ ? = 1] mylist2) ) / 
                            ((length (filter [ ? = 1] mylist2) ) + ((1 - alpha) * (length (filter [ ? = 0] mylist2)))))
      foreach  mylist2 
       [
         ifelse (random-float 1 <= perceived-grammar-state )
         [ 
           set acquirer-grammar-state (acquirer-grammar-state + (gamma * ( 1 - acquirer-grammar-state)))
         ]
         [
           set acquirer-grammar-state ((1 - gamma ) * acquirer-grammar-state )
         ]
       ]
end  

to speak ;  speak grammar to arena 
ask turtles
      [
      set arena-grammar-state-of patch-here ( acquirer-grammar-state )
      ]
end

to speak-prob ;  speak grammar to arena  probabilistic set grammar state by the probability of "acquirer-grammar-state" 
ask turtles
[
    ifelse (random-float 1 < acquirer-grammar-state) 
      [set arena-grammar-state-of patch-here ( 1 )]
      [set arena-grammar-state-of patch-here ( 0 )]
]
end

to speak-det ;speak grammar to arena deterministic - winner take all!
ask turtles
[
    ifelse (acquirer-grammar-state > .5 ) 
      [set arena-grammar-state-of patch-here ( 1 )]
      [set arena-grammar-state-of patch-here ( 0 )]
]
end
  
to update-colors 
ask turtles 
  [
    set color scale-color red acquirer-grammar-state 0 1  
  ]
  ask patches 
  [
  set pcolor scale-color black arena-grammar-state 0 1 
  ]
  ;diffuse pcolor .5
  end

to do-plots
  set-current-plot "grammar states"
  ;set-current-plot-pen "acquirers"
  ;plot (mean values-from turtles [acquirer-grammar-state])
  set-current-plot-pen "arena"
  plot (mean values-from patches [arena-grammar-state])
  set-current-plot-pen "individual" 
  plot (value-from (patch 0 0) [arena-grammar-state])
  set arena-mean (mean values-from patches [arena-grammar-state])
  
end




@#$#@#$#@
GRAPHICS-WINDOW
302
10
637
366
12
12
13.0
0
10
1
1
1
0
1
1
1

CC-WINDOW
5
489
646
584
Command Center
0

BUTTON
116
54
195
87
go-variational 
go-var
T
1
T
OBSERVER
NIL
NIL

BUTTON
14
10
108
92
setup
setup
NIL
1
T
OBSERVER
T
NIL

SLIDER
349
374
596
407
initial-arena
initial-arena
0
1
0.1
0.01
1
NIL

SLIDER
349
413
597
446
proportion-to-sample
proportion-to-sample
0.01
1
0.1
0.01
1
NIL

SLIDER
99
372
288
405
alpha
alpha
0
1
0.2
0.01
1
NIL

PLOT
16
103
288
320
grammar states
NIL
NIL
0.0
10.0
0.0
1.0
true
true
PENS
"arena" 1.0 0 -16777216 true
"individual" 1.0 0 -2674135 true

SLIDER
99
330
288
363
utterances
utterances
1
100
10
1
1
NIL

MONITOR
22
387
92
436
utt/acqu
counter
0
1

MONITOR
21
329
92
378
arena-mean
arena-mean
3
1

BUTTON
199
53
286
88
go-hybrid
go-hybrid
T
1
T
OBSERVER
T
NIL

BUTTON