---josephson-cooperative.nlogo

NETLOGO

; NetLogo Model: josephson-cooperative :: Version: 0.4.3 (21 Oct 2003)
; Author: S. Maggi :: NetLogo version: 1.3.1 (for Mac OS X)
; -----------------------------------------------------------------------------

; Global variables:
;    population = turtle population (equal to the width of the graphics window)
;    pi2        = 2 x 3.14159...
;
; Variables belonging to each turtle:
;    tau    = current simulation time
;    phi    = phase difference at time tau
;    phidot = derivative of the phase at time tau
 
globals     [population pi2]
turtles-own [tau phi phidot]


; Setup of simulation: clears Graphics window, sets some constants and defines 
; characteristics of turtle population
to setup
   clear-all

   set pi2    2 * pi
   set plot?  false

; The turtle population is set equal to the total width of the Graphics window
   set population screen-size-x
   create-turtles population

; Turtle setup: the initial coordinates of the turtles are:
; [x = -screen-edge-x, -screen-edge-x + 1, ... +screen-edge-x;  y = 0],
; i.e., the turtles are distributed along the y = 0 axis of the Graphics window
   ask turtles [set tau    0.0
                set phi    phi-0
                set phidot phidot-0
                set color yellow
                set heading 0
                setxy (who - screen-edge-x) 0
               ]
   setup-plot
end


; Default simulation parameters (set by pressing the Default params button)
to default
   set dtau      0.1
   set phi-0     0.0
   set phidot-0  0.0

   set alpha-dc  0.0
   set beta-c    0.1
   set alpha-rf  0.0
   set omega-rf  0.0
  
   set slowdown  0
   set y-ampl    5
end


; Main simulation loop
to go
   without-interruption [solve-diff-eq
                         if plot? [do-plot]
                         wait (slowdown / 500)
                        ]
end


; Solve the 2nd order differential equation using a finite difference method
to solve-diff-eq
   locals [who-1 who+1 ntc
           tau_n phi_n phi_n+1
           phidot_n phidot_n+1
          ]

   set ntc (dtau / beta-c)

   without-interruption
      [set who-1    who-of    turtle ( (who - 1) mod screen-size-x )
       set who+1    who-of    turtle ( (who + 1) mod screen-size-x )
       set tau_n    tau-of    turtle    who
       set phi_n    phi-of    turtle    who
       set phidot_n phidot-of turtle    who

; this finite-difference method does not work because of numerical instabilities
    ;locals [phi_n-1]
    ;set phi_n-1  phi-of  turtle who-1
    ;set phi_n+1  ( (2 * beta-c + dtau) * phi_n - (beta-c) * phi_n-1 + (dtau ^ 2) * (alpha-dc + alpha-rf * sin (rad-to-deg (tau_n * omega-rf) ) - sin (rad-to-deg phi_n) ) ) / (beta-c + dtau)

; this finite-difference method works!
       set phidot_n+1 (1 - ntc) * phidot_n + ntc * ( alpha-dc + alpha-rf * sin (rad-to-deg (omega-rf * tau_n)) - sin (rad-to-deg (phi_n)) )
       set phi_n+1    (phi_n + phidot_n+1 * dtau)

       ask turtle who+1 [set tau    (tau_n + dtau)
                         set phi    (phi_n+1) mod pi2
                         set phidot (phidot_n+1)
                         set ycor   (y-ampl * phidot)
                        ]
      ]
end


; This procedure converts an angle from radians to degrees (as used by NetLogo).
;   input: 'angle' in radians
;   report: angle converted to degrees
to-report rad-to-deg [angle]
   report angle * 360 / pi2
end

; This procedure sets up the phase-space plot
to setup-plot
   set-current-plot "Phase space"
   auto-plot-on
   set-plot-x-range  -3.2  3.2
   set-plot-y-range  -1.0  1.0
   set-plot-pen-mode  2
   set-plot-pen-color blue
end

to do-plot
   set-current-plot "Phase space"
   plotxy (phi mod pi2 - pi) phidot
; one could also plot the cosine of phi instead of phi
;   plotxy cos (rad-to-deg phi) phidot
end

to reset-plot
   setup-plot
   plot-pen-reset
   set plot? false
end
@#$#@#$#@
GRAPHICS-WINDOW
210
30
621
365
200
150
1.0
1
10
1
1
1

TEXTBOX
20
20
180
38
Simulation settings:

SLIDER
15
40
185
73
dtau
dtau
0.0020
0.2
0.1
0.0020
1
NIL

SLIDER
15
80
185
113
phi-0
phi-0
0
6.4
0.0
0.2
1
NIL

SLIDER
15
120
185
153
phidot-0
phidot-0
0
6.4
0.0
0.2
1
NIL

TEXTBOX
20
180
180
198
Junction parameters:

SLIDER
15
200
185
233
alpha-dc
alpha-dc
-10
10
0.0
0.1
1
NIL

SLIDER
15
240
185
273
beta-c
beta-c
0.1
2.5
0.1
0.2
1
NIL

SLIDER
15
290
185
323
alpha-rf
alpha-rf
0
10
0.0
0.1
1
NIL

SLIDER
15
330
185
363
omega-rf