class.asp

Sql数据库的应用

<!--#Include File="SQLDB.asp"-->
<%
'类名：ScoreClass
'功能：成绩类的一般方法与属性
Class ScoreClass	
	
	'数据库连接类
	Public dbc_Class

	'功能：查找某个学生某学期所有课程的成绩
	'参数：	StudentID 学生的学号
	'	Term 学期编号
	Public Sub searchScore(StudentID,Term)
		Set dbc_Class = New DBConn 		
		
		'建立存储过程的输入参数
		Set Cmd1 = Server.CreateObject("ADODB.Command")       
		Set  Param = Cmd1.CreateParameter("@StudentID",adVarChar,adParamInput,20,StudentID)
		Cmd1.Parameters.Append  Param
		Set  Param = Cmd1.CreateParameter("@Term",adInteger,adParamInput,4,Term)
		Cmd1.Parameters.Append  Param		
			
		'运行名为sp_SearchScore的存储过程		
		Call dbc_Class.CreateCommandProc("sp_SearchScore",Cmd1)		
		Set Cmd1 = nothing				
	End Sub	
	
	'功能：查找某年级、某个班级，某学科学生的成绩
	'参数：	grade 年级
	'	class1 班级
	'	cource 课程编号
	Public Sub getClassScore(course,grade,class1)
		Set dbc_Class = New DBConn 		
		
		'建立存储过程的输入参数
		Set Cmd1 = Server.CreateObject("ADODB.Command")  
		Set  Param = Cmd1.CreateParameter("@CourseID",adVarChar,adParamInput,20,course)
		Cmd1.Parameters.Append  Param	     
		Set  Param = Cmd1.CreateParameter("@Grade",adVarChar,adParamInput,20,grade)
		Cmd1.Parameters.Append  Param
		Set  Param = Cmd1.CreateParameter("@Class",adInteger,adParamInput,4,class1)
		Cmd1.Parameters.Append  Param
		
			
		'运行名为sp_GetScore的存储过程		
		Call dbc_Class.CreateCommandProc("sp_GetScore",Cmd1)		
		Set Cmd1 = nothing				
	End Sub	
	
	'功能：查找某年级、某个班级，某学科学生的成绩的名次报表或是补考名单
	'参数：	grade 年级
	'	class1 班级
	'	cource 课程编号
	'	type1 报表类型
	Public Sub getClassScoreReport(course,grade,class1,type1)
		Set dbc_Class = New DBConn 		
		
		'建立存储过程的输入参数
		Set Cmd1 = Server.CreateObject("ADODB.Command")  
		Set  Param = Cmd1.CreateParameter("@CourseID",adVarChar,adParamInput,20,course)
		Cmd1.Parameters.Append  Param	     
		Set  Param = Cmd1.CreateParameter("@Grade",adVarChar,adParamInput,20,grade)
		Cmd1.Parameters.Append  Param
		Set  Param = Cmd1.CreateParameter("@Class",adInteger,adParamInput,4,class1)
		Cmd1.Parameters.Append  Param
		Set  Param = Cmd1.CreateParameter("@Type",adInteger,adParamInput,4,type1)
		Cmd1.Parameters.Append  Param
		
			
		'运行名为sp_GetScoreReport的存储过程		
		Call dbc_Class.CreateCommandProc("sp_GetScoreReport",Cmd1)		
		Set Cmd1 = nothing				
	End Sub	
	
	'功能：查找某个学生某课程的成绩
	'参数：	studentid 学生的学号
	'	courseid 课程编号
	Public Sub getOneScore(studentid,courseid)
		Set dbc_Class = New DBConn 		
		
		'建立存储过程的输入参数
		Set Cmd1 = Server.CreateObject("ADODB.Command")       
		Set  Param = Cmd1.CreateParameter("@StudentID",adVarChar,adParamInput,20,studentid)
		Cmd1.Parameters.Append  Param
		Set  Param = Cmd1.CreateParameter("@CourseID",adVarChar,adParamInput,20,courseid)
		Cmd1.Parameters.Append  Param		
			
		'运行名为sp_GetOneScore的存储过程		
		Call dbc_Class.CreateCommandProc("sp_GetOneScore",Cmd1)		
		Set Cmd1 = nothing				
	End Sub
	
	'功能：添加一个学生一门课程的成绩
	'参数：studentid学生ID,courseid课程ID,score分值,term学期,type1考试类型
	Public Sub addScore(studentid,courseid,score,term,type1)
		Set dbc_Class = New DBConn 
		
		'建立存储过程的输入参数
		Set Cmd1 = Server.CreateObject("ADODB.Command")	
		Set  Param = Cmd1.CreateParameter("@StudentID",adVarChar,adParamInput,20,studentid)
		Cmd1.Parameters.Append  Param
		Set  Param = Cmd1.CreateParameter("@CourseID",adVarChar,adParamInput,20,courseid)
		Cmd1.Parameters.Append  Param
		Set  Param = Cmd1.CreateParameter("@Score",adInteger,adParamInput,4,score)
		Cmd1.Parameters.Append  Param
		Set  Param = Cmd1.CreateParameter("@Term",adInteger,adParamInput,4,term)
		Cmd1.Parameters.Append  Param
		Set  Param = Cmd1.CreateParameter("@Type",adInteger,adParamInput,4,type1)
		Cmd1.Parameters.Append  Param		
			
		'运行名为sp_AddScore的存储过程		
		Call dbc_Class.CreateCommandProc("sp_AddScore",Cmd1)		
		Set Cmd1 = nothing
		dbc_Class.CloseConn()		
	End Sub	
	
	'功能：更新一个学生一门课程的成绩
	'参数：studentid学生ID,courseid课程ID,score分值,term学期,type1考试类型
	Public Sub updateScore(studentid,courseid,score,term,type1)
		Set dbc_Class = New DBConn 
		
		'建立存储过程的输入参数
		Set Cmd1 = Server.CreateObject("ADODB.Command")	
		Set  Param = Cmd1.CreateParameter("@StudentID",adVarChar,adParamInput,20,studentid)
		Cmd1.Parameters.Append  Param
		Set  Param = Cmd1.CreateParameter("@CourseID",adVarChar,adParamInput,20,courseid)
		Cmd1.Parameters.Append  Param
		Set  Param = Cmd1.CreateParameter("@Score",adInteger,adParamInput,4,score)
		Cmd1.Parameters.Append  Param
		Set  Param = Cmd1.CreateParameter("@Term",adInteger,adParamInput,4,term)
		Cmd1.Parameters.Append  Param
		Set  Param = Cmd1.CreateParameter("@Type",adInteger,adParamInput,4,type1)
		Cmd1.Parameters.Append  Param		
			
		'运行名为sp_UpdateScore的存储过程		
		Call dbc_Class.CreateCommandProc("sp_UpdateScore",Cmd1)		
		Set Cmd1 = nothing
		dbc_Class.CloseConn()		
	End Sub	
	
	'功能：删除某个学生的某门课程的成绩
	'参数：sid要删除的学生ID
	'      cid要删除的课程ID
	Public Sub delScore(sid,cid)
		Set dbc_Class = New DBConn 
		
		'建立存储过程的输入参数
		Set Cmd1 = Server.CreateObject("ADODB.Command")	
		Set  Param = Cmd1.CreateParameter("@StudentID",adVarChar,adParamInput,20,sid)
		Cmd1.Parameters.Append  Param	
		Set  Param = Cmd1.CreateParameter("@CourseID",adVarChar,adParamInput,20,cid)
		Cmd1.Parameters.Append  Param		
			
		'运行名为sp_DelScore的存储过程		
		Call dbc_Class.CreateCommandProc("sp_DelScore",Cmd1)		
		Set Cmd1 = nothing
		dbc_Class.CloseConn()		
	End Sub	
