configure.in

嵌入式下基于MiniGUI的Web Browser

dnl Process this file with autoconf to produce a configure script.
AC_PREREQ(2.52)
AC_INIT(src/edillo.c)

eDillo_VERSION=0.4.0

dnl ========================================================================
dnl needed for cross-compiling
AC_CANONICAL_SYSTEM

dnl ========================================================================
dnl Checks for programs.
dnl AC_PROG_CC
AC_PROG_LD
AC_PROG_RANLIB
AC_PROG_LIBTOOL
AC_PROG_MAKE_SET
AC_PROG_LN_S

AM_INIT_AUTOMAKE(edillo,$eDillo_VERSION,-)

dnl ========================================================================
dnl Checks for typedefs, structures, and compiler characteristics.
AC_C_CONST

dnl ========================================================================
dnl Checks for header files.
AC_HEADER_STDC
AC_HEADER_SYS_WAIT
AC_HEADER_TIME
AC_CHECK_HEADERS(sys/time.h unistd.h)

using_pthread="yes"

build_gif="yes"
build_animation="yes"
build_jpg="yes"
build_png="yes"
build_bmp="yes"
build_ipv6="no"
build_ssl="no"
build_digitallink="no"
build_tvoutput="no"
build_cookie="no"

AC_ARG_ENABLE(pthread,
[  --enable-pthread         enable PThread support <default=yes>],
build_ptread=$enableval)

AC_ARG_ENABLE(gif,
[  --enable-gif             enable GIF image support <default=yes>],
build_gif=$enableval)

AC_ARG_ENABLE(jpeg,
[  --enable-jpeg            enable JPEG image support <default=yes>],
build_jpg=$enableval)

AC_ARG_ENABLE(png,
[  --enable-png             enable PNG image support <default=yes>],
build_png=$enableval)

AC_ARG_ENABLE(bmp,
[  --enable-bmp             enable BMP image support <default=yes>],
build_bmp=$enableval)

AC_ARG_ENABLE(ipv6,
[  --enable-ipv6            enable IPv6 support <default=no>],
build_ipv6=$enableval)

AC_ARG_ENABLE(ssl,
[  --enable-ssl             enable SSL features (eg. https) <default=no>], 
build_ssl=$enableval)

AC_ARG_ENABLE(animation,
[  --enable-animation       enable GIF Animation support <default=yes>],
build_animation=$enableval)

AC_ARG_ENABLE(digitallink,
[  --enable-digitallink     showing a number before the hyperlink <default=no>],
build_digitallink=$enableval)

AC_ARG_ENABLE(tvoutput,
[  --enable-tvoutput        rendering text for TV <default=no>],
build_tvoutput=$enableval)

AC_ARG_ENABLE(cookies,
[  --enable-cookies         include support for cookies <default=no>],
build_cookie=$enableval)

dnl Check for JPEG library.
if test "x$build_jpg" != "xno"; then
  AC_CHECK_LIB(jpeg, jpeg_std_error,
  SYSTEM_LIBS="$SYSTEM_LIBS -ljpeg",
  build_jpg=no, -lm)
fi

dnl Check for PNG library.
if test "x$build_png" != "xno"; then
  AC_CHECK_LIB(png, png_check_sig,
  SYSTEM_LIBS="$SYSTEM_LIBS -lpng -lz",
  build_png=no, -lm)
fi

dnl Check for SSL Library

if test "x$build_ssl" = "xyes"; then
  AC_CHECK_HEADER(openssl/ssl.h, ssl_ok=yes, ssl_ok=no)

  if test "x$ssl_ok" = "xyes"; then
    old_libs="$LIBS"
    AC_CHECK_LIB(ssl, SSL_library_init, ssl_ok=yes, ssl_ok=no, -lcrypto)
    LIBS="$old_libs"
  fi

  if test "x$ssl_ok" = "xyes"; then
    SYSTEM_LIBS="-lcrypto -lssl"
  else
    AC_MSG_WARN([*** No libssl found. Disabling ssl support.***])
  fi
fi

if test "x$ssl_ok" = "xyes"; then
  AC_DEFINE(ENABLE_SSL, 1, [Enable SSL support])
fi

AM_CONFIG_HEADER(mgdconfig.h)

