compare.pas

=== === === MiniHex 1.61 源程序说明 ============================== “$(MiniHex)Source”目录中的所有

{**********************************************************}
{  功能：实现数据比较.                                     }
{**********************************************************}

unit Compare;

interface

uses
  Windows, Messages, SysUtils, Classes, Controls, Forms, Dialogs, ChildFrm;

type
  TCompareKind = (ckCompareDiff, ckCompareSame);
  TCompareFrom = (cfFromHead, cfFromCur);

  TComparePara = record
    Form1, Form2: TChildForm;
    CompKind: TCompareKind;
    CompFrom: TCompareFrom;
  end;

  TCompareMgr = class
  private
    FPara: TComparePara;
    FResultOffset1: Integer;
    FResultOffset2: Integer;

    function Compare(CompKind: TCompareKind; CompFrom: TCompareFrom; CompNext: Boolean): Boolean;
  public
    property Para: TComparePara read FPara write FPara;
    property ResultOffset1: Integer read FResultOffset1;
    property ResultOffset2: Integer read FResultOffset2;

    function CompareFirst: Boolean;
    function CompareNext: Boolean;
    function FormExists: Boolean;
  end;

implementation

uses
  Misc, MainFrm;

function TCompareMgr.Compare(CompKind: TCompareKind; CompFrom: TCompareFrom; CompNext: Boolean): Boolean;
var
  I, Count: Integer;
  FromOffset1, ToOffset1: Integer;
  FromOffset2, ToOffset2: Integer;
  Offset1, Offset2: Integer;
  Find: Boolean;
begin
  if CompFrom = cfFromCur then
  begin
    FromOffset1 := FPara.Form1.HexEdit.Offset;
    FromOffset2 := FPara.Form2.HexEdit.Offset;
  end else
  begin
    FromOffset1 := 0;
    FromOffset2 := 0;
  end;
  ToOffset1 := FPara.Form1.HexEdit.DataSize - 1;
  ToOffset2 := FPara.Form2.HexEdit.DataSize - 1;
  if CompNext then
  begin
    Inc(FromOffset1);
    Inc(FromOffset2);
  end;

  Count := ToOffset1 - FromOffset1;
  if Count > (ToOffset2 - FromOffset2) then
    Count := ToOffset2 - FromOffset2;

  for I := 0 to Count - 1 do
  begin
    Offset1 := I + FromOffset1;
    Offset2 := I + FromOffset2;
    if CompKind = ckCompareSame then
    begin
      Find := (FPara.Form1.HexEdit.DataAddr[Offset1] = FPara.Form2.HexEdit.DataAddr[Offset2]);
    end else
    begin
      Find := (FPara.Form1.HexEdit.DataAddr[Offset1] <> FPara.Form2.HexEdit.DataAddr[Offset2]);
    end;
    if Find then
    begin
      Result := True;
      FResultOffset1 := Offset1;
      FResultOffset2 := Offset2;
      Exit;
    end;
  end;
  Result := False;
  FResultOffset1 := -1;
  FResultOffset2 := -1;
end;

function TCompareMgr.CompareFirst: Boolean;
begin
  Result := Compare(FPara.CompKind, FPara.CompFrom, False);
  if Result then
  begin
    FPara.Form1.BringToFront;
    FPara.Form1.HexEdit.Offset := FResultOffset1;
    FPara.Form2.HexEdit.Offset := FResultOffset2;
    if FResultOffset1 = FResultOffset2 then
      FPara.Form2.HexEdit.TopRow := FPara.Form1.HexEdit.TopRow;
  end else
  begin
    MsgBox('比较完毕。');
  end;
end;

function TCompareMgr.CompareNext: Boolean;
begin
  Result := Compare(FPara.CompKind, cfFromCur, True);
  if Result then
  begin
    FPara.Form1.BringToFront;
    FPara.Form1.HexEdit.Offset := FResultOffset1;
    FPara.Form2.HexEdit.Offset := FResultOffset2;
    if FResultOffset1 = FResultOffset2 then
      FPara.Form2.HexEdit.TopRow := FPara.Form1.HexEdit.TopRow;
  end else
  begin
    MsgBox('比较完毕。');
  end;
end;

function TCompareMgr.FormExists: Boolean;
var
  I: Integer;
begin
  Result := False;
  for I := 0 to MainForm.MDIChildCount - 1 do
  begin
    if MainForm.MDIChildren[I] = FPara.Form1 then
    begin
      Result := True;
      Break;
    end;
  end;
  if not Result then Exit;
  Result := False;
  for I := 0 to MainForm.MDIChildCount - 1 do
  begin
    if MainForm.MDIChildren[I] = FPara.Form2 then
    begin
      Result := True;
      Break;
    end;
  end;
end;

end.