configure.in

一段linux下用OpenGL实现的小程序

dnl Process this file with autoconf to produce a configure script.

dnl Simple Automake init
AC_INIT(sscroll.c)
AC_CANONICAL_HOST
AC_CANONICAL_TARGET
AM_INIT_AUTOMAKE(smoothscroll, 1.1)

dnl Look for X
AC_PATH_X
AC_PATH_XTRA

AC_MSG_CHECKING(target platform);
case "$target_os" in
	linux*)
		AC_MSG_RESULT(GNU/Linux)
		MATHLIB="-lm"
		if test x$have_x = xyes; then
			CFLAGS="$CFLAGS $X_CFLAGS"
			SYS_GL_LIBS="$X_LIBS -lGL"
		else
			SYS_GL_LIBS="-lGL"
		fi
		;;
	beos)
		AC_MSG_RESULT(BeOS)
		MATHLIB=""
		SYS_GL_LIBS="-lGL"
		;;
	mingw32*)
		AC_MSG_RESULT(Win32 (mingw32))
		MATHLIB=""
		SYS_GL_LIBS="-lopengl32"
		;;
	cygwin*)
		AC_MSG_RESULT(Win32 (cygwin))
		MATHLIB=""
		SYS_GL_LIBS="-lopengl32"
		;;
	darwin*)
		AC_MSG_RESULT(Mac OS X/Darwin)
		MATHLIB=""
		;;
	aix*)
		AC_MSG_RESULT(AIX)
		if test x$ac_cv_c_compiler_gnu = xyes; then
			CFLAGS="-mthreads"
		fi
		if test x$have_x = xyes; then
			CFLAGS="$CFLAGS $X_CFLAGS"
			SYS_GL_LIBS="$X_LIBS -lGL"
		else
			SYS_GL_LIBS="-lGL"
		fi
		;;
	solaris*)
		AC_MSG_RESULT(Solaris SPARC)
		MATHLIB="-lm"
		CFLAGS="$CFLAGS $X_CFLAGS"
		SYS_GL_LIBS="-lGL"
		;;
	*)
		AC_MSG_RESULT(Unknown (assuming Un*x-like))
	        MATHLIB="-lm"
		if test x$have_x = xyes; then
			CFLAGS="$CFLAGS $X_CFLAGS"
			SYS_GL_LIBS="$X_LIBS -lGL"
		else
			SYS_GL_LIBS="-lGL"
		fi
		;;
esac
AC_SUBST(MATHLIB)

dnl Check for various tools
AC_PROG_CC
AC_PROG_CPP

dnl Check for SDL 1.2.0+
SDL_VERSION=1.2.0
AM_PATH_SDL($SDL_VERSION,:,AC_MSG_ERROR([*** SDL >= $SDL_VERSION not found!]))

AC_CHECK_HEADERS(SDL/SDL_opengl.h)

dnl Checks for OpenGL
AC_MSG_CHECKING(for OpenGL support)
have_opengl=no
AC_TRY_COMPILE([
	#ifdef WIN32
	#include <windows.h>
	#endif
	#if defined(__APPLE__) && defined(__MACH__)
	#include <OpenGL/gl.h>
	#else
	#include <GL/gl.h>
	#endif
],[
],[
have_opengl=yes
])
AC_MSG_RESULT($have_opengl)
if test x$have_opengl = xyes; then
	CFLAGS="$CFLAGS -DHAVE_OPENGL"
	CXXFLAGS="$CXXFLAGS -DHAVE_OPENGL"
	GL_LIBS="$SYS_GL_LIBS"
else
	GL_LIBS=""
fi
AC_SUBST(GL_LIBS)

dnl Get compile and linking flags
CFLAGS="$CFLAGS $SDL_CFLAGS"
LIBS="$LIBS $SDL_LIBS"

dnl Generate Makefile
AC_OUTPUT(Makefile)