rtdxflashcfg.cmd

支持ti的dsp 5402的基本运行的c程序,简洁好用

/*************************************************************************
* $RCSFile: /db/sds/syseng/rtdx/target/examples/54x/c5402.cmd,v $
* $Revision: 1.1 $
* $Date: 2000/09/15 17:38:11 $
* Copyright (c) 2000 Texas Instruments Incorporated
*
* LINKER COMMAND FILE FOR TMS5402 DSK Target
*
*   Usage:  lnk500 <obj files...>    -o <out file> -m <map file> c5402.cmd
*           cl500  <src files...> -z -o <out file> -m <map file> c5402.cmd
*
*   Description: This file is a sample command file that can be used
*                for linking programs built with the TMS54x C Compiler.   
*                Use it as a guideline; you may want to change
*                the allocation scheme according to the size of your
*                program and the memory layout of your target system.
*************************************************************************/
-c /* copy constants in .cinit to global variables at boot time */
-stack 0x0200
-heap  0x0200

/* This symbol defines the interrupt mask to be applied to IMR inside
   RTDX Critical Code sections.

   This example masks the timer interrupt.
*/
_RTDX_interrupt_mask = ~0x0008; /* interrupts masked by RTDX */


/* Note: The default power-up state of board is PMST = 0xffa0, but we
    set it to 0xffe0 in a GEL file.

                            PMST Values
    PMST Bit    Name    0xffe0  0xffa0  0xffc0
    ========    ====    =====   ======  ======
    15-7        IPTR    0x1ff   0x1ff   0x1ff
    6           MP/!MC  1       0       1
    5           OVLY    1       1       0
    3           DROM    0       0       0

Note: Memory between 0x0080-0x8000 is shared if OVLY = 1.

Note: PMEM0/DMEM0 will be flash memory if FLASHENB = 1.  
This memory may be recovered as SRAM by setting to 0.
*/


MEMORY  
{

    PAGE 0: /* Program Space */
        MMRS    (RW ) : o=000000h l=000060h /* Memory-mapped registers  */
        SCRATCH (RW ) : o=000060h l=000020h /* scratch-pad DARAM        */
        VECS    (RWX) : o=000080h l=000080h /* Interrupt Vector Table   */
        IPROG   (RWX) : o=000100h l=001f00h /* On-Chip DARAM            */
    PAGE 1: /* Data Space */
        /* declaration for DARAM already made in PAGE 0                 */
        IDATA   (RWX) : o=002000h l=002000h /* On-Chip DARAM            */
}

SECTIONS
{
    .vectors    : > VECS    PAGE 0/* interrupt vector table            */

    .text       : > IPROG   PAGE 0 /* User code                         */
    .rtdx_text  : > IPROG   PAGE 0 /* RTDX code                         */
    .cinit      : > IPROG   PAGE 0 /* initialization tables             */
    .pinit      : > IPROG   PAGE 0 /* initialization functions          */
    .switch     : > IPROG   PAGE 0 /* for C-switch tables               */

    /* Normally, data would go to DMEM0, but OVLY=1 so put data in      */
    /* PMEM0 to keep loader from overwriting program with data.         */
    .sysmem     : > IDATA   PAGE 1 /*fill = 0DEADh*/ /* dynamic heap        */
    .stack      : > IDATA   PAGE 1 /*fill = 0BEEFh*/ /* system stack        */
    .const      : > IDATA   PAGE 1 /* C constant tables                 */
    .cio        : > IDATA   PAGE 1 /* C-IO Buffer                       */
    .bss        : > IDATA   PAGE 1 /* global & static vars              */
    .data       : > IDATA   PAGE 1 /* asm data area                     */
    .rtdx_data  : > IDATA   PAGE 1 /* RTDX data area                    */
}