End Class

'类名：StudentClass
'功能：学生类的一般方法与属性
Class StudentClass	
	
	'数据库连接类
	Public dbc_Class
	
	'功能：取得所有学生的信息
	Public Sub getAllStudent()
		Set dbc_Class = New DBConn 		
		
		'建立存储过程的输入参数
		Set Cmd1 = Server.CreateObject("ADODB.Command") 			
			
		'运行名为sp_GetAllStudent的存储过程		
		Call dbc_Class.CreateCommandProc("sp_GetAllStudent",Cmd1)		
		Set Cmd1 = nothing				
	End Sub
	
	'功能：取得某个学生的信息
	'参数：	studentID 查询的学生学号
	'	type1 查询的类型，是完全方式还是模糊匹配
	Public Sub getStudentInf(studentID,type1)
		Set dbc_Class = New DBConn 		
		
		'建立存储过程的输入参数
		Set Cmd1 = Server.CreateObject("ADODB.Command")       
		Set  Param = Cmd1.CreateParameter("@ID",adVarChar,adParamInput,20,studentID)
		Cmd1.Parameters.Append  Param
		Set  Param = Cmd1.CreateParameter("@Type",adInteger,adParamInput,4,type1)
		Cmd1.Parameters.Append  Param			
			
		'运行名为sp_GetStudentInf的存储过程		
		Call dbc_Class.CreateCommandProc("sp_GetStudentInf",Cmd1)		
		Set Cmd1 = nothing				
	End Sub	
	
	'功能：添加一个学生
	'参数：id学号,name姓名,gender性别,grade年级,class1班级
	Public Sub addStudent(id,name,gender,grade,class1)
		Set dbc_Class = New DBConn 
		
		'建立存储过程的输入参数
		Set Cmd1 = Server.CreateObject("ADODB.Command")	
		Set  Param = Cmd1.CreateParameter("@ID",adVarChar,adParamInput,20,id)
		Cmd1.Parameters.Append  Param
		Set  Param = Cmd1.CreateParameter("@Name",adVarChar,adParamInput,20,name)
		Cmd1.Parameters.Append  Param
		Set  Param = Cmd1.CreateParameter("@Gender",adInteger,adParamInput,4,gender)
		Cmd1.Parameters.Append  Param
		Set  Param = Cmd1.CreateParameter("@Grade",adVarChar,adParamInput,20,grade)
		Cmd1.Parameters.Append  Param
		Set  Param = Cmd1.CreateParameter("@Class",adInteger,adParamInput,4,class1)
		Cmd1.Parameters.Append  Param		
			
		'运行名为sp_AddStudent的存储过程		
		Call dbc_Class.CreateCommandProc("sp_AddStudent",Cmd1)		
		Set Cmd1 = nothing
		dbc_Class.CloseConn()		
	End Sub	
	
	'功能：更新一个学生的信息
	'参数：id学号,name姓名,gender性别,grade年级,class1班级
	Public Sub updateStudent(id,name,gender,grade,class1)
		Set dbc_Class = New DBConn 
		
		'建立存储过程的输入参数
		Set Cmd1 = Server.CreateObject("ADODB.Command")	
		Set  Param = Cmd1.CreateParameter("@ID",adVarChar,adParamInput,20,id)
		Cmd1.Parameters.Append  Param
		Set  Param = Cmd1.CreateParameter("@Name",adVarChar,adParamInput,20,name)
		Cmd1.Parameters.Append  Param
		Set  Param = Cmd1.CreateParameter("@Gender",adInteger,adParamInput,4,gender)
		Cmd1.Parameters.Append  Param
		Set  Param = Cmd1.CreateParameter("@Grade",adVarChar,adParamInput,20,grade)
		Cmd1.Parameters.Append  Param
		Set  Param = Cmd1.CreateParameter("@Class",adInteger,adParamInput,4,class1)
		Cmd1.Parameters.Append  Param		
			
		'运行名为sp_UpdateStudent的存储过程		
		Call dbc_Class.CreateCommandProc("sp_UpdateStudent",Cmd1)		
		Set Cmd1 = nothing
		dbc_Class.CloseConn()		
	End Sub	
	
	'功能：删除某个学生
	'参数：id要删除的学生ID
	Public Sub delStudent(id)
		Set dbc_Class = New DBConn 
		
		'建立存储过程的输入参数
		Set Cmd1 = Server.CreateObject("ADODB.Command")	
		Set  Param = Cmd1.CreateParameter("@ID",adVarChar,adParamInput,20,id)
		Cmd1.Parameters.Append  Param		
			
		'运行名为sp_DelMessage的存储过程		
		Call dbc_Class.CreateCommandProc("sp_DelStudent",Cmd1)		
		Set Cmd1 = nothing
		dbc_Class.CloseConn()		
	End Sub		
