---ogenj.nlogo

NETLOGO

globals [
  initial-trees   ;; how many trees (green patches) we started with
  burned-trees    ;; how many have burned so far
]

breeds [
  fires    ;; bright red turtles -- the leading edge of the fire
  embers   ;; turtles gradually fading from red to near black
]

to setup
  ca
  ;; make some green trees, leaving edges blank so
  ;; the fire can't wrap around the edges of the screen
  ask patches with [abs pxcor < screen-edge-x and
                    abs pycor < screen-edge-y]
    [ if (random-float 100) < gostota 
        [ set pcolor green ] ]
  ;; make a column of burning trees
  ask patches with [pxcor = (- screen-edge-x)]
    [ ignite ]
  ;; set tree counts
  set initial-trees count patches with [pcolor = green]
  set burned-trees 0
end

to go
  if not any? turtles
    [ stop ]
  ask fires
    [ ;; use without-interruption to prevent the same patch
      ;; from igniting multiple times
      without-interruption
        [ ask neighbors4 with [pcolor = green]
            [ ignite ]
          set breed embers ] ]
  fade-embers
end

to ignite  ;; patch procedure
  sprout 1
    [ set breed fires
      set color red ]
  set pcolor black
  set burned-trees burned-trees + 1
end

to fade-embers
  ask embers
    [ set color color - 0.3  ;; make red darker
      if color < red - 4     ;; are we almost at black?
        [ stamp color
          die ] ]
end


; *** NetLogo Model Copyright Notice ***
;
; This model was created as part of the project: CONNECTED MATHEMATICS:
; MAKING SENSE OF COMPLEX PHENOMENA THROUGH BUILDING OBJECT-BASED PARALLEL
; MODELS (OBPML).  The project gratefully acknowledges the support of the
; National Science Foundation (Applications of Advanced Technologies
; Program) -- grant numbers RED #9552950 and REC #9632612.
;
; Copyright 1998 by Uri Wilensky. All rights reserved.
;
; Permission to use, modify or redistribute this model is hereby granted,
; provided that both of the following requirements are followed:
; a) this copyright notice is included.
; b) this model will not be redistributed for profit without permission
;    from Uri Wilensky.
; Contact Uri Wilensky for appropriate licenses for redistribution for
; profit.
;
; This model was converted to NetLogo as part of the project:
; PARTICIPATORY SIMULATIONS: NETWORK-BASED DESIGN FOR SYSTEMS LEARNING IN
; CLASSROOMS.  The project gratefully acknowledges the support of the
; National Science Foundation (REPP program) -- grant number REC #9814682.
; Converted from StarLogoT to NetLogo, 2001.  Updated 2003.
;
; To refer to this model in academic publications, please use:
; Wilensky, U. (1998).  NetLogo Fire model.
; http://ccl.northwestern.edu/netlogo/models/Fire.
; Center for Connected Learning and Computer-Based Modeling,
; Northwestern University, Evanston, IL.
;
; In other publications, please use:
; Copyright 1998 by Uri Wilensky.  All rights reserved.  See
; http://ccl.northwestern.edu/netlogo/models/Fire
; for terms of use.
;
; *** End of NetLogo Model Copyright Notice ***
@#$#@#$#@
GRAPHICS-WINDOW
200
10
612
443
100
100
2.0
0
10
1
1
1

CC-WINDOW
5
252
199
443
Command Center

MONITOR
43
125
164
174
procent po瀏anega
(burned-trees / initial-trees)\n* 100
1
1

SLIDER
5
82
190
115
gostota
gostota
0.0
99.0
57.0
1.0
1
%

BUTTON
106
35
175
71
za鑞i
go
T
1
T
OBSERVER
NIL

BUTTON
26
35
98
71
nastavi
setup
NIL
1
T
OBSERVER
T

@#$#@#$#@
KAJ JE TO?
-----------

Model simulira 歩rjenje ognja skozi gozd. Ogenj se za鑞e 歩riti iz levega kota gozda in se 歩ri po blji瀗jih drevesih. 奿ri se v 歵irih smereh: sever, jug, vzhod, zahod.

V tem modelu ni vklju鑕n veter. Zato mora imeti ogenj na svoji poti drevesa, da se lahko 歩ri. Zato se ogenj ne more 歩riti po nepogozdovanem obmo鑚u. Tako obmo鑚e blokira napredovanje ognja, v njegovem 歩rjenju.

Mo瀗ost da ogenj dose瀍 desni rob gozda je odvisna od gostote dreves v gozdu.


KAKO UPORABLJAMO 
----------------

Klikni na gumb NASTAVI postavi