---heatbugs.nlogo

NETLOGO

turtles-own
[
  ideal-temp
  output-heat
  unhappiness
]

patches-own
[
  temp
]

to setup
  clear-all
  ;; creating the bugs the following way ensures that we won't
  ;; wind up with more than one bug on a patch
  ask random-n-of bug-count patches [
    sprout 1 [
      set color lime
      set ideal-temp  min-ideal-temp  + random abs (max-ideal-temp  - min-ideal-temp )
      set output-heat min-output-heat + random abs (max-output-heat - min-output-heat)
      set unhappiness abs (ideal-temp - temp)
    ]
  ]
  ;; plot the initial state of the system
  plot mean values-from turtles [unhappiness]
end

to go
  if not any? turtles [ stop ]
  ;; diffuse heat through world
  diffuse temp diffusion-rate
  ask turtles [
    ;; we must use without-interruption to prevent two turtles
    ;; from ever ending up on the same patch
    without-interruption [
      step
    ]
  ]
  recolor-patches
  plot mean values-from turtles [unhappiness]
end

to recolor-patches
  ask patches
  [
    ;; the world retains a percentage of its heat each cycle
    set temp temp * (1 - evaporation-rate)
    ;; hotter patches will be red turning to white, cooler patches will be black
    set pcolor scale-color red temp 0 150
  ]
end

to step  ;; turtle procedure
  ;; my unhappiness is the magnitude or absolute value of the difference
  ;; between by ideal temperature and the temperature of this patch
  set unhappiness abs (ideal-temp - temp)
  ;; if unhappy and not at the hottest neighbor8
  ;; then move to an open neighbor (trying random ones up to 10 times)
  ifelse unhappiness = 0
    [ set temp temp + output-heat ]
    [ let target find-target
      if (patch-here != target) or (random-move-chance > random 100)
        [ bug-move target ]
      set temp temp + output-heat
    ]
end

;; find the hottest or coolest location next to me
to-report find-target  ;; turtle procedure
  ifelse temp < ideal-temp
    [ report max-one-of neighbors [temp] ]
    [ report min-one-of neighbors [temp] ]
end

to bug-move [target]  ;; turtle procedure
  let tries 0
  ;; move to the hottest (or coolest location if I'm too hot) location next to me
  ;; if it is not occupied by another bug
  if not any? turtles-on target [
    setxy (pxcor-of target) (pycor-of target)
    stop
  ]
  ;; If I can't get to the best spot, then I try the others randomly
  ;; I only try 9 times, since there are only nine spots around me.
  ;; Even then, I might try a spot more than once.
  while [tries <= 9]
    [ set tries tries + 1
      set target random-one-of neighbors
      if not any? turtles-on target [
        setxy (pxcor-of target) (pycor-of target)
        stop
      ]
    ]
end

;;; the following procedures support the two extra buttons
;;; in the interface

;; remove all heat from the world
to deep-freeze
  ask patches [ set temp 0 ]
end

;; add max-output-heat to all locations in the world, heating it evenly
to heat-up
  ask patches [ set temp temp + max-output-heat ]
end


; *** NetLogo Model Copyright Notice ***
;
; This model was created as part of the projects:
; PARTICIPATORY SIMULATIONS: NETWORK-BASED DESIGN FOR SYSTEMS LEARNING IN
; CLASSROOMS and INTEGRATED SIMULATION AND MODELING ENVIRONMENT.
; The project gratefully acknowledges the support of the
; National Science Foundation (REPP & ROLE programs) -- grant numbers
; REC #9814682 and REC-0126227.
;
; Copyright 2004 by Uri Wilensky.  Updated 2004.  All rights reserved.
;
; Permission to use, modify or redistribute this model is hereby granted,
; provided that both of the following requirements are followed:
; a) this copyright notice is included.
; b) this model will not be redistributed for profit without permission
;    from Uri Wilensky.
; Contact Uri Wilensky for appropriate licenses for redistribution for
; profit.
;
; To refer to this model in academic publications, please use:
; Wilensky, U. (2004).  NetLogo Heatbugs model.
; http://ccl.northwestern.edu/netlogo/models/Heatbugs.
; Center for Connected Learning and Computer-Based Modeling,
; Northwestern University, Evanston, IL.
;
; In other publications, please use:
; Copyright 2004 Uri Wilensky.  All rights reserved.
; See http://ccl.northwestern.edu/netlogo/models/Heatbugs
; for terms of use.
;
; *** End of NetLogo Model Copyright Notice ***
@#$#@#$#@
GRAPHICS-WINDOW
373
10
686
344
50
50
3.0
0
10
1
1
1
0
1
1
1

CC-WINDOW
5
520
695
615
Command Center
0

SLIDER
14
41
276
74
bug-count
bug-count
10
500
200
10
1
bugs

BUTTON
27
188
96
221
NIL
setup
NIL
1
T
OBSERVER
NIL
NIL

BUTTON
98
188
166
221
NIL
go
T
1
T
OBSERVER
T
NIL

SLIDER
18
305
211
338
evaporation-rate
evaporation-rate
0
1
0.02
0.01
1
NIL

SLIDER
18
339
211
372
diffusion-rate
diffusion-rate
0
1
1.0
0.1
1
NIL

SLIDER
18
374
211
407
random-move-chance
random-move-chance
0
100
1.0
1.0
1
%

PLOT
373
347
686
506
Avg. Bug Unhappiness
time
unhappiness
0.0
100.0
0.0
10.0
true
false

SLIDER
14
80
186
113
min-ideal-temp
min-ideal-temp
0
200
0.0
1.0
1
NIL

SLIDER
14
113
186
146
max-ideal-temp
max-ideal-temp
0
200
100.0
1.0
1
NIL

SLIDER
189
113
362
146
max-output-heat
max-output-heat
0
100
30.0
1.0
1
NIL

SLIDER
189
80
362
113
min-output-heat
min-output-heat
0
100
10.0
1.0
1
NIL

BUTTON
195
188
312
221
NIL
deep-freeze
NIL
1
T
OBSERVER
T
NIL

BUTTON
195
222
312
255
NIL
heat-up
NIL
1
T
OBSERVER
T
NIL

TEXTBOX
10
21
160
39
Initial settings for bugs

TEXTBOX
11
273
164
301
Other parameters (OK to change during run)

TEXTBOX
12
167
162
185
Actions