class.asp

ASP+sql 组成的系统．功能强大

<!--#Include File="DBConn.asp"-->
<%
'类名：MaterialClass
'功能：物资类的一般方法与属性
Class MaterialClass	
	
	'数据库连接类
	Public dbc_Class
	
	'功能：取得物资信息
	'参数：userID用户名
	'      status物资状态
	'返回值：记录集RS
	Public Sub getMaterialByUserID(userid,status)
		Set dbc_Class = New DBConn 
		
		'建立存储过程的输入参数
		Set Cmd1 = Server.CreateObject("ADODB.Command")	
		set  Param = Cmd1.CreateParameter("@UserID",adVarChar,adParamInput,20,userid)
		Cmd1.Parameters.Append  Param
		set  Param = Cmd1.CreateParameter("@Status",adInteger,adParamInput,4,status)
		Cmd1.Parameters.Append  Param
		'运行名为sp_GetMaterialByUserID的存储过程		
		Call dbc_Class.CreateCommandProc("sp_GetMaterialByUserID",Cmd1)				
		Set Cmd1 = nothing
		'dbc_Class.CloseConn()
	End Sub	
	
	'功能：按物资编号取得物资信息
	'参数：id物资编号
	'      type1查询方法
	'返回值：记录集RS
	Public Sub SeekMaterialByID(id,type1)
		Set dbc_Class = New DBConn 
		
		'建立存储过程的输入参数
		Set Cmd1 = Server.CreateObject("ADODB.Command")	
		set  Param = Cmd1.CreateParameter("@ID",adVarChar,adParamInput,20,id)
		Cmd1.Parameters.Append  Param
		set  Param = Cmd1.CreateParameter("@Type",adInteger,adParamInput,4,type1)
		Cmd1.Parameters.Append  Param
		'运行名为sp_SeekMaterialByID的存储过程		
		Call dbc_Class.CreateCommandProc("sp_SeekMaterialByID",Cmd1)				
		Set Cmd1 = nothing
		'dbc_Class.CloseConn()
	End Sub	
	
	'功能：按物资名称取得物资信息
	'参数：name物资名称
	'      type1查询方法
	'返回值：记录集RS
	Public Sub SeekMaterialByName(name,type1)
		Set dbc_Class = New DBConn 
		
		'建立存储过程的输入参数
		Set Cmd1 = Server.CreateObject("ADODB.Command")	
		set  Param = Cmd1.CreateParameter("@Name",adVarChar,adParamInput,20,name)
		Cmd1.Parameters.Append  Param
		set  Param = Cmd1.CreateParameter("@Type",adInteger,adParamInput,4,type1)
		Cmd1.Parameters.Append  Param
		'运行名为sp_SeekMaterialByName的存储过程		
		Call dbc_Class.CreateCommandProc("sp_SeekMaterialByName",Cmd1)				
		Set Cmd1 = nothing
		'dbc_Class.CloseConn()
	End Sub	
	
	'功能：按物资规格取得物资信息
	'参数：spec物资规格
	'      type1查询方法
	'返回值：记录集RS
	Public Sub SeekMaterialBySpec(spec,type1)
		Set dbc_Class = New DBConn 
		
		'建立存储过程的输入参数
		Set Cmd1 = Server.CreateObject("ADODB.Command")	
		set  Param = Cmd1.CreateParameter("@Spec",adVarChar,adParamInput,200,spec)
		Cmd1.Parameters.Append  Param
		set  Param = Cmd1.CreateParameter("@Type",adInteger,adParamInput,4,type1)
		Cmd1.Parameters.Append  Param
		'运行名为sp_SeekMaterialBySpec的存储过程		
		Call dbc_Class.CreateCommandProc("sp_SeekMaterialBySpec",Cmd1)				
		Set Cmd1 = nothing
		'dbc_Class.CloseConn()
	End Sub
	
	'功能：按物资存放地点取得物资信息
	'参数：spec物资存放地点
	'      type1查询方法
	'返回值：记录集RS
	Public Sub SeekMaterialByPlace(place,type1)
		Set dbc_Class = New DBConn 
		
		'建立存储过程的输入参数
		Set Cmd1 = Server.CreateObject("ADODB.Command")	
		set  Param = Cmd1.CreateParameter("@Place",adVarChar,adParamInput,20,place)
		Cmd1.Parameters.Append  Param
		set  Param = Cmd1.CreateParameter("@Type",adInteger,adParamInput,4,type1)
		Cmd1.Parameters.Append  Param
		'运行名为sp_SeekMaterialByPlace的存储过程		
		Call dbc_Class.CreateCommandProc("sp_SeekMaterialByPlace",Cmd1)				
		Set Cmd1 = nothing
		'dbc_Class.CloseConn()
	End Sub	
	
	'功能：按物资责任人取得物资信息
	'参数：userid物资责任人
	'      type1查询方法
	'返回值：记录集RS
	Public Sub SeekMaterialByUserID(userid,type1)
		Set dbc_Class = New DBConn 
		
		'建立存储过程的输入参数
		Set Cmd1 = Server.CreateObject("ADODB.Command")
		set  Param = Cmd1.CreateParameter("@UserID",adVarChar,adParamInput,20,userid)
		Cmd1.Parameters.Append  Param
		set  Param = Cmd1.CreateParameter("@Type",adInteger,adParamInput,4,type1)
		Cmd1.Parameters.Append  Param
		'运行名为sp_SeekMaterialByUserID的存储过程		
		Call dbc_Class.CreateCommandProc("sp_SeekMaterialByUserID",Cmd1)				
		Set Cmd1 = nothing
		'dbc_Class.CloseConn()
	End Sub	
	
	'功能：添加新的物资信息
	'参数：id,name,spec,place,userid,status,good,remark
	'返回值：
	Public Sub addMaterial(id,name,spec,place,userid,status,good,remark)
		Set dbc_Class = New DBConn 
		
		'建立存储过程的输入参数
		Set Cmd1 = Server.CreateObject("ADODB.Command")	
		Set  Param = Cmd1.CreateParameter("@ID",adVarChar,adParamInput,20,id)
		Cmd1.Parameters.Append  Param
		Set  Param = Cmd1.CreateParameter("@Name",adVarChar,adParamInput,20,name)
		Cmd1.Parameters.Append  Param
		Set  Param = Cmd1.CreateParameter("@Spec",adVarChar,adParamInput,200,spec)
		Cmd1.Parameters.Append  Param
		Set  Param = Cmd1.CreateParameter("@Place",adVarChar,adParamInput,20,place)
		Cmd1.Parameters.Append  Param
		Set  Param = Cmd1.CreateParameter("@UserID",adVarChar,adParamInput,20,userid)
		Cmd1.Parameters.Append  Param		
		Set  Param = Cmd1.CreateParameter("@Status",adInteger,adParamInput,4,status)
		Cmd1.Parameters.Append  Param
		Set  Param = Cmd1.CreateParameter("@Good",adInteger,adParamInput,1,good)
		Cmd1.Parameters.Append  Param		
		Set  Param = Cmd1.CreateParameter("@Remark",adVarChar,adParamInput,100,remark)
		Cmd1.Parameters.Append  Param
			
		'运行名为sp_AddMaterial的存储过程		
		Call dbc_Class.CreateCommandProc("sp_AddMaterial",Cmd1)		
		Set Cmd1 = nothing
		dbc_Class.CloseConn()		
	End Sub
	
	'功能：更新物资信息
	'参数：id,name,spec,place,userid,status,good,remark
	'返回值：
	Public Sub updateMaterial(id,name,spec,place,userid,status,good,remark)
		Set dbc_Class = New DBConn 
		
		'建立存储过程的输入参数
		Set Cmd1 = Server.CreateObject("ADODB.Command")	
		Set  Param = Cmd1.CreateParameter("@ID",adVarChar,adParamInput,20,id)
		Cmd1.Parameters.Append  Param
		Set  Param = Cmd1.CreateParameter("@Name",adVarChar,adParamInput,20,name)
		Cmd1.Parameters.Append  Param
		Set  Param = Cmd1.CreateParameter("@Spec",adVarChar,adParamInput,200,spec)
		Cmd1.Parameters.Append  Param
		Set  Param = Cmd1.CreateParameter("@Place",adVarChar,adParamInput,20,place)
		Cmd1.Parameters.Append  Param
		Set  Param = Cmd1.CreateParameter("@UserID",adVarChar,adParamInput,20,userid)
		Cmd1.Parameters.Append  Param		
		Set  Param = Cmd1.CreateParameter("@Status",adInteger,adParamInput,4,status)
		Cmd1.Parameters.Append  Param
		Set  Param = Cmd1.CreateParameter("@Good",adInteger,adParamInput,1,good)
		Cmd1.Parameters.Append  Param		
		Set  Param = Cmd1.CreateParameter("@Remark",adVarChar,adParamInput,100,remark)
		Cmd1.Parameters.Append  Param
			
		'运行名为sp_UpdateMaterial的存储过程		
		Call dbc_Class.CreateCommandProc("sp_UpdateMaterial",Cmd1)		
		Set Cmd1 = nothing
		dbc_Class.CloseConn()		
	End Sub		
	
	'功能：更改物资状态信息
	'参数：ids处理的物资编号序列；status更改后的状态；userid分配的责任人
	'返回值：无
	Public Sub dealMaterial(status,userid,ids)
		Set dbc_Class = New DBConn 
		
		'建立存储过程的输入参数，一定要注意参数顺序
		Set Cmd1 = Server.CreateObject("ADODB.Command")	
		Set  Param = Cmd1.CreateParameter("@IDS",adVarChar,adParamInput,1000,ids)
		Cmd1.Parameters.Append  Param
		Set  Param = Cmd1.CreateParameter("@UserID",adVarChar,adParamInput,20,userid)
		Cmd1.Parameters.Append  Param
		Set  Param = Cmd1.CreateParameter("@Status",adVarChar,adParamInput,2,status)
		Cmd1.Parameters.Append  Param	
				
			
		'运行名为sp_DealMaterialStatus的存储过程		
		Call dbc_Class.CreateCommandProc("sp_DealMaterialStatus",Cmd1)	
				
		Set Cmd1 = nothing
		dbc_Class.CloseConn()		
	End Sub	
	
	'功能：删除物资
	'参数：ids要删除的物资编号序列
	'返回值：无
	Public Sub delMaterial(ids)
		Set dbc_Class = New DBConn 
		
		'建立存储过程的输入参数
		Set Cmd1 = Server.CreateObject("ADODB.Command")	
		Set  Param = Cmd1.CreateParameter("@IDS",adVarChar,adParamInput,1000,ids)
		Cmd1.Parameters.Append  Param		
			
		'运行名为sp_DelMaterial的存储过程		
		Call dbc_Class.CreateCommandProc("sp_DelMaterial",Cmd1)		
		Set Cmd1 = nothing
		dbc_Class.CloseConn()		
	End Sub		
	
	'功能：取得物资状态字符串
	'参数：status物资状态
	'返回值：物资状态字符串
	Public Function getStatus(status)
		Dim strReturn
		strReturn = ""
		Select Case Cint(status)
			Case 0
				strReturn = "<font color=red>出库</font>"
			Case 1
				strReturn = "公司库存"
			Case 2
				strReturn = "部门库存"
			Case 3
				strReturn = "<font color=blue>占有</font>"
			Case Else
				strReturn = ""
		End Select
		getStatus = strReturn
	End Function
	
	'功能：取得物资好坏状态字符串
	'参数：good物资好坏状态
	'返回值：物资好坏状态字符串
	Public Function getGood(good)
		Dim strReturn
		strReturn = ""
		If good = False Then
			strReturn = "<font color=red>坏</font>"
		Else
			strReturn = "好"			
		End If
		getGood = strReturn
	End Function
