datacompfrm.pas

=== === === MiniHex 1.61 源程序说明 ============================== “$(MiniHex)Source”目录中的所有

unit DataCompFrm;

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms,
  Dialogs, ComCtrls, StdCtrls, ExtCtrls, ChildFrm, Compare;

type
  TDataCompData = record
    Para: TComparePara;
  end;

  TDataCompForm = class(TForm)
    WinListView: TListView;
    CompKindRadioGroup: TRadioGroup;
    CompFromRadioGroup: TRadioGroup;
    OkButton: TButton;
    CancelButton: TButton;
    Label1: TLabel;
    procedure FormCreate(Sender: TObject);
    procedure OkButtonClick(Sender: TObject);
    procedure CancelButtonClick(Sender: TObject);
  private
    { Private declarations }
    procedure FillListView;
    function CheckValid: Boolean;
  public
    { Public declarations }
    procedure GetData(var Value: TDataCompData);
  end;

var
  DataCompForm: TDataCompForm;

function ShowDataCompForm(var Value: TDataCompData): Boolean;

implementation

uses Misc, MainFrm;

{$R *.DFM}

function ShowDataCompForm(var Value: TDataCompData): Boolean;
var
  Frm: TDataCompForm;
begin
  if MainForm.GetDocCount < 2 then
  begin
    MsgBox('请打开两个或两个以上的文档后再进行数据比较。');
    Result := False;
    Exit;
  end;
  Frm := TDataCompForm.Create(Application);
  Result := (Frm.ShowModal = mrOk);
  if Result  then Frm.GetData(Value);
  Frm.Free;
end;

procedure TDataCompForm.GetData(var Value: TDataCompData);
var
  I: Integer;
begin
  Value.Para.Form1 := nil;
  Value.Para.Form2 := nil;
  for I := 0 to WinListView.Items.Count - 1 do
  begin
    if (Value.Para.Form1 <> nil) and (Value.Para.Form2 <> nil) then Break;
    if WinListView.Items[I].Checked then
    begin
      if Value.Para.Form1 = nil then
        Value.Para.Form1 := WinListView.Items[I].Data
      else
        Value.Para.Form2 := WinListView.Items[I].Data;
    end;
  end;
  Value.Para.CompKind := TCompareKind(CompKindRadioGroup.ItemIndex);
  Value.Para.CompFrom := TCompareFrom(CompFromRadioGroup.ItemIndex);
end;

function TDataCompForm.CheckValid: Boolean;
var
  I, J: Integer;
begin
  Result := True;
  J := 0;
  for I := 0 to WinListView.Items.Count - 1 do
    if WinListView.Items[I].Checked then Inc(J);
  if J <> 2 then
  begin
    Result := False;
    MsgBox('请从列表中选择两个文件。');
    WinListView.SetFocus;
  end;
end;

procedure TDataCompForm.FillListView;
var
  HexFrm: TChildForm;
  ListItem: TListItem;
  I: Integer;
begin
  WinListView.Items.BeginUpdate;
  WinListView.Items.Clear;
  for I := 0 to MainForm.MDIChildCount - 1 do
  begin
    if MainForm.MDIChildren[I] is TChildForm then
    begin
      HexFrm := (MainForm.MDIChildren[I] as TChildForm);

      ListItem := WinListView.Items.Add;
      ListItem.Caption := HexFrm.FileName;
      ListItem.SubItems.Add(IntToStr(HexFrm.HexEdit.DataSize));
      ListItem.SubItems.Add(IntToStr(HexFrm.HexEdit.Offset));
      ListItem.Data := HexFrm;

      if MainForm.ActiveMDIChild = HexFrm then
        WinListView.Selected := ListItem;
    end;
  end;
  WinListView.Items.EndUpdate;
end;

procedure TDataCompForm.FormCreate(Sender: TObject);
begin
  FillListView;
  if WinListView.Items.Count = 2 then
  begin
    WinListView.Items[0].Checked := True;
    WinListView.Items[1].Checked := True;
  end else
  begin
    WinListView.Selected.Checked := True;
  end;
end;

procedure TDataCompForm.OkButtonClick(Sender: TObject);
begin
  if CheckValid then
    ModalResult := mrOk;
end;

procedure TDataCompForm.CancelButtonClick(Sender: TObject);
begin
  ModalResult := mrCancel;
end;

end.