ag_parse.parse

bluetooth audio gateway

######################################################################################
#
# This file contains all AT commands as specified in the Headset and Hands Free specs. 
#
######################################################################################

# ------------------------------------------------------------------------------------
# AT Commands
#
# Format specified in spec AT<cmd>=<value><cr>
#-------------------------------------------------------------------------------------

# Command reporting microphone gain (allowed values: 0-15)
{ AT + VGM = %d:gain \r } : handleMicrophoneGain

# Command reporting speaker gain (allowed values: 0-15)
{ AT + VGS = %d:gain \r } : handleSpeakerGain

# Command indicating button press
{ AT + CKPD = %d:button \r } : handleButtonPress

{ AT + CKPD = %s:button \r } : handleCustomButtonPress

# Get description of supported indicators (test command)
{ AT + CIND = ? \r } : handleIndicatorDescriptionRequest

# Get the current status of the indicators (read command)
{ AT + CIND ? \r } : handleIndicatorStatusRequest

# Activation of indicator events reporting. Listed as <mode>, <keyp>, <disp>, <ind>.
# but only mode = (0, 3) and ind=(0, 1) supported. 
{ AT + CMER = %d:mode , %d:keyp , %d:disp , %d:ind \r } : handleIndicatorReportActivation

# Standard answer AT command
{ ATA \r } : handleCallAnswer

# Standard hang-up AT command 
{ AT + CHUP \r } : handleCallHangUp

# Command requesting a call be placed to the given number 
# TODO can consist of one or more digits
{ ATD %s:number; \r } : handleRemoteNumberDial

# Command requesting a call be placed to the given memory location
# TODO can consist of one or more digits
{ ATD > %s:memory; \r } : handleRemoteMemoryDial

# Last number redial
# Ignore AT+BLDN? and AT+BLDN=? as they are not mandatory
{ AT + BLDN \r } : handleLastNumberRedial

# AT command to enable / disable call waiting, (allowed values: 0, 1)
{ AT + CCWA = %d:status \r } : handleCallWaitingEnable

# Call hold and multiparty handling AT command (allowed # values: 0, 1, 2, 3, 4)
{ AT + CHLD = %d:hold \r } : handleCallHoldRequest

# Retrieve info about call holding services available 
{ AT + CHLD = ? \r } : handleCallHoldTestCmd

# Activation command for Calling Line Identification
{ AT + CLIP = %d:enable \r } : handleCallerIdActivation

# Disable echo cancelling and noise reduction (allowed value: 0)
{ AT + NREC = %d:enable \r } : handleEchoCancellingDisable

# Enable /disable voice recognition function in the AG (allowed # values: 0, 1)
# TODO ignore AT+BVRA? and AT+BVRA=? as they are not mandatory
{ AT + BVRA = %d:enable \r } : handleVoiceRecognitionEnable

# Command requesting specific data input. Currently only supports phone 
# number request i.e. only 1 allowed as an argument.
{ AT + BINP = %d:request \r } : handleSpecificDataRequest

# DTMF generation  only one of [0-9 # * A-D] allowed
{ AT + VTS = %s:code \r } : handleDTMFGeneration




# -------------------------------------------------------------------
# AT Result Codes
#
# Format specified in spec <cr><lf><Result Code><cr><lf>
# -------------------------------------------------------------------

# Command processed successfully
{ \r \n OK \r \n } : handleOK

# Command not processed successfully
{ \r \n ERROR \r \n } : handleError

# Incoming call indication
{ \r \n RING \r \n } : handleRing

# Set microphone gain indication (allowed values: 0-15)
{ \r \n + VGM =  %d:gain \r \n } : handleMicrophoneGain

# Set speaker gain indication (allowed values: 0-15)
{ \r \n + VGS =  %d:gain \r \n } : handleSpeakerGain