shell.plt

这是一个 York大学开发的FDTD代码。很好用的工具

#To run this file type load shell.gnu' at the gnuplot prompt
print " "
print "Gnuplot file to plot Shielding of spherical shells"
print "Also approximates cubic enclosure of same volume "
print " (C) M. P. Robinson & J. F. Dawson, University of York 1999"
print "See shell.gnu to set plot parameters"
print " "

#Parameters to adjust are near end of file

##### Setup gnuplot ######################################
set title "SE of spherical shell radius R thickness d" 0,0
set xlabel "Frequency (MHz)" 0,0
set xrange [0.001 : 1000]
set ylabel "SE (dB)" 2,0

############## Functions to compute Shielding #############################
#misc
dB(a)=20*log10(a)
antidB(a)=10.0**(0.05*a)
parallel(a,b)=a*b/(a+b)
MHz(f)=f*1e6

#Skin depth
delta(x,sigma)=503.0/sqrt(x*mur*sigma)

# Plane wave contributions to SE
R(x,sigma)=106+10*log10(sigma/(mur*x))
A(x,sigma)=8.69*d/delta(x,sigma)
B(x,sigma)=dB(1-exp(-2*d/delta(x,sigma)))

# Plane wave shielding effectivness of material
SEPW(x,sigma)=R(x,sigma)+A(x,sigma)+B(x,sigma)

SEthin(x)=dB(1+0.5*Z0/x)
g(x,sigma)=sqrt(j*2*pi*x*sigma*mur*mu0)
denom(x,sigma)=g(x,sigma)*sinh(g(x,sigma)*d)
num(x)=6*pi*pi*x*x*eps0*mur*mu0*R

#Electric field Shielding effectivness - Full range, LF approximation, HF Approximation
SEE(x,sigma)=-dB(abs(num(x)/denom(x,sigma)))
SEELF(x,sigma)=-dB(3*pi*x*eps0*R/(sigma*d))
SEEHF(x,sigma)=-dB(6.0*sqrt(2.0)*pi*x*eps0*R*exp(-d/delta(x,sigma))/(sigma*delta(x,sigma)))

#Magnetic field Shielding effectivness - Full range, LF approximation, HF Approximation
SEM(x,sigma)=dB(abs(cosh(g(x,sigma)*d)+0.3333*g(x,sigma)*R*sinh(g(x,sigma)*d)))
SEMLF(x,sigma)=dB(abs(1+0.3333*j*2*pi*x*mu0*R*sigma*d))
SEMHF(x,sigma)=-dB(3.0*sqrt(2.0)*delta(x,sigma)*exp(-d/delta(x,sigma))/R)
# Useful Constants
j = {0.0, 1.0}
c0 = 2.99792e+08
mu0 = 1.25664e-06
eps0 = 8.85419e-12
Z0 = 376.73

####################### ADJUST BELOW ###########################
# Shell Parameters - adjust these for your particular shell
# Also gives good approximation to cube of same volume
#Relative permeability of shell
mur = 1.0
#Thickness of shell
d = 0.0015
#Radius of shell
R = 0.137

#Some example material conductivities
CFRP = 30000.0
Cu = 5.8e+07
Ni_paint = 800000.0
brass = 1e+07
#################################################################
#Plot SE for "brass shell as specified above" - replace brass with desired conductivity, e.g. CFRP, Cu, Ni_paint or your own...
#print 'plot SEM(x,brass),SEE(x,brass),SEPW(x,brass)'
#pl SEM(x,brass),SEE(x,brass),SEPW(x,brass)
print 'pl SEM(MHz(x),CFRP),SEE(MHz(x),CFRP),SEPW(MHz(x),CFRP)'
pl SEM(MHz(x),CFRP),SEE(MHz(x),CFRP),SEPW(MHz(x),CFRP)