thisdocument.vb

讲解visual studio的应用

Public Class ThisDocument

    Private WithEvents SaveCompanyName As Microsoft.Office.Tools.Word.Action
    Private WithEvents DisplayCompanyValue As Microsoft.Office.Tools.Word.Action

    Private MainPane As New MainActions
    Private TableAreaPane As New CompanyNameActions

    Private Sub TableArea_Selected(ByVal sender As Object, _
        ByVal e As Microsoft.Office.Tools.Word.SelectionEventArgs) Handles _
        TableArea.Selected

        Me.ActionsPane.Controls.Add(TableAreaPane)

    End Sub
    Private Sub TableArea_Deselected(ByVal sender As Object, _
        ByVal e As Microsoft.Office.Tools.Word.SelectionEventArgs) Handles _
        TableArea.Deselected

        Me.ActionsPane.Controls.Remove(TableAreaPane)

    End Sub
    Private Sub AddCompanySmartTag()
        Dim CompanyDetails As New Microsoft.Office.Tools.Word.SmartTag( _
            "www.test.com/CompanyDetails#CompanyDetailsSample", "Company Details")

        CompanyDetails.Terms.Add("Microsoft")
        CompanyDetails.Terms.Add("ParsonsDesigns")
        CompanyDetails.Terms.Add("AutumnCare")
        CompanyDetails.Terms.Add("Wrox")
        CompanyDetails.Terms.Add("Wiley")

        SaveCompanyName = New Microsoft.Office.Tools.Word.Action("Save Name")
        DisplayCompanyValue = New Microsoft.Office.Tools.Word.Action("Show Details")

        CompanyDetails.Actions = New Microsoft.Office.Tools.Word.Action() _
            {SaveCompanyName, DisplayCompanyValue}

        Me.VstoSmartTags.Add(CompanyDetails)
    End Sub

    Sub SaveCompanyName_BeforeCaptionShow(ByVal sender As Object, _
    ByVal e As Microsoft.Office.Tools.Word.ActionEventArgs) Handles _
    SaveCompanyName.BeforeCaptionShow

        SaveCompanyName.Caption = "Save " & e.Text & " to name list"
    End Sub

    Sub DisplayCompanyValue_BeforeCaptionShow(ByVal sender As Object, _
        ByVal e As Microsoft.Office.Tools.Word.ActionEventArgs) Handles _
        DisplayCompanyValue.BeforeCaptionShow

        DisplayCompanyValue.Caption = "Display information about " & e.Text
    End Sub

    Sub SaveCompanyName_Click(ByVal sender As Object, _
        ByVal e As Microsoft.Office.Tools.Word.ActionEventArgs) Handles _
        SaveCompanyName.Click

        TableAreaPane.NameList.Items.Add(e.Text)
    End Sub
    Sub DisplayCompanyValue_Click(ByVal sender As Object, _
    ByVal e As Microsoft.Office.Tools.Word.ActionEventArgs) Handles _
    DisplayCompanyValue.Click

        Dim TempValue As String = vbNullString
        Select Case e.Text
            Case "Microsoft"
                TempValue = "NO COMPLAINTS"
            Case "ParsonsDesigns"
                TempValue = "UH OH"
            Case "AutumnCare"
                TempValue = "COULD BE BETTER"
            Case "Wrox"
                TempValue = "SOLID GOLD"
            Case "Wiley"
                TempValue = "SKY HIGH"
        End Select

        MessageBox.Show("The current value of " & e.Text & " is " & TempValue)
    End Sub

    Private Sub SaveAuthorName_Click(ByVal sender As System.Object, _
        ByVal e As System.EventArgs) Handles SaveAuthorName.Click

        Me.BuiltInDocumentProperties("Author").value = DocAuthorName.Text
        MessageBox.Show("The Author Name property has been set to " & _
            DocAuthorName.Text & ". You can check by looking at File->Properties.")
    End Sub

    Private Sub ThisDocument_Startup(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.Startup

        AddCompanySmartTag()
        DocumentSummary.Select()

        Me.ActionsPane.Controls.Add(MainPane)
        MainPane.HeadingAreaRef = DocumentHeading
    End Sub

    Private Sub ThisDocument_Shutdown(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.Shutdown

    End Sub

End Class