---serendipsegregation.nlogo

NETLOGO

globals [
  percent-similar  ;; on the average, what percent of a turtle's neighbors
                   ;; are the same color as that turtle?
  percent-unhappy  ;; what percent of the turtles are unhappy?
]

turtles-own [
  happy?       ;; for each turtle, indicates whether at least %-similar-wanted percent of
               ;; that turtles' neighbors are the same color as the turtle
]

patches-own [
  reds-nearby   ;; how many neighboring patches have a red turtle?
  greens-nearby ;; ditto for green turtles
  total-nearby  ;; sum of previous two variables
]

to setup
    do-randomize
    update-variables
    do-plots
end

to do-randomize
  ca
  set-default-shape turtles "circle"
  cct number
  [
    setxy (random screen-size-x)  ;; randomize the turtle locations
          (random screen-size-y)
    ifelse who < (number / 2)     ;; turn half the turtles red, the others green
      [ set color red ]
      [ set color green ]
    if any other-turtles-here     ;; make sure each turtle is in its own patch
      [ find-new-spot ]
  ]
end

to setup-segregated
    no-display
    set preference "prefers-similarity"
    do-randomize
    update-variables

    go-segregated
    set preference "prefers-difference"
    update-variables
    display
    do-plots
end

to go
  move-unhappy-turtles
  update-variables
  do-plots
  if not any turtles with [not happy?] [ stop ]
end

to go-segregated
  move-unhappy-turtles
  update-variables
  if (percent-unhappy = 0) or (percent-similar > 89) [ stop ]
  go-segregated
end

to move-unhappy-turtles
  ask turtles [
    if not happy?
      [ find-new-spot ]
  ]
end

to find-new-spot
  rt random 360
  fd random 10
  if any other-turtles-here
    [ find-new-spot ]          ;; keep going until we find an unoccupied patch
end

to update-variables
  update-patches
  update-turtles
  update-globals
end

to update-patches
  ask patches [
    ;; in next two lines, we use "neighbors" to test the eight patches surrounding
    ;; the current patch
    set reds-nearby count neighbors with [any turtles-here with [color = red]]
    set greens-nearby count neighbors with [any turtles-here with [color = green]]
    set total-nearby reds-nearby + greens-nearby
  ]
end

to update-turtles
  ask turtles [
    if preference = "prefers-similarity" [
    if color = red
      [ set happy? reds-nearby >= ( strength-of-preference * total-nearby / 100 ) ]
    if color = green
      [ set happy? greens-nearby >= ( strength-of-preference * total-nearby / 100 ) ]
    ]
    if preference = "prefers-difference" [
        if color = red
      [ set happy? greens-nearby >= ( strength-of-preference * total-nearby / 100 ) ]
    if color = green
      [ set happy? reds-nearby >= ( strength-of-preference * total-nearby / 100 ) ]
    ] 
    ]
end

to update-globals
  locals [ similar-neighbors total-neighbors ]
  set similar-neighbors
      sum values-from turtles with [color = red] [reds-nearby] +
      sum values-from turtles with [color = green] [greens-nearby]
  set total-neighbors
      sum values-from turtles [total-nearby]
  set percent-similar (similar-neighbors / total-neighbors) * 100
  set percent-unhappy (count turtles with [not happy?]) / (count turtles) * 100
end

to do-plots
  set-current-plot "Percent Similar"
  plot percent-similar
  set-current-plot "Percent Unhappy"
  plot percent-unhappy
end


; *** NetLogo Model Copyright Notice ***
;
; This model was created as part of the project: CONNECTED MATHEMATICS:
; MAKING SENSE OF COMPLEX PHENOMENA THROUGH BUILDING OBJECT-BASED PARALLEL
; MODELS (OBPML).  The project gratefully acknowledges the support of the
; National Science Foundation (Applications of Advanced Technologies
; Program) -- grant numbers RED #9552950 and REC #9632612.
;
; Copyright 1998 by Uri Wilensky. All rights reserved.
;
; Permission to use, modify or redistribute this model is hereby granted,
; provided that both of the following requirements are followed:
; a) this copyright notice is included.
; b) this model will not be redistributed for profit without permission
;    from Uri Wilensky.
; Contact Uri Wilensky for appropriate licenses for redistribution for
; profit.
;
; This model was converted to NetLogo as part of the project:
; PARTICIPATORY SIMULATIONS: NETWORK-BASED DESIGN FOR SYSTEMS LEARNING IN
; CLASSROOMS.  The project gratefully acknowledges the support of the
; National Science Foundation (REPP program) -- grant number REC #9814682.
; Converted from StarLogoT to NetLogo, 2001.  Updated 2002.
;
; To refer to this model in academic publications, please use:
; Wilensky, U. (1998).  NetLogo Segregation model.
; http://ccl.northwestern.edu/netlogo/models/Segregation.
; Center for Connected Learning and Computer-Based Modeling,
; Northwestern University, Evanston, IL.
;
; *** End of NetLogo Model Copyright Notice ***
@#$#@#$#@
GRAPHICS-WINDOW
311
18
627
355
25
25
6.0
1
10
0
0

CC-WINDOW
264
419
662
525
Command Center

MONITOR
170
288
283
337
Percent Unhappy
percent-unhappy
1
1

MONITOR
43
288
151
337
Percent Similar
percent-similar
1
1

PLOT
44
376
303
496
Percent Similar
time
%
0.0
25.0
0.0
100.0
true
false
PENS
"percent" 1.0 0 -65536 true

PLOT
355
375
614
495
Percent Unhappy
time
%
0.0
25.0
0.0
100.0
true
false
PENS
"percent" 1.0 0 -11352576 true

SLIDER
6
10
218
43
number
number
500
2500
1400
10
1
NIL

SLIDER
9
165
230
198
strength-of-preference
strength-of-preference
0.0
100.0
50.0
1.0
1
%

BUTTON
7
55
230
88
setup with random distribution
setup
NIL
1
T
OBSERVER

BUTTON
187
247
267
280
go
go
T
1
T
OBSERVER

BUTTON
7
116
229
149
setup with segregated distribution
setup-segregated
NIL
1
T
OBSERVER

TEXTBOX
101
92
191
110
OR

CHOICE
8
208
169
253
preference
preference
"prefers-similarity" "prefers-difference"
0

BUTTON
187
207
267
240
Initialize
update-variables
NIL
1
T
OBSERVER

@#$#@#$#@
WHAT IS IT?
------------
This project models the behavior of two types of turtles in a mythical pond. The red turtles and green turtles get along with one another. But each turtle wants to make sure that it lives near some of "its own." That is, each red turtle wants to live near at least some red turtles, and each green turtle wants to live near at least some green turtles. The simulation shows how these individual preferences ripple through the pond, leading to large-scale patterns.

This project was inspired by Thomas Schelling's writings about social systems (such as housing patterns in cities).


HOW TO USE IT
--------------
Click the SETUP button to set up the turtles. There are equal numbers of red and green turtles. The turtles move around until there is at most one turtle on a patch.  Click GO to start the simulation. If turtles don't have enough same-color neighbors, they jump to a nearby patch.

The NUMBER slider controls the total number of turtles. (It takes effect the next time you click SETUP.)  The %-SIMILAR-WANTED slider controls the percentage of same-color turtles that each turtle wants among its neighbors. For example, if the slider is set at 30, each green turtle wants at least 30% of its neighbors to be green turtles.

The "Percent Similar" monitor shows the average percentage of same-color neighbors for each turtle. It starts at about 0.5, since each turtle starts (on average) with an equal number of red and green turtles as neighbors. The "Percent Unhappy" monitor shows the percent of turtles that have fewer same-color neighbors than they want (and thus want to move).  Both monitors are also plotted.


