---antsopt(1).nlogo

NETLOGO

patches-own [ground pheromone visited]
turtles-own [cost path pathdir]
globals [n-of-turtles latest-cost currentmin currentmax pathlengths]

to setup
ask turtles [die]
ask patches [set ground rand-from-to -3 4]
repeat 10 [diffuse ground 0.3]
ask patches [
    set ground crude ground 0 1]
clear
clear
end


to clear
ask patches with [ground = 0] [set pcolor blue - 1]
ask patches with [ground = 1] [set pcolor brown]
ask patches with [ground = 2] [set pcolor green - 2]
ask patches [set pheromone [1 1 1 1]]
ask patch-at screen-edge-x ((-1) * screen-edge-y) [set pcolor red]
ask patch-at ((-1) * screen-edge-x) screen-edge-y [set pcolor green]
ask patches with [pxcor = ((-1) * screen-edge-x)] [set pheromone nullify pheromone 3]
ask patches with [pxcor = (screen-edge-x)] [set pheromone nullify pheromone 1]
ask patches with [pycor = ((-1) * screen-edge-y)] [set pheromone nullify pheromone 2]
ask patches with [pycor = (screen-edge-y)] [set pheromone nullify pheromone 0]
ask patches [if (value-from patch-at 0 1 [ground]) = 0 [set pheromone nullify pheromone 0]]
ask patches [if (value-from patch-at 1 0 [ground]) = 0 [set pheromone nullify pheromone 1]]
ask patches [if (value-from patch-at 0 -1 [ground]) = 0 [set pheromone nullify pheromone 2]]
ask patches [if (value-from patch-at -1 0 [ground]) = 0 [set pheromone nullify pheromone 3]]
set n-of-turtles 0
set latest-cost 1000000
set currentmin 1000000
set currentmax 0
ask turtles [die]
set pathlengths []
setup-plot
do-plot
end


to recolor
ask patches with [ground = 0] [set pcolor blue - 1]
ask patches with [ground = 1] [set pcolor brown]
ask patches with [ground = 2] [set pcolor green - 2]
ask patch-at screen-edge-x ((-1) * screen-edge-y) [set pcolor red]
ask patch-at ((-1) * screen-edge-x) screen-edge-y [set pcolor green]
end

to-report crude [val lo hi]
if val < lo [report 0]
if val > hi [report 2]
report 1
end


to turtle-step
locals [rdir dirvec]
;set dirvec value-from patch-here [pheromone]
;show dirvec
;if (value-from patch-at 0 1 [visited]) [set dirvec nullify dirvec 0] 
;if (value-from patch-at 1 0 [visited]) [set dirvec nullify dirvec 1] 
;if (value-from patch-at 0 -1 [visited]) [set dirvec nullify dirvec 2] 
;if (value-from patch-at -1 0 [visited]) [set dirvec nullify dirvec 3] 
;set heading random-dir dirvec

set heading random-dir value-from patch-here [pheromone]
set pathdir fput (int (heading / 90)) pathdir
forward 1
set cost (cost + value-from patch-here [ground])
set path fput (list xcor ycor) path 
ask patch-here [ifelse ground = 1 [set pcolor turquoise - 1] [set pcolor turquoise - 2]]
ask patch-here [set visited true]
end

to-report arrived?
report (xcor >= (screen-edge-x - 0.1)) and (ycor <= (-1) * (screen-edge-y) + 0.1)
end


to walk
set n-of-turtles n-of-turtles + 1
set path fput (list ((-1) * screen-edge-x) screen-edge-y) []
set pathdir []
setxy ((-1) * screen-edge-x) screen-edge-y
while [not arrived?] [turtle-step]
end

to single-walk
crt 1 
;ask patches [set visited false]
ask turtles [walk]
do-plot
end

to retrace
locals [currind currcost localpathdir localpath]
;show length path
if remove-loops?
    [
    set localpath remove-loops path
    set localpathdir stepdirs localpath
    set path localpath
    set pathdir localpathdir
    ]
set path butfirst path
set currcost cost

set latest-cost cost
set currentmin min list latest-cost currentmin
set currentmax max list latest-cost currentmax
set pathlengths fput cost pathlengths
;show length path
while [not empty? path] [
        setxy first first path last first path 
        set currind first pathdir
;        set currind first localpathdir
        ask patch-here [ 
                ifelse ground = 1 [set pcolor yellow - 1] [set pcolor yellow - 2]
                set pheromone replace-item currind pheromone 
                        ((item currind pheromone) + (increment currcost))] 
        set pathdir butfirst pathdir 
;        set localpathdir butfirst localpathdir 
        set path butfirst path
      ]
