generate_prbs.asm

移动通讯PHY设计中用到的数据块的随机序列产生模块

/*****************************************************************************
Copyright (c) 2005 Analog Devices.  All Rights Reserved.

Developed by Analog Devices Australia - Unit 3, 97 Lewis Road,
Wantirna, Victoria, Australia, 3152.  Email: [e-mail]

THIS SOFTWARE IS PROPRIETARY & CONFIDENTIAL.  By using this module you
agree to the terms of the associated Analog Devices License Agreement.
******************************************************************************

Project:        IEEE 802.16 Library
Title:          Generate PRBS
Author(s):      Luke Mawbey ([e-mail])
Revised by:

Description:
                Generates a PRBS as described in section 8.4.9.4.1 of
                [1]

References:
                [1] IEEE 802.16-2004

******************************************************************************
Target Processor:           SPARC, i686, ADSP-TS201
Target Tools Revision:      gcc 3.2, ccts 7.0.7.2
*****************************************************************************/

/*void generate_prbs_c(bit32x1 state,
                     unsigned length,
                     bit32x1 *prbs)
*/
.section program;
.global _generate_prbs;
.align_code 4;

_generate_prbs:

// Section 1
    XR0 = J4;               R11 = 0x7FF;        XR1 = lshift R1 by 32;;

    XR0 = R0 and R11;;

    XLR5:4 = lshift R1:0 by -2;         J10 = J5 - 1;;

    XLR5:4 = R5:4 XOR R1:0;;

    XLR3:2 = lshift R5:4 by 9;;
    XLR7:6 = lshift R5:4 by 11;         R10 = J10;;
    XLR5:4 = R5:4 XOR R3:2;;

    XLR5:4 = R5:4 XOR R7:6;;

    XLR3:2 = lshift R5:4 by 18;;
    XLR7:6 = lshift R5:4 by 22;;
    XLR5:4 = R5:4 XOR R3:2;             R10 = lshift R10 by -6;;

    XLR5:4 = R5:4 XOR R7:6;;

    XLR3:2 = lshift R5:4 by 36;         R10 = inc R10;;
    XLR7:6 = lshift R5:4 by 44;         R11 = 0xFFFFFF;;
    XLR5:4 = R5:4 xor R3:2;;

    XLR5:4 = R5:4 xor R7:6;;

    XLR3:2 = lshift R5:4 by -9;         R13 = 24;;
    XLR7:6 = lshift R5:4 by -17;        LC0 = xr10;;
    XLR5:4 = lshift R5:4 by 11;;
    XLR7:6 = R3:2 xor R7:6;;
    XLR5:4 = R5:4 xor R1:0;;

Loop_process_64_bits:
    XLR9:8 = lshift R5:4 by -16;        L[J6+=2] = XR5:4;;
    XR10 = lshift R6 by 16;;
    XR14 = R6 and R11;;
    XR9 = R9 or R10;;
//stall
    XLR9:8 = R5:4 xor R9:8;      XR4 = lshift R14 by 0;;
//stall
    XR5:4 += putbits R9:8 by R13:12;;
    if nlc0e, jump Loop_process_64_bits; XR7:6 = BFOTMP;;


.align_code 4;
    cjmp(abs);;

_generate_prbs.end: