---prob graphs basic.nlogo

NETLOGO

globals [
  event
  total-attempts
  total-successes
  counter
  counter-list 
  successes-per-sample-list
  attempts-this-sample
  successes-this-sample
  samples-counter ]

to setup  ;; resets everything to appropriate initial values
  ca
  set event "-"
  set total-attempts 0  
  set total-successes 0
  set counter 0  
  set counter-list []
  set attempts-this-sample 0
  set successes-this-sample 0
  set samples-counter 0
  set successes-per-sample-list []
end

to go
  if samples-counter = how-many-samples? [stop]
  set total-attempts total-attempts + 1
  set counter counter + 1
  select-and-check
  update-and-plot
end    

to select-and-check  
  ;; This procedure simulates a chance event by randomly selecting a number between 1 and
  ;; sample-space-size, for instance between 1 and 5, as if you are rolling a die with 5
  ;; sides. Next, the procedure checks to see if this event (what you "rolled") happens to
  ;; be '1.' A '1' is a success. Note that 'random' reports a number between 0 and value,
  ;; so "random 1" is only 0, and "random 2" is 0 or 1. That is why we have to add 1.
  set event ( 1 + random sample-space-size )
  if  event = 1
    [
     set total-successes total-successes + 1
     set counter-list lput counter counter-list
     set counter 0
     set successes-this-sample successes-this-sample + 1
    ]
end

to update-and-plot  ;; updates values for each of the three plots
  update-and-plot-m/n
  update-and-plot-Attempts
  update-and-plot-successes
end

to update-and-plot-m/n
  set-current-plot "m/n convergence to limiting value"
  plot (total-successes / total-attempts)
end

to update-and-plot-Attempts
  if length counter-list = 0 [stop]
  set-current-plot "Attempts-until-Success Distribution"
  
  ;; setting the range just beyond the maximum value (e.g.,5 beyond but it could be more or less)
  ;; helps the eye pick up that the right-most value is indeed the maximum value
  set-plot-x-range 0 ( (max counter-list) + 5)
  histogram-list counter-list
end

to update-and-plot-successes
  set attempts-this-sample attempts-this-sample + 1
  if attempts-this-sample = sample-size 
  [
    set successes-per-sample-list lput successes-this-sample successes-per-sample-list
    set-current-plot "Successes-per-Sample Distribution"
    
    ;; This line adjusts the top range of the x-axis so as to stabilize and centralize
    ;; the distribution. The idea is to try and keep the emergent graph shape in the
    ;; middle of the plot. The 'ceiling' primitive keeps the maximum range value an integer.
    set-plot-x-range 0 ( max ( list plot-x-max
                                    ( 3 + ( ceiling ( 2 * mean successes-per-sample-list ) ) ) ) )
    histogram-list successes-per-sample-list
    set attempts-this-sample 0
    set successes-this-sample 0
    set samples-counter samples-counter + 1     
  ]
end

; *** NetLogo Model Copyright Notice ***
;
; This model was created as part of the project:
; PARTICIPATORY SIMULATIONS: NETWORK-BASED DESIGN FOR SYSTEMS LEARNING IN
; CLASSROOMS.  The project gratefully acknowledges the support of the
; National Science Foundation (REPP program) -- grant number REC #9814682.
;
; Copyright 2002 by Uri Wilensky.  Updated 2003.  All rights reserved.
;
; Permission to use, modify or redistribute this model is hereby granted,
; provided that both of the following requirements are followed:
; a) this copyright notice is included.
; b) this model will not be redistributed for profit without permission
;    from Uri Wilensky.
; Contact Uri Wilensky for appropriate licenses for redistribution for
; profit.
;
; To refer to this model in academic publications, please use:
; Wilensky, U. (2002).  NetLogo Prob Graphs Basic model.
; http://ccl.northwestern.edu/netlogo/models/ProbGraphsBasic.
; Center for Connected Learning and Computer-Based Modeling,
; Northwestern University, Evanston, IL.
;
; In other publications, please use:
; Copyright 1998 by Uri Wilensky.  All rights reserved.  See
; http://ccl.northwestern.edu/netlogo/models/ProbGraphsBasic
; for terms of use.
;
; *** End of NetLogo Model Copyright Notice ***
@#$#@#$#@
GRAPHICS-WINDOW
240
30
495
68
17
0
7.0
1
10
1
1
1
0
1
1
1

CC-WINDOW
5
623
743
718
Command Center
0

BUTTON
99
55
178
101
NIL
go
T
1
T
OBSERVER
T
NIL

BUTTON
4
55
83
101
NIL
setup
NIL
1
T
OBSERVER
T
NIL

PLOT
201
55
543
238
m/n convergence to limiting value
Attempts
Successes per Attempts
0.0
100.0
0.0
1.0
true
false

PLOT
201
239
543
399
Attempts-until-Success Distribution
Run Length
Frequency
1.0
50.0
0.0
10.0
true
false
PENS
"default" 1.0 1 -16777216 true

SLIDER
6
199
181
232
sample-space-size
sample-space-size
1
10
2
1
1
NIL

PLOT
201
398
543
559
Successes-per-Sample Distribution
Successes
Frequency
0.0
10.0
0.0
25.0
true
false
PENS
"default" 1.0 1 -16777216 true

SLIDER
9
481
181
514
sample-size
sample-size
0
100
10
5
1
NIL

SLIDER
7
395
181
428
how-many-samples?
how-many-samples?
0
1000
300
10
1
NIL

MONITOR
547
132
646
181
NIL
total-attempts
3
1

MONITOR
677
86
734
135
rate
total-successes / total-attempts
3
1

MONITOR
547
55
646
104
total-successes
total-successes
0
1

TEXTBOX
548
109
674
127
________________     =

MONITOR
546
399
693
448
NIL
successes-this-sample
3
1

MONITOR
9
515
181
564
NIL
attempts-this-sample
3
1

MONITOR
546
239
603
288
NIL
counter
3
1

MONITOR
8
429
181
478
NIL
samples-counter
3
1

MONITOR
442
560
543
609
max
max successes-per-sample-list
3
1

MONITOR
201
560
305
609
min
min successes-per-sample-list
3
1

MONITOR
322
560
426
609
mean
mean successes-per-sample-list
3
1

TEXTBOX
6
103
136
199
The program will record and plot the random occurrence of the event "1" among other integers in the sample space of size...

MONITOR
546
290
603
339
mean
mean counter-list
3
1

TEXTBOX
312
10
402
28
speed slider

MONITOR
140
118
190