End Class


'类名：UserClass
'功能：用户类的一般方法与属性
Class UserClass	
	
	'私有的数据库连接类
	Public dbc_Class
	
	'功能：验证用户信息是否正确
	'参数：username用户名
	'      password密码
	'返回值：正确则返回1，不正确返回0
	'        设置COOKIES用户ID（UserID）和登录状态(Login)
	Public Function checkUser(username,password)
		Set dbc_Class = New DBConn 
		
		'建立存储过程的输入参数
		Set Cmd1 = Server.CreateObject("ADODB.Command")	
		set  Param = Cmd1.CreateParameter("@ID",adVarChar,adParamInput,20,username)
		Cmd1.Parameters.Append  Param
		set  Param = Cmd1.CreateParameter("@PassWord",adVarChar,adParamInput,20,password)
		Cmd1.Parameters.Append  Param
		'运行名为sp_CheckStaff的存储过程
		Call dbc_Class.CreateCommandProc("sp_CheckStaff",Cmd1)	
		
		If dbc_Class.Rs.EOF Then
			'失败时的返回值	
			Response.Cookies("Login") = 0		
			checkUser = 0
		Else
			While Not dbc_Class.Rs.EOF
				'建立变量以识别登录的用户
				Response.Cookies("UserID") = dbc_Class.Rs("ID")			
				Response.Cookies("Login") = 1	
				dbc_Class.Rs.MoveNext
			Wend
			'成功时的返回值
			checkUser = 1
		End If
		Set Cmd1 = nothing
		dbc_Class.CloseConn()
	End Function
	
	'功能：根据用户ID获取用户名
	'参数：userID用户ID	
	'返回值：用户名
	Public Function getUserName(userid)
		Dim strReturn
		Set dbc_Class = New DBConn 
		strReturn = ""
		'建立存储过程的输入参数
		Set Cmd1 = Server.CreateObject("ADODB.Command")	
		set  Param = Cmd1.CreateParameter("@ID",adVarChar,adParamInput,20,userid)
		Cmd1.Parameters.Append  Param	
		'运行名为sp_GetUserName的存储过程
		Call dbc_Class.CreateCommandProc("sp_GetUserName",Cmd1)	
		
		If dbc_Class.Rs.EOF Then				
			strReturn = "无效用户"
		Else
			While Not dbc_Class.Rs.EOF
				strReturn = dbc_Class.Rs("Name")				
				dbc_Class.Rs.MoveNext()
			Wend			
		End If
		Set Cmd1 = nothing
		dbc_Class.CloseConn()
		getUserName = strReturn
	End Function
	
	'功能：获取所有用户信息
	'参数：userID用户ID	
	'返回值：数据集RS
	Public Sub getAllUser()
		Set dbc_Class = New DBConn 		
		'建立存储过程的输入参数
		Set Cmd1 = Server.CreateObject("ADODB.Command")		
		'运行名为sp_GetAllUser的存储过程
		Call dbc_Class.CreateCommandProc("sp_GetAllUser",Cmd1)		
		Set Cmd1 = nothing		
	End Sub		
End Class


%>