conn.asp

动易网站管理系统在新版的开发中

<%
Dim conn, db, PE_True, PE_False, PE_Now
Dim SqlDatabaseName, SqlPassword, SqlUsername, SqlHostIP
Dim SiteName, SiteTitle, SiteKey, SiteUrl, InstallDir
Dim LogoUrl, BannerUrl, WebmasterName, WebmasterEmail, Copyright
Dim SessionTimeout, objName_FSO, FileExt_SiteIndex
Dim PhotoObject, Thumb_DefaultWidth, Thumb_DefaultHeight
Dim RssCodeType, EnableLinkReg, EnableSoftKey, AdminCheckReg

Const SystemVersion = 0
Const SystemDatabaseType = "ACCESS"  '系统数据库类型，"SQL"为MS SQL2000数据库，"ACCESS"为MS ACCESS 2000数据库


'如果是ACCESS数据库，请认真修改好下面的数据库的文件名
db = "\Database\data.asa"      'ACCESS数据库的文件名，请使用相对于网站根目录的的绝对路径
                                     '如果是安装在网站根目录，直接修改文件名即可。如果是安装在网站某一目录下，则在前面加上此目录，
                                     '例如，系统安装在“http://www.asp163.net/PE2005/”目录下（PE2005为安装目录），则这里应该修改为：db="\PE2005\database\PowerEasy5.mdb"

'如果是SQL数据库，请认真修改好以下数据库选项
SqlUsername = "PowerEasy5"           'SQL数据库用户名
SqlPassword = "PowerEasy*9988"       'SQL数据库用户密码
SqlDatabaseName = "PowerEasy5"       'SQL数据库名
SqlHostIP = "127.0.0.1"              'SQL主机IP地址（本地可用“127.0.0.1”或“(local)”，非本机请用真实IP）

Call OpenConn
Call GetSiteConfig

Sub OpenConn()
    On Error Resume Next
    Dim ConnStr
    If SystemDatabaseType = "SQL" Then
        ConnStr = "Provider = Sqloledb; User ID = " & SqlUsername & "; Password = " & SqlPassword & "; Initial Catalog = " & SqlDatabaseName & "; Data Source = " & SqlHostIP & ";"
    Else
        ConnStr = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & Server.MapPath(db)
    End If
    Set conn = Server.CreateObject("ADODB.Connection")
    conn.open ConnStr
    If Err Then
        Err.Clear
        Set conn = Nothing
        Response.Write "数据库连接出错，请检查Conn.asp文件中的数据库参数设置。"
        Response.End
    End If
    Application("DbPath") = db
    Application("ConnStr") = ConnStr
    Application("SystemVersion") = SystemVersion
    Application("SystemDatabaseType") = SystemDatabaseType
    If SystemDatabaseType = "SQL" Then
        PE_True = "1"
        PE_False = "0"
        PE_Now = "getdate()"
    Else
        PE_True = "True"
        PE_False = "False"
        PE_Now = "Now()"
    End If
End Sub

Sub CloseConn()
    On Error Resume Next
    If IsObject(conn) Then
        conn.Close
        Set conn = Nothing
    End If
End Sub

Sub GetSiteConfig()
    Dim rsConfig
    Set rsConfig = conn.execute("select * from PE_Config")
    If rsConfig.bof And rsConfig.EOF Then
        rsConfig.Close
        Set rsConfig = Nothing
        Response.Write "网站配置数据丢失！系统无法正常运行！"
        Response.End
    Else
        SiteName = rsConfig("SiteName")
        SiteTitle = rsConfig("SiteTitle")
        SiteUrl = rsConfig("SiteUrl")
        SiteKey = rsConfig("SiteKey")
        InstallDir = rsConfig("InstallDir")
        EnableSoftKey = rsConfig("EnableSoftKey")
        LogoUrl = rsConfig("LogoUrl")
        WebmasterName = rsConfig("WebmasterName")
        WebmasterEmail = rsConfig("WebmasterEmail")
        AdminCheckReg = rsConfig("AdminCheckReg")
        SessionTimeout = rsConfig("SessionTimeout")
        objName_FSO = rsConfig("objName_FSO")
        FileExt_SiteIndex = rsConfig("FileExt_SiteIndex")
        EnableLinkReg = rsConfig("EnableLinkReg")
        PhotoObject = rsConfig("PhotoObject")
        Thumb_DefaultWidth = rsConfig("Thumb_DefaultWidth")
        Thumb_DefaultHeight = rsConfig("Thumb_DefaultHeight")
        RssCodeType = rsConfig("RssCodeType")
    End If
    rsConfig.Close
    Set rsConfig = Nothing
    Application("InstallDir") = InstallDir
    Application("SiteKey") = SiteKey
    Application("objName_FSO") = objName_FSO
End Sub
%>