AC_DEFINE(EDILLO_VERSION, "0.4.0", [version of eDillo])

if test "x$using_pthread" = "xyes"; then
  AC_DEFINE(ENABLE_PTHREADS, 1, [Define if using PThreads])
fi

if test "x$build_gif" = "xyes"; then
  AC_DEFINE(ENABLE_GIF, 1, [Define if support GIF image format])
fi

if test "x$build_jpg" = "xyes"; then
  AC_DEFINE(ENABLE_JPEG, 1, [Define if support JPEG image format])
  SYSTEM_LIBS="$SYSTEM_LIBS -ljpeg"
fi

if test "x$build_png" = "xyes"; then
  AC_DEFINE(ENABLE_PNG, 1, [Define if support PNG image format])
  SYSTEM_LIBS="$SYSTEM_LIBS -lpng"
fi

if test "x$build_bmp" = "xyes"; then
  AC_DEFINE(ENABLE_BMP, 1, [Define if support BMP image format])
fi

if test "x$build_ipv6" = "xyes"; then
  AC_DEFINE(ENABLE_IPV6, 1, [Define if support IPv6])
fi

if test "x$build_animation" = "xyes"; then
  AC_DEFINE(ENABLE_ANIMATION, 1, [Define if support GIF Animation])
fi

if test "x$build_digitallink" = "xyes" ; then
  AC_DEFINE(ENABLE_DIGITAL_LINK, 1, [Define if numbering links])
fi

if test "x$build_tvoutput" = "xyes" ; then
  AC_DEFINE(ENABLE_TVOUTPUT, 1, [Define if rendering text for TV])
fi

if test "x$build_cookie" = "xyes" ; then
  AC_DEFINE(ENABLE_COOKIES, 1, [Define if including support for cookies])
fi

dnl ========================================================================
dnl check for libminigui
have_libminigui="no"
AC_CHECK_HEADERS(minigui/common.h, have_libminigui=yes, foo=bar)

dnl check for lite or threads version of MiniGUI
lite_version="no"
AC_CHECK_DECLS(_LITE_VERSION, lite_version="yes", foo=bar, [#include <minigui/common.h>])

dnl ========================================================================
dnl check for StandAlone version of MiniGUI-Lite
stand_alone="no"
AC_CHECK_DECLS(_STAND_ALONE, stand_alone="yes", foo=bar, [#include <minigui/common.h>])

dnl ========================================================================
dnl check for newgal or oldgal interface.
use_newgal="yes"
AC_CHECK_DECLS(_USE_NEWGAL, use_newgal="yes", foo=bar, [#include <minigui/common.h>])

dnl ========================================================================
dnl Write Output

if test "$ac_cv_prog_gcc" = "yes"; then
    CFLAGS="$CFLAGS -Wall -Wstrict-prototypes -pipe"
fi

if test "x$lite_version" = "xyes"; then
    SYSTEM_LIBS="$SYSTEM_LIBS -lminigui -lpthread"
else
    CFLAGS="$CFLAGS -D_REENTRANT"
    SYSTEM_LIBS="$SYSTEM_LIBS -lminigui -lpthread"
fi

AC_CHECK_DECLS(_HAVE_MATH_LIB, SYSTEM_LIBS="$SYSTEM_LIBS -lm", foo=bar, [#include <minigui/common.h>])
AC_CHECK_DECLS(_TYPE1_SUPPORT, SYSTEM_LIBS="$SYSTEM_LIBS -lt1", foo=bar, [#include <minigui/common.h>])
AC_CHECK_DECLS(_TTF_SUPPORT, SYSTEM_LIBS="$SYSTEM_LIBS -lttf", foo=bar, [#include <minigui/common.h>])

AC_SUBST(SYSTEM_LIBS)

AC_OUTPUT(
Makefile
m4/Makefile
glib/Makefile
include/Makefile
src/io/Makefile
src/Makefile
test/Makefile
test/simple/Makefile
)

if test "x$have_libminigui" != "xyes"; then
    AC_MSG_WARN([
        MiniGUI is not properly installed on the system. You need 
        MiniGUI Ver 1.6.8 or later for building this package. 
        Please configure and install MiniGUI Ver 1.6.8 first.
    ])
fi