sig4559n.inc

这是RENESAS空调遥控的一个方案,使用单片机开发

;**************************************************************;
;       Remote controller for M34559 DEMO                      ;
;       MODULE :   SIGNAL RADIATION SUBROUTINE                 ;
;       MCU:       M34559G6-xxxFP                              ;
;       VERSION:   1.0                                         ;
;       DESIGNED:  GAO YUAN HONG                               ;
;       DATE:      2006-05-12                                  ;
;       Renesas System Solutions Asia Pte. Ltd	               ;
;       SHANGHAI Representative Office                         ;
;**************************************************************;
;***************************************
; Send a frame datas 
;***************************************
Send_data:
        BML     Head
        LXY     TDATAAL
Send_loop05:
        TAY
        TEAB
        SZB     0
        BML     Send_1bit
        BML     Send_0bit
        TABE
        TYA
        SZB     1
        BML     Send_1bit
        BML     Send_0bit
        TABE
        TYA
        SZB     2
        BML     Send_1bit
        BML     Send_0bit
        TABE
        TYA
        SZB     3
        BML     Send_1bit
        BML     Send_0bit
        TABE
        TYA
        INY
        BL	Send_loop05
        LXY     TDATAIL
Send_loop10:
        TAY
        TEAB
        SZB     0
        BML     Send_1bit
        BML     Send_0bit
        TABE
        TYA
        SZB     1
        BML     Send_1bit
        BML     Send_0bit
        TABE
        TYA
        SZB     2
        BML     Send_1bit
        BML     Send_0bit
        TABE
        TYA
        SZB     3
        BML     Send_1bit
        BML     Send_0bit
        TABE
        TYA
        INY
        TAY
;        SEA	10
        SEA	2                      ;20060424
	BL      Send_loop10
        .CLB	TRANSF
        LA      1000b
        TW4A
Send_loop20:
        SNZT1
        BL      Send_loop20
        LA	1000b
        TW2A
        LA      0000b
        TW1A
        RT
;***************************************
; Generate the HEAD of command 
; Refer to the signal wave
; Note : HEAD=(4.4ms)HIGH+(4.4ms)LOW
;***************************************
Head:
	LA      1000b			; PMW output is start
        TW2A
	LA	4
	TBA
	LA	6
	T2AB
	LA	2
	TBA
	LA	3
	T2HAB
	T2R2L
        LA      1010b			; PMW output is start
        TW2A
        LA      1000b			; auto control not select
        TW4A
        LA      0AH                     ; (0A9H = 169) * 1/37.6k = 4.5ms
        TBA
        LA      0AH
        T1AB                            ; Initial timer 1 count value
        SNZT1                           ; Clear T1F flag
        NOP                                     
        LA      0100b                   ; Start timer 1
        TW1A
Head0:
        SNZT1
        BL      Head0
        LA      1010b			; auto control select
        TW4A
Head1:
        SNZT1
        BL      Head1
        LA      0AH                     ; 0A9H = 169, 4.5ms
        TBA
        LA      0AH
        T1AB
Head2:                                 
        SNZT1                           
        BL      Head2
        LA      01H                     ; 15H = 21, 0.56ms
        TBA
        LA      05H
        T1AB
        RT
;----------------------------------------
Send_1bit:
        SNZT1
        BL      Send_1bit
        LA      04H			;  40H = 64, 1.69ms
        TBA
        LA      00H
        T1AB
Send_1bit0:
        SNZT1
        BL      Send_1bit0
        LA      01H
        TBA
        LA      04H
        T1AB
        RTS
;----------------------------------------
Send_0bit:
        SNZT1
        BL      Send_0bit
        LA      01H
        TBA
        LA      05H
        T1AB
Send_0bit0:
        SNZT1
        BL      Send_0bit0
        LA      01H
        TBA
        LA      05H
        T1AB
        RT