counter.asp

1、整个程序共三个文件（数据库、WEB页面、页面调用) 2、调用后显示：总IP量、今日访问量、今日IP量、昨日IP量、最高IP量、平均IP量、共统计天数 3、打开Counter.asp就可以任意调整显

<%
'********************************
'官方网站:http://www.ztren.com
'站长:贝o壳
'E-mail:[e-mail]
'发布日期:2008-6-9
'********************************

'连接数据库
Dim conn,connstr
on error resume next
connstr="DBQ="+server.mappath("#Date.mdb")+";DefaultDir=;DRIVER={Microsoft Access Driver (*.mdb)};"'数据库连接地址
set conn=server.createobject("ADODB.CONNECTION")
conn.open connstr

dim mRs,Userip,Oto,Zday,Counter,CountemRs,Today,Daynum,Yesterday,Top,Stats,Browser
	Userip = Request.ServerVariables("HTTP_X_FORWARDED_FOR")
	If Userip = "" Then Userip = Request.ServerVariables("REMOTE_ADDR")

Set mRs=Server.CreateObject("adodb.recordSet")
	Sql="Select * from [Counter]"
	mRs.open Sql,conn,1,3
	Oto=mRs("Oto")

	'判断日期是否为今天
		If Oto<>date() then

	'日期为当前时间-1
			Zday=date()-1
			application.lock

	'将今日IP,今日浏览改为0;日期改为当前日期,统计天数+1,昨日浏览
			conn.Execute"Update [Counter] Set Today=0,Browser=0,Oto=date(),Daynum=Daynum+1,Yesterday="& mRs("Today") &""

	'新增加总访问天数,每天的IP数,每天的访问量
			conn.Execute"Insert into [Day](Zday,Stats,Browser) values ('"& Zday &"',"& mRs("Today") &","& mRs("Browser") &")"
			application.unlock

	'删除所有IP
			conn.Execute"delete from [ip]"
		Else
			application.lock

	'今日浏览量+1
			conn.Execute"Update [Counter] Set Browser=Browser+1"
	'打开IP数据库,将当前IP写入数据库
			Set mRs=Server.CreateObject("adodb.recordSet")
			Sql="Select * from [Ip] where IP='"&Userip&"' order by Id desc"
			mRs.open Sql,conn,1,3
				If mRs.bof and mRs.eof then
					mRs.addnew
					mRs("IP")=Userip
					mRs.update
	'总访问人数+1,今日IP访问量+1
					conn.Execute"Update [Counter] Set Counter=Counter+1,Today=Today+1"
				End If
			mRs.close
			Set mRs=nothing
			application.unlock
		End If

	'开打数据库判断最高IP访问量是否大于数据库记录,如果大于替换为当前IP
			Set mRs=Server.CreateObject("adodb.recordSet")
			Sql="Select * from [Counter]"
			mRs.open Sql,conn,1,3
				If mRs("Top")<mRs("Today") then
					conn.Execute"Update [Counter] Set Top="&mRs("Today")&""
				End If
'显示总IP量
Response.Write"document.write(""总IP量：<b>"& mRs("Counter") &"</b>&nbsp;次&nbsp;&nbsp;"");"
'显示今日访问量
Response.Write"document.write(""今日访问量：<b>"& mRs("Browser") &"</b>&nbsp;&nbsp;"");"
'显示今日IP
Response.Write"document.write(""今日IP量：<b>"& mRs("Today") &"</b>&nbsp;&nbsp;"");"
'显示昨日IP
Response.Write"document.write(""昨日IP量：<b>"& mRs("Yesterday") &"</b>&nbsp;次&nbsp;&nbsp;"");"
'显示最高IP
Response.Write"document.write(""最高IP量：<b>"& mRs("Top") &"</b>&nbsp;&nbsp;"");"
'显示平均IP
Response.Write"document.write(""平均IP量：<b>"& int(mRs("Counter")/mRs("Daynum")) &"</b>&nbsp;&nbsp;"");"
'显示共统计多少天
Response.Write"document.write(""共统计：<b>"& mRs("Daynum") &"</b>&nbsp;天"");"

'关闭记录集和数据库
mRs.close
Set mRs=nothing
conn.close
Set conn=nothing
%>