logincheck.asp

Sql数据库的应用

<!--#Include File="ErrorClass.asp"-->
<!--#Include File="Class.asp"-->
<% 
'此段声明表示遇到错误即跳到下一句
On Error Resume Next
Dim UserID
Dim PassWord1
Dim error_Class,ac_Class
'初始化一个管理员类 
Set ac_Class = New AdminClass
'初始化一个错误处理类 
Set error_Class = New ErrorClass

If getForm() = 1 Then		
	If checkUser(UserID,PassWord1) = 1 Then
		error_Class.Message = "登录成功"
		Call ac_Class.getAdminInf(UserID)
		
		While not ac_Class.dbc_Class.Rs.EOF			
			If ac_Class.dbc_Class.Rs("Type") = 1 Then
				Response.Redirect ("Manage.asp")
			ElseIf ac_Class.dbc_Class.Rs("Type") = 2 Then
				Response.Redirect ("teacher.asp")
			Else
				Response.Redirect("SearchScore.asp")
			End If
			ac_Class.dbc_Class.Rs.MoveNext()
		Wend
		Call ac_Class.dbc_Class.CloseConn()
	Else
		error_Class.Founderr = True
		error_Class.Message = "用户名或密码有误"
		Call error_Class.showMessage("login.asp","失败")
	End If	
Else
	error_Class.Founderr = True
	error_Class.Message = "用户和密码不能为空"
	Call error_Class.showMessage("login.asp","失败")
End If

'功能：取得用户输入的用户名和密码
Function getForm()	
	UserID = trim(Request.Form("userid1"))
	PassWord1 = trim(Request.Form("password1"))	
	If UserID<>"" And PassWord1<>"" Then
		getForm = 1
	Else
		getForm = 0
	End If	
End Function

	
'功能：验证用户信息是否正确
'参数：username用户名
'      password密码
'返回值：正确则返回1，不正确返回0
'        设置Cookies用户ID（UserID）和登录状态(Login)
Function checkUser(userid,password)
	Dim dbc_Class
	Set dbc_Class = New DBConn 
	
	'建立存储过程的输入参数
	Set Cmd1 = Server.CreateObject("ADODB.Command")	
	set  Param = Cmd1.CreateParameter("@ID",adVarChar,adParamInput,20,userid)
	Cmd1.Parameters.Append  Param
	set  Param = Cmd1.CreateParameter("@PassWord",adVarChar,adParamInput,20,password)
	Cmd1.Parameters.Append  Param
	'运行名为sp_CheckUser的存储过程
	Call dbc_Class.CreateCommandProc("sp_CheckUser",Cmd1)	
	
	If dbc_Class.Rs.EOF Then
		'失败时的返回值	
		Response.Cookies("Login") = 0		
		checkUser = 0
	Else
		While Not dbc_Class.Rs.EOF
			'建立Cookies客户端变量以识别登录的用户
			Response.Cookies("UserID") = dbc_Class.Rs("ID")			
			Response.Cookies("Login") = 1	
			dbc_Class.Rs.MoveNext
		Wend
		'成功时的返回值
		checkUser = 1
	End If
	Set Cmd1 = nothing
	dbc_Class.CloseConn()
End Function

%>