THINGS TO NOTICE
----------------
When you execute SETUP, the red and green turtles are randomly distributed throughout the pond. But many turtles are "unhappy" since they don't have enough same-color neighbors. The unhappy turtles jump to new locations in the vicinity. But in the new locations, they might tip the balance of the local population, prompting other turtles to leave. If a few red turtles move into an area, the local green turtles might leave. But when the green turtles move to a new area, they might prompt red turtles to leave that area.

Over time, the number of unhappy turtles decreases. But the pond becomes more segregated, with clusters of red turtles and clusters of green turtles.

In the case where each turtle wants at least 30% same-color neighbors, the turtles end up with (on average) 70% same-color neighbors. So relatively small individual preferences can lead to significant overall segregation.


THINGS TO TRY
------------
Try different values for %-SIMILAR-WANTED. How does the overall degree of segregation change?

If each turtle wants at least 40% same-color neighbors, what percentage (on average) do they end up with?


NETLOGO FEATURES
----------------
In the UPDATE-GLOBALS procedure, note the use of SUM, COUNT, VALUES-FROM, and WITH to compute the percentages displayed in the monitors and plots.


CREDITS AND REFERENCES
----------------------
Schelling, T. (1978). Micromotives and Macrobehavior. New York: Norton.
Seee also a recent Atlantic article:   Rauch, J. (2002). Seeing Around Corners; The Atlantic Monthly; April 2002;Volume 289, No. 4; 35-48. http://www.theatlantic.com/issues/2002/04/rauch.htm

To refer to this model in academic publications, please use: Wilensky, U. (1998).  NetLogo Segregation model. http://ccl.northwestern.edu/netlogo/models/Segregation. Center for Connected Learning and Computer-Based Modeling, Northwestern University, Evanston, IL.
@#$#@#$#@
default
true
0
Polygon -7566196 true true 150 5 40 250 150 205 260 250

arrow
true
0
Polygon -7566196 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

box
true
0
Polygon -7566196 true true 45 255 255 255 255 45 45 45

circle
true
0
Circle -7566196 true true 35 35 230

person
false
0
Circle -7566196 true true 155 20 63
Rectangle -7566196 true true 158 79 217 164
Polygon -7566196 true true 158 81 110 129 131 143 158 109 165 110
Polygon -7566196 true true 216 83 267 123 248 143 215 107
Polygon -7566196 true true 167 163 145 234 183 234 183 163
Polygon -7566196 true true 195 163 195 233 227 233 206 159

spacecraft
true
0
Polygon -7566196 true true 150 0 180 135 255 255 225 240 150 180 75 240 45 255 120 135

thin-arrow
true
0
Polygon -7566196 true true 150 0 0 150 120 150 120 293 180 293 180 150 300 150

truck-down
false
0
Polygon -7566196 true true 225 30 225 270 120 270 105 210 60 180 45 30 105 60 105 30
Polygon -8716033 true false 195 75 195 120 240 120 240 75
Polygon -8716033 true false 195 225 195 180 240 180 240 225

truck-left
false
0
Polygon -7566196 true true 120 135 225 135 225 210 75 210 75 165 105 165
Polygon -8716033 true false 90 210 105 225 120 210
Polygon -8716033 true false 180 210 195 225 210 210

truck-right
false
0
Polygon -7566196 true true 180 135 75 135 75 210 225 210 225 165 195 165
Polygon -8716033 true false 210 210 195 225 180 210
Polygon -8716033 true false 120 210 105 225 90 210

turtle
true
0
Polygon -7566196 true true 138 75 162 75 165 105 225 105 225 142 195 135 195 187 225 195 225 225 195 217 195 202 105 202 105 217 75 225 75 195 105 187 105 135 75 142 75 105 135 105

@#$#@#$#@
NetLogo 1.3.1
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@