flash.ld

做的是LCD液晶显示实验

MEMORY
{
        vectors (rx): org = 0x00000000, len = 0x00004000
        sdram : org = (0x00000000 +0x00004000), len = (0x02000000 -0x00004000 -(0x4000*5))
}
SECTIONS
{

        .debug 0 : { *(.debug) }
        .line 0 : { *(.line) }


        .debug_srcinfo 0 : { *(.debug_srcinfo) }
        .debug_sfnames 0 : { *(.debug_sfnames) }


        .debug_aranges 0 : { *(.debug_aranges) }
        .debug_pubnames 0 : { *(.debug_pubnames) }


        .debug_info 0 : { *(.debug_info) }
        .debug_abbrev 0 : { *(.debug_abbrev) }
        .debug_line 0 : { *(.debug_line) }
        .debug_frame 0 : { *(.debug_frame) }
        .debug_str 0 : { *(.debug_str) }
        .debug_loc 0 : { *(.debug_loc) }
        .debug_macinfo 0 : { *(.debug_macinfo) }


        .debug_weaknames 0 : { *(.debug_weaknames) }
        .debug_funcnames 0 : { *(.debug_funcnames) }
        .debug_typenames 0 : { *(.debug_typenames) }
        .debug_varnames 0 : { *(.debug_varnames) }

        .vectors : AT(0x00000000){
                *(.vectors)
                __vectors_end = . ;
                } > vectors

        .text : {
                *(.text)
                *(.rdata)
                *(.rodata)
                *(.gnu.linkonce.r*)
                *(.frame_info)
                *(.j_class_table)
                *(.gnu.linkonce.t*)
                *(.init)
                *(.init.*)
                *(.fini)
                *(.fini.*)
                *(.glue_7t)
                *(.glue_7)
                *(.eh_frame)
        } > sdram

        .ctors :
        {
                __CTOR_LIST__ = .;
                LONG( ( __CTOR_END__ - __CTOR_LIST__ ) / 4 - 1 )
                KEEP (*crtbegin.o(.ctors))
                KEEP (*(EXCLUDE_FILE (*crtend.o ) .ctors))
                KEEP (*(SORT(.ctors.*)))
                KEEP (*(.ctors))
                __CTOR_END__ = .;
                LONG( 0 )
        } > sdram

        .dtors :
        {
                __DTOR_LIST__ = .;
                LONG( ( __DTOR_END__ - __DTOR_LIST__ ) / 4 - 1 )
                KEEP (*crtbegin.o(.dtors))
                KEEP (*(EXCLUDE_FILE (*crtend.o ) .dtors))
                KEEP (*(SORT(.dtors.*)))
                KEEP (*(.dtors))
                __DTOR_END__ = .;
                LONG( 0 )
        } > sdram

        .jcr : { KEEP (*(.jcr)) } > sdram

        .sdata2 : {} > sdram

        __DATA_RAM = .;
        __DATA_ROM = . ;
        .data : {
                *(.data)
                *(.gnu.linkonce.d*)
                *(.gcc_except_table)
        } > sdram

        .sdata : {
                *(.sdata)
                *(.gnu.linkonce.s*)
        } > sdram

        __DATA_END = .;

        __BSS_START = .;
        .sbss : {}
        .bss : {
                *(.bss)
        } > sdram
        __BSS_END = .;
        end = .;
        _end = .;
        __HEAP_START = .;
}





__INT_SP_INIT = (0x00000000 +0x02000000) ;
__INT_SP_END = __INT_SP_INIT - 0x4000 ;

__FIQ_SP_INIT = __INT_SP_END ;
__FIQ_SP_END = __FIQ_SP_INIT - 0x4000 ;

__ABT_SP_INIT = __FIQ_SP_END ;
__ABT_SP_END = __ABT_SP_INIT - 0x4000 ;

__SVC_SP_INIT = __ABT_SP_END ;
__SVC_SP_END = __SVC_SP_INIT - 0x4000;

__USR_SP_INIT = __SVC_SP_END ;
__USR_SP_END = __USR_SP_INIT - 0x4000;

__HEAP_END = __USR_SP_END ;
__SP_END = __USR_SP_END ;

__IMAGE_DEST_ADDRESS = 0xc0000000 ;
__PHYSICAL_EXEC_ADDRESS = 0xd0000000 ;
__ALIAS_SETTING = 0x08 ;




__TMP_SP_INIT = (0xd1030000 +0x00004000);
__EH_FRAME_BEGIN__ = 0 ;