!!!---itineraries.nlogo

NETLOGO

;;sliders
;;num-travellers the number of travelling Romans
;;to add more maps, save them as png files, and colour the desired routeways red
;;call your map ''your-map.png", and save it in the same folder as the model.
;;then you can choose it from the drop-down list.

globals
[ticks  ;; a counter that updates after each cycle through the 'go' routine
]

turtles-own
[heard-it?   ;; yes or no variable
times-heard-it ;; count of how many times a turtle has encountered another who passes on the 'message'
]

;;;;;;setup routines;;;;;

to setup
ca
 setup-patches
 setup-agents
 set ticks 0   

;; plot the initial state of the world
update-plots
watch turtle 0  ;; this is the original turtle who has the news; turn this line off to remove the 'halo' effect in the view window
end
   
to setup-patches
  file-close-all
  import-pcolors map-choice  ;; imports the map in the map chooser
end


to setup-agents
  create-custom-turtles num-travellers [setup-agent]
    ask turtles [
        set color brown
        set shape "person"
        set heard-it? false  
        set times-heard-it 0
               ]
               
    ask turtle 0 [set heard-it? true
                  set color blue] 
end

to setup-agent   ;;; this puts the turtles on the route
  set size 3
   while [not on-route?] 
    [ 
    setxy random screen-size-x random screen-size-y
    ]
  end

to-report on-route?
  report (abs (pcolor - red) < 5) or  (abs (pcolor - orange) < 5) or  (abs (pcolor - pink) < 5)
end

to go-home ; agent proc
  set pcolor green setup-agent ; prevents turtle from getting 'stuck' on odd pixels.
end

;;;Movement;;

to go
if ticks = 0 [if (count turtles) = 0 [setup]]  
  set ticks ticks + 1
  ask turtles 
    [
     pass-the-word
     move-forward
    ]
    update-plots

if everyone-heard-it = 100
    [stop]

end

to-report everyone-heard-it
report (((count turtles with [ color = blue]) / ( count turtles )) * 100)
end

to move-forward  ; turtle procedure - original from Cruise.netlogo, http://backspaces.net/models/cruise.html
  locals [n p l]
  set n neighbors with [on-route?]
  ifelse count n = 0 [go-home] [
    set l []
    ask patch-left-and-ahead  90 3 [if on-route? [set l lput self l]]
    ask patch-right-and-ahead 90 3 [if on-route? [set l lput self l]]
    if (length l != 0) and (0 = random 3) [ set p random-one-of l ]
    if p = 0      [ set p one-of n with [(heading-angle myself) = 0] ]
    if p = nobody [ set p random-one-of n with [(heading-angle myself) <= 45] ]
    if p = nobody [ set p random-one-of n with [(heading-angle myself) <= 90] ]
    if p = nobody [ set p min-one-of n [heading-angle myself] ]
    set heading towards p
    forward distance p
  ]

end

to-report heading-angle [t] ; patch proc
  locals [h]
  ;set h abs (heading-of t - (towards t + 180) mod 360)
  set h (towards t + 180 - heading-of t) mod 360
  if h > 180 [set h 360 - h]
  report h
end

;;;;Message Transmission;;;

to pass-the-word
ask turtles with [heard-it?]
    [ ask other-turtles-here with [ not heard-it? ]
        [ if (random-float 100) < importance-of-the-news
            [ get-the-word ] ] ]
end

to get-the-word ;; turtle procedure
  set heard-it? true
  set color blue
  set times-heard-it times-heard-it + 1
end

;;;;plots;;;;

to update-plots
update-message-impact
update-message-diffusion
end

to update-message-impact
  set-current-plot "Message Impact"
  set-current-plot-pen "min-heard"
  plot ( min values-from turtles [times-heard-it] ) / 100
  set-current-plot-pen "max-heard"
  plot ( max values-from turtles [times-heard-it] ) / 100
end

to update-message-diffusion
  set-current-plot "Message Diffusion Over Time"
  set-current-plot-pen "%hearing"
  plot ( ((count turtles with [ color = blue]) / ( count turtles )) * 100 )
end
@#$#@#$#@
GRAPHICS-WINDOW
462
10
979
548
150
150
1.6844
1
10
1
1
1
0
0
0
1

CC-WINDOW
5
567
988
662
Command Center
0

BUTTON
6
10
69
43
NIL
setup
NIL
1
T
OBSERVER
T
NIL

BUTTON
79
10
142
43
NIL
go
T
1
T
OBSERVER
T
NIL

SLIDER
220
49
421
82
num-travellers
num-travellers
1
500
200
1
1
NIL

MONITOR
333
91
419
140
Elapsed Time
ticks
0
1

BUTTON
149
10
214
43
Step one
go
NIL
1
T
OBSERVER
T
NIL

MONITOR
215
92
331
141
% Heard the rumour?
everyone-heard-it
0
1

SLIDER
220
10
421
43
importance-of-the-news
importance-of-the-news
1
100
100
1
1
%

PLOT
6
348
421
553
Message Impact
Time
Number of Times Heard
0.0
10.0
0.0
10.0
true
false
PENS
"min-heard" 1.0 0 -16777216 true
"max-heard" 1.0 0 -2674135 true

PLOT
2
141
418
347
Message Diffusion Over Time
Time in Weeks
Percent who've heard the message
0.0
10.0
0.0
10.0
true
false
PENS
"%hearing" 1.0 0 -16777216 true

CHOOSER
51
66
189
111
map-choice
map-choice
"britain.png" "italy.png" "spain.png" "france.png" "thewest.png" "your-map.png"
0

@#$#@#$#@
INTRODUCTION
-----------

This model explores the effect of route network topology on the diffusion of information in the Roman world. 

It was built as part of my research as the Postdoctoral Research Fellow in Roman Archaeology at the University of Manitoba, funded by the Canada Research Chair in Roman Archaeology. It was first presented at the 35th Annual Medieval Workshop, "Cartography in Antiquity and the Middle Ages: Fresh Perspectives, New Methods" at the University of British Columbia on October 28th, in my paper  "The Antonine Itineraries and Agent-Based Modeling".  The comments and critiques offered by the participants of that workshop are gratefully acknowledged. I also am in debt to the participants at the Netlogo workshop at Mesa State College, Grand Junction Co., for teaching me how to develop models in Netlogo.

The information presented here is intended as a preliminary description; an in-depth description of the model and the implications of this simulation will be discussed in print in due course.  To cite this model and this information page, please use:

Graham, S. (2005) "An Agent-Based Exploration of the Antonine Itineraries" http://home.cc.umanitoba.ca/~grahams/itineraries.html

SPACE AND REPRESENTATION
-----------
Most people have a mental image of how places interrelate, how they connect.  There is an excellent cartoon by Gary Larson, where a man wants to get from Point B to Point A. He asks for directions, but the local responds, 態eats me sonny. Most people want to go the other way