end

to-report random-dir [weightvec]
locals [randnum probvec]
set probvec cumsum normalize weightvec
set randnum random-int-or-float 1.0
if randnum < (item 0 probvec) [report 0]
if randnum < (item 1 probvec) [report 90]
if randnum < (item 2 probvec) [report 180]
report 270
end

to-report nullify [l index]
if empty? l [report l] 
if index = 0 [report fput 0 butfirst l]
report fput first l nullify butfirst l (index - 1)
end

to-report addlists [l1 l2]
if empty? l1 [report l2]
if empty? l2 [report l1]
report fput ((first l1) + (first l2)) (addlists (butfirst l1) (butfirst l2))
end

to-report normalize [l]
report scalmult (1 / (sum l))   l
end

to-report scalmult [factor l]
if empty? l [report l]
output fput (factor * first l) scalmult factor butfirst l
end

to-report scaladd [scalar l]
if empty? l [report l]
output fput (scalar + first l) scaladd scalar butfirst l
end


to-report vecadd [vec1 vec2]
if empty? vec1 [report vec2]
if empty? vec2 [report vec1]
report fput ((first vec1) + (first vec2)) vecadd butfirst vec1 butfirst vec2
end

to-report cumsum [l]
if empty? l [report l]
report fput (first l) scaladd (first l) (cumsum butfirst l)
end

to runs
repeat n-of-runs [
    full-turtle-run]
end

to full-turtle-run
single-walk
wait delay / 10
recolor
ask turtles [retrace]
ask turtles [show cost]
wait delay / 10
ask turtles [die]
recolor
end

to-report rand-from-to [a b]
report (random-int-or-float (b - a + 0.0)) + a
end

to-report increment [x]
report (2000 ^ 3) / (x ^ 3)
end


to-report second [l]
report first butfirst l
end

to-report stepdirs [coordlist]
if (length coordlist = 1) [report []]
output fput dir-from-step (list ((first first coordlist) - (first second coordlist))
                  ((second first coordlist) - (second second coordlist)))
            stepdirs butfirst coordlist  
end

to-report dir-from-step [step]
if ((first step) = 0) and ((second step) = 1) [report 0]
if ((first step) = 1) and ((second step) = 0) [report 1]
if ((first step) = 0) and ((second step) = -1) [report 2]
if ((first step) = -1) and ((second step) = 0) [report 3]
end


to-report remove-loops [p]
  locals [loopitem initend reststart intermediate]
  if double-free? p [report p] 
  set loopitem first-double p
  set initend position loopitem p
  set reststart lastpos loopitem p
  set intermediate sentence (segment p  0 initend) (segment p (1 + reststart) length p)
  report remove-loops intermediate
end

to-report first-double [p]
  if empty? p [report []]
  if member? (first p) (butfirst p) [report first p]
  report first-double butfirst p
end

to-report lastpos [el p]
   report ((length p) - position el reverse p) - 1   
end

to-report iseq [a b]
   report n-values ((b - a) + 1) [a + ?]
end

to-report segment [p start finish]
    report map [item ? p] iseq (ifelse-value (start < 0) [0] [start]) (ifelse-value (finish >= length p) [(length p) - 1] [finish])  
end

to-report double-free? [p]
  if empty? p [report true]
  if member? first p butfirst p [report false]
  output double-free? butfirst p
end



to-report cut-head [p num]
  if (num < 1) [report p]
  report cut-head butfirst p (num - 1)
end


to setup-plot
  set-current-plot "Path length"
  set-plot-x-range  0 10 * (screen-edge-x * screen-edge-y)
  set-plot-y-range 0 10
  set-histogram-num-bars 10
end

to do-plot
  set-histogram-num-bars 10
;  set-plot-x-range  0 50 * (screen-edge-x * screen-edge-y)
  set-plot-x-range  0 histwidth
  set-plot-y-range  0 max list 10 n-of-turtles
  set-histogram-num-bars 20
  histogram-list pathlengths          ; using the default plot pen
end



@#$#@#$#@
GRAPHICS-WINDOW
321
10
672
228
15
8
11.0
1
10
1
1
1

CC-WINDOW
329
295
644
415
Command Center

BUTTON
24
10
105
43
NIL
setup
NIL
1
T
OBSERVER
T

BUTTON
25
87
106
120
NIL
runs
NIL
1
T
OBSERVER
T

SLIDER
111
87
283
120
n-of-runs
n-of-runs
1
100
1
1
1
NIL

SWITCH
25
50
175
83
remove-loops?
remove-loops?
1
1
-1000

BUTTON
112
10
193