End Class

'类名：AdminClass
'功能：管理员及教师类的一般方法与属性
Class AdminClass	
	
	'数据库连接类
	Public dbc_Class

	'功能：取得某个管理员或是老师的信息
	'参数：	AdminID 管理ID号
	Public Sub getAdminInf(AdminID)
		Set dbc_Class = New DBConn 		
		
		'建立存储过程的输入参数
		Set Cmd1 = Server.CreateObject("ADODB.Command")       
		Set  Param = Cmd1.CreateParameter("@ID",adVarChar,adParamInput,20,AdminID)
		Cmd1.Parameters.Append  Param		
			
		'运行名为sp_GetAdminInf的存储过程		
		Call dbc_Class.CreateCommandProc("sp_GetAdminInf",Cmd1)		
		Set Cmd1 = nothing				
	End Sub

End Class

'类名：CourseClass
'功能：课程类的一般方法与属性
Class CourseClass	
	
	'数据库连接类
	Public dbc_Class

	'功能：取得所有课程的信息
	Public Sub getAllCourse()
		Set dbc_Class = New DBConn 		
		
		'建立存储过程的输入参数
		Set Cmd1 = Server.CreateObject("ADODB.Command")		
		'运行名为sp_GetAllCourse的存储过程		
		Call dbc_Class.CreateCommandProc("sp_GetAllCourse",Cmd1)		
		Set Cmd1 = nothing				
	End Sub
	
	'功能：取得某个老师负责的所有课程的信息
	'参数：teacherid老师的登录ID
	Public Sub getCourseByTeacher(teacherid)
		Set dbc_Class = New DBConn 		
		
		'建立存储过程的输入参数
		Set Cmd1 = Server.CreateObject("ADODB.Command")		
		Set  Param = Cmd1.CreateParameter("@ID",adVarChar,adParamInput,20,teacherid)
		Cmd1.Parameters.Append  Param
		'运行名为sp_GetCourseByTeacher的存储过程		
		Call dbc_Class.CreateCommandProc("sp_GetCourseByTeacher",Cmd1)		
		Set Cmd1 = nothing				
	End Sub

