---peernet.nlogo

NETLOGO

; ToDo: Seth Tisue: Make inEdges/outEdges lists of turtles thus agentlists
; Make controls clearer w/ In/Out labels
;
globals [
    steps         ; Number of steps the model has made (think hours for peers)
    graphs        ; List of connected sub graphs in peer network
    maxgraph      ; The ID of the graph with the largest number of nodes
    percent       ; Percent of total maxgraphsize is
    maxgraphsize  ; The number of nodes is has
    totalEdges    ; Total number of edges
]
turtles-own [
    inEdges       ; List of IDs of nodes pointing to me
    outEdges      ; List of IDs of nodes I point to
    numOutEdges   ; Number of out edges I'm supposed to maintain
    nhood         ; The nodes in my neighborhood
    ttl           ; The number of steps until I go off the air
    graph         ; The subnet I currently belong to
]
to-report edgeCount
    report length outEdges + length inEdges
end
to setup
    clear-all
    set-default-shape turtles "circle"
    set steps 0
    create-custom-turtles (screen-size-x * screen-size-y) [
        set ycor (screen-edge-y - floor (who / screen-size-x))
        set xcor (who mod screen-size-x) - screen-edge-x
        set color gray
        set inEdges []
        set outEdges []
        set ttl 0
        set numOutEdges 0
        ifelse drawLabels? [set label  0 + " "][set label no-label]
    ]
    ask turtles [ ; need second pass for nhood: all turtles created & in place
        set nhood turtles with [
            (distance myself <= radiusRange) and (who != who-of myself)
        ]
    ]
end
to step
    set steps steps + 1
    ask turtles [
        ifelse (ttl = 0) [
            if ( random 100 < birthProbability ) [createNode]
        ] [
            set ttl ttl - 1
            if (ttl = 0) [destroyNode]
        ]
    ]
    ; nodes may need to add links anytime they are reduced
    ; by deletions or because there were previously too 
    ; few "on" neighbors available
    ask turtles with [numOutEdges > length outEdges] [
        addOutEdges (numOutEdges - length outEdges)
    ]
    calcGraphs
    set totalEdges 0
    ask turtles [
        ;set edgeCount length outEdges + length inEdges
        ifelse (ttl = 0) [hideturtle][
            set totalEdges totalEdges + edgeCount
            set color (position graph graphs) * 10 + red
            ifelse drawLabels? 
                [set label (length outEdges + length inEdges) + " "]
                [set label no-label]
            showturtle
        ]
    ]
    set totalEdges totalEdges / 2 ; Resolve double count
    doPlots
end
to createNode
    set ttl 1 + random lifeRange
    set numOutEdges 1 + random edgesRange
end
to destroyNode
    locals [myID]
    set ttl 0
    set numOutEdges 0
    set myID who
    ask nhood [
        set inEdges remove myID inEdges
        set outEdges remove myID outEdges
    ]
    set inEdges []
    set outEdges []
end
to addOutEdges [numEdges]
    locals [myID theirID them]
    set myid who
    repeat numEdges [
        set them random-one-of nhood with [
            not (member? myID outEdges or member? myID inEdges or ttl = 0)
        ]
        if (them != nobody) [
            ask them [
                set inEdges fput myID inEdges
                set theirID who
            ]
            set outEdges fput theirID outEdges
        ]
    ]
end
to calcGraphs
    locals[stack node edges graphsize]
    set graphs [] ; reset list of graphs
    set maxgraphsize 0
    ask turtles [set graph -1] ; reset which graph each turtle belongs to
    ask turtles with [ttl > 0] [
        ; important! must be sequential due to state kept in turtles
        without-interruption [ 
            if (graph = -1) [ ; if this turtle not yet in a graph, make root of next graph
                set stack [] ; stack of current batch of turtles to be processed
                set stack fput turtle who stack
                set graph who
                set graphs lput who graphs
                set graphsize 0
                while [length stack > 0] [
                    set node first stack
                    set stack but-first stack
                    set graphsize graphsize + 1
                    set edges sentence inEdges-of node outEdges-of node
                    while [length edges > 0] [
                        set node turtle first edges
                        set edges but-first edges
                        if (graph-of node = -1) [
                            set graph-of node who
                            set stack lput node stack
                        ]
                    ]
                    if (graphsize > maxgraphsize) [
                        set maxgraph who
                        set maxgraphsize graphsize
                    ]
                ]
            ]
        ]
    ]
    set graphs sentence maxgraph remove maxgraph graphs
    set percent maxgraphsize / count turtles with [ ttl > 0 ]
end
to doPlots
    set-current-plot "Nodes"
    set-current-plot-pen "One"
        plot count turtles with [edgeCount = 1]
    set-current-plot-pen "Two"
        plot count turtles with [edgeCount = 2]
    set-current-plot-pen "Three"
        plot count turtles with [edgeCount = 3]
    set-current-plot-pen "Four"
        plot count turtles with [edgeCount = 4]
    set-current-plot-pen "Five"
        plot count turtles with [edgeCount = 5]
    set-current-plot-pen "Six"
        plot count turtles with [edgeCount = 6]
    set-current-plot-pen ">Six"
        plot count turtles with [edgeCount > 6]
    set-current-plot "EdgeHistogram"
    set-histogram-num-bars 10
    histogram-from turtles with [ttl > 0] [edgeCount]
end
@#$#@#$#@
GRAPHICS-WINDOW
309
10
739
461
10
10
20.0
1
12
0
0
0

CC-WINDOW
309
467
731
587
Command Center

BUTTON
6
43
61
76
NIL
setup
NIL
1
T
OBSERVER
T

SLIDER
131
79
303
112
lifeRange
lifeRange
1
10
4
1
1
NIL

BUTTON
6
78
61
111
NIL
step
NIL
1
T
OBSERVER
T

SLIDER
131
117
303
150
radiusRange
radiusRange
1
5
2
1
1
NIL

SLIDER
131
42
303
75
birthProbability
birthProbability
1
100
20
1
1
NIL

SLIDER
131
153
304
186
edgesRange
edgesRange
1
8
2
1
1
NIL

BUTTON
6
112
62
145
go
step
T
1
T
OBSERVER
T

MONITOR
67
44
124
93
NIL
steps