End Class

'类名：MessageClass
'功能：留言类的一般方法与属性
Class MessageClass	
	
	'数据库连接类
	Public dbc_Class

	'功能：查看留言信息,使用此方法时请注意关闭DBConn类中的数据连接
	Public Sub viewMessage()
		Set dbc_Class = New DBConn	
		'直接运行一个SQL语句			
		Call dbc_Class.runSQL("Select * From Message where type=1")	
		Set Cmd1 = nothing			
	End Sub
	
	'功能：查看某个留言的回复信息
	'参数：ParentID
	'返回值：
	Public Sub revertMessage(ParentID)
		Set dbc_Class = New DBConn 		
		
		'建立存储过程的输入参数
		Set Cmd1 = Server.CreateObject("ADODB.Command")       
		
		Set  Param = Cmd1.CreateParameter("@ParentID",adInteger,adParamInput,4,ParentID)
		Cmd1.Parameters.Append  Param		
			
		'运行名为sp_GetRevertMessage的存储过程		
		Call dbc_Class.CreateCommandProc("sp_GetRevertMessage",Cmd1)		
		Set Cmd1 = nothing
		dbc_Class.CloseConn()		
	End Sub
	
	
	'功能：添加留言信息
	'参数：Name,Email,Oicq,Tell,Ip,InputDate,Type1,ParentID,Message
	'返回值：
	Public Sub addMessage(Name,Email,Oicq,Tell,Ip,InputDate,Type1,ParentID,Message)
		Set dbc_Class = New DBConn 		
		
		'建立存储过程的输入参数
		Set Cmd1 = Server.CreateObject("ADODB.Command")       
		Set  Param = Cmd1.CreateParameter("@Name",adVarChar,adParamInput,20,Name)
		Cmd1.Parameters.Append  Param
		Set  Param = Cmd1.CreateParameter("@Email",adVarChar,adParamInput,20,Email)
		Cmd1.Parameters.Append  Param
		Set  Param = Cmd1.CreateParameter("@Oicq",adVarChar,adParamInput,20,Oicq)
		Cmd1.Parameters.Append  Param
		Set  Param = Cmd1.CreateParameter("@Tell",adVarChar,adParamInput,20,Tell)
		Cmd1.Parameters.Append  Param
		Set  Param = Cmd1.CreateParameter("@Ip",adVarChar,adParamInput,20,Ip)
		Cmd1.Parameters.Append  Param		
		Set  Param = Cmd1.CreateParameter("@InputDate",adVarChar,adParamInput,20,InputDate)
		Cmd1.Parameters.Append  Param
		Set  Param = Cmd1.CreateParameter("@Type",adInteger,adParamInput,1,Type1)
		Cmd1.Parameters.Append  Param		
		Set  Param = Cmd1.CreateParameter("@ParentID",adInteger,adParamInput,4,ParentID)
		Cmd1.Parameters.Append  Param		
		Set  Param = Cmd1.CreateParameter("@Message",adVarChar,adParamInput,1000,Message)
		Cmd1.Parameters.Append  Param	
		'运行名为sp_AddMsg的存储过程		
		Call dbc_Class.CreateCommandProc("sp_AddMsg",Cmd1)		
		Set Cmd1 = nothing
		dbc_Class.CloseConn()		
	End Sub
	
	
	'功能：删除留言
	'参数：id要删除的留言编号序列
	'返回值：无
	Public Sub delMessage(id)
		Set dbc_Class = New DBConn 
		
		'建立存储过程的输入参数
		Set Cmd1 = Server.CreateObject("ADODB.Command")	
		Set  Param = Cmd1.CreateParameter("@ID",adInteger,adParamInput,20,id)
		Cmd1.Parameters.Append  Param		
			
		'运行名为sp_DelMessage的存储过程		
		Call dbc_Class.CreateCommandProc("sp_DelMessage",Cmd1)		
		Set Cmd1 = nothing
		dbc_Class.CloseConn()		
	End Sub		
End Class

%>