ecma.txt

sswf-1.7.4-src.zip 源码

	PostfixExpression
	ContinueStatement
	BreakStatement
	ReturnStatement
	ThrowStatement



SourceCharacter ::
	any Unicode character



PrimaryExpression ::
	'this'
	Identifier
	Literal
	ArrayLiteral
	ObjectLiteral
	'(' Expression ')'


ArrayLiteral ::
	'[' Elision/opt ']'
	'[' ElementList ']'
	'[' ElementList ',' Elision/opt ']'

[can be simplified to:]
ArrayLiteral ::
	'[' Elision/opt ']'
	'[' ElementList Elision/opt ']'


ElementList ::
	Elision/opt AssignmentExpression
	ElementList ',' Elision/opt AssignmentExpression

Elision ::
	','
	Elision ','



ObjectLiteral ::
	'{' PropertyNameAndValueList/opt '}'

PropertyNameAndValueList ::
	PropertyName ':' AssignmentExpression
	PropertyNameAndValueList ',' PropertyName ':' AssignmentExpression

PropetyName ::
	Identifier
	StringLiteral
	NumericLiteral


MemberExpression ::
	PrimaryExpression
	FunctionExpression
	MemberExpression '[' Expression ']'
	MemberExpression '.' Identifier
	'new' MemberExpression Arguments

NewExpression ::
	MemberExpression
	'new' NewExpression

CallExpression ::
	MemberExpression Arguments
	CallExpression Arguments
	CallExpression '[' Expression ']'
	CallExpression '.' Identifier

Arguemnts ::
	'(' ArgumentList/opt ')'

ArgumentList ::
	AssignmentExpression
	ArgumentList ',' AssignmentExpression

LeftHandSideExpression ::
	NewExpression
	CallExpression


PostfixExpression ::
	LeftHandSideExpression
	LeftHandSideExpression [no LineTerminator here] '++'
	LeftHandSideExpression [no LineTerminator here] '--'


UnaryExpression ::
	PostfixExpression
	'delete' UnaryExpression
	'void' UnaryExpression
	'typeof' UnaryExpression
	'++' UnaryExpression
	'--' UnaryExpression
	'+' UnaryExpression
	'-' UnaryExpression
	'~' UnaryExpression
	'!' UnaryExpression


['void' returns 'undefined']
['typeof' returns one of "undefined", "oject", "boolean",
"number", "string", "function", <implementation dependent>]



MultiplicativeExpression ::
	UnaryExpression
	MultiplicativeExpression '*' UnaryExpression
	MultiplicativeExpression '/' UnaryExpression
	MultiplicativeExpression '%' UnaryExpression


AdditiveExpression ::
	MultiplicativeExpression
	AdditiveExpression '+' MultiplicativeExpression
	AdditiveExpression '-' MultiplicativeExpression

ShiftExpression ::
	AdditiveExpression
	ShiftExpression '<<' AdditiveExpression
	ShiftExpression '>>' AdditiveExpression
	ShiftExpression '>>>' AdditiveExpression

RelationalExpression ::
	ShiftExpression
	RelationalExpression '<' ShiftExpression
	RelationalExpression '>' ShiftExpression
	RelationalExpression '<=' ShiftExpression
	RelationalExpression '>=' ShiftExpression
	RelationalExpression 'instanceof' ShiftExpression
	RelationalExpression 'in' ShiftExpression

RelationalExpressionNoIn ::
	ShiftExpression
	RelationalExpressionNoIn '<' ShiftExpression
	RelationalExpressionNoIn '>' ShiftExpression
	RelationalExpressionNoIn '<=' ShiftExpression
	RelationalExpressionNoIn '>=' ShiftExpression
	RelationalExpressionNoIn 'instanceof' ShiftExpression


EqualityExpression ::
	RelationalExpression
	EqualityExpression '==' RelationalExpression
	EqualityExpression '!=' RelationalExpression
	EqualityExpression '===' RelationalExpression
	EqualityExpression '!==' RelationalExpression

EqualityExpressionNoIn ::
	RelationalExpressionNoIn
	EqualityExpressionNoIn '==' RelationalExpressionNoIn
	EqualityExpressionNoIn '!=' RelationalExpressionNoIn
	EqualityExpressionNoIn '===' RelationalExpressionNoIn
	EqualityExpressionNoIn '!==' RelationalExpressionNoIn


BitwiseANDExpression ::
	EqualityExpression
	BitwiseANDExpression '&' EqualityExpression

BitwiseANDExpressionNoIn ::
	EqualityExpressionNoIn
	BitwiseANDExpressionNoIn '&' EqualityExpressionNoIn

BitwiseXORExpression ::
	BitwsieANDExpression
	BitwiseXORExpression '^' BitwsieANDExpression

BitwiseXORExpressionNoIn ::
	BitwsieANDExpressionNoIn
	BitwiseXORExpressionNoIn '^' BitwsieANDExpressionNoIn

BitwiseORExpression ::
	BitwsieXORExpression
	BitwiseORExpression '^' BitwsieXORExpression

BitwiseORExpressionNoIn ::
	BitwsieXORExpressionNoIn
	BitwiseORExpressionNoIn '^' BitwsieXORExpressionNoIn



LogicalANDExpression ::
	BitwiseORExpression
	LogicalANDExpression '&&' BitwiseORExpression

LogicalANDExpressionNoIn ::
	BitwiseORExpressionNoIn
	LogicalANDExpressionNoIn '&&' BitwiseORExpressionNoIn


LogicalORExpression ::
	LogicalANDExpression
	LogicalORExpression '||' LogicalANDExpression

LogicalORExpressionNoIn ::
	LogicalANDExpressioNoIn
	LogicalORExpressionNoIn '||' LogicalANDExpressioNoIn



ConditionalExpression ::
	LogicalORExpression
	LogicalORExpression '?' AssignmentExpression ':' AssignmentExpression

ConditionalExpressionNoIn ::
	LogicalORExpressionNoIn
	LogicalORExpressionNoIn '?' AssignmentExpression ':' AssignmentExpressionNoIn


AssignmentExpression ::
	ConditionalExpression
	LeftHandSideExpression AssignmentOperator AssignmentExpression

AssignmentExpressionNoIn ::
	ConditionalExpressionNoIn
	LeftHandSideExpression AssignmentOperator AssignmentExpressionNoIn

AssignmentOperator ::
	'='
	'*='
	'/='
	'%='
	'+='
	'-='
	'<<='
	'>>='
	'>>>='
	'&='
	'^='
	'|='

Expression ::
	AssignmentExpression
	Expression ',' AssignmentExpression

ExpresionNoIn ::
	AssignmentExpressionNoIn
	ExpressionNoIn ',' AssignmentExpressionNoIn






Statement ::
	Block
	VariableStatement
	EmptyStatement
	ExpressionStatement
	IfStatement
	IterationStatement
	ContinueStatement
	BreakStatement
	ReturnStatement
	WithStatement
	LabelledStatement
	SwitchStatement
	ThrowStatement
	TryStatement


Block ::
	'{' StatementList/opt '}'

StatementList ::
	Statement
	StatementList Statement

VariableStatement::
	'var' VariableDeclarationList ';'

VariableDeclarationList ::
	VariableDeclaration
	VariableDeclarationList ',' VariableDeclaration

VariableDeclarationListNoIn ::
	VariableDeclarationNoIn
	VariableDeclarationListNoIn ',' VariableDeclarationNoIn

VariableDeclaration ::
	Identifier Initializer/opt

VariableDeclarationNoIn ::
	Identifier InitializerNoIn/opt

Initializer ::
	'=' AssignmentExpression

InitializerNoIn ::
	'=' AssignmentExpressionNoIn



EmptyStatement ::
	';'


ExpressionStatement ::
	Expression ';' BUT NOT '{' or 'function'



IfStatement ::
	'if' '(' Expression ')' Statement 'else' Statement
	'if' '(' Expression ')' Statement


IterationStatement ::
	'do' Statement 'while' '(' Expression ')' ';'
	'while' '(' Expression ')' statement
	'for' '(' ExpressionNoIn/opt ';' ExpressionNoIn/opt ';' ExpressionNoIn/opt ')' Statement
	'for' '(' 'var' VariableDeclarationListNoIn ';' ExpressionNoIn/opt ';' ExpressionNoIn/opt ')' Statement
	'for' '(' LeftHandSideExpression 'in' Expression ')' Statement
	'for' '(' 'var' VariableDeclarationListNoIn 'in' Expression ')' Statement



ContinueStatement ::
	'continue' [no LineTerminator here] Identifier/opt ';'

BreakStatement ::
	'break' [no LineTerminator here] Identifier/opt ';'


ReturnStatement ::
	'return' [no LineTerminator here] Expression/opt ';'


WithStatement ::
	'with' '(' Expression ')' Statement


SwitchStatement ::
	'switch' '(' Expression ')' CaseBlock

CaseBlock ::
	'{' CaseClauses/opt '}'
	'{' CaseClauses/opt DefaultClause CaseClauses/opt '}'

CaseClauses ::
	CaseClause
	CaseClauses CaseClause

CaseClause ::
	'case' Expression ':' StatementList/opt

DefaultClause ::
	'default' ':' StatementList/opt


LabelledStatement ::
	Identifier ':' Statement



ThrowStatement ::
	'throw' [no LineTerminator here] Expression ';'



TryStatement ::
	'try' Block Catch
	'try' Block Finally
	'try' Block Catch Finally

Catch ::
	'catch' '(' Identifier ')' Block

Finally ::
	'finally' Block



FunctionDeclaration ::
	'function' Identifier '(' FormalParameterList/opt ')' '{' FunctionBody '}'

FunctionExpression ::
	'function' Identifier/opt '(' FormalParameterList/opt ')' '{' FunctionBody '}'


FormalParameterList ::
	Identifier
	FormalParameterList ',' Identifier

FunctionBody ::
	SourceElements



Program ::
	SourceElements

SourceElements ::
	SourceElement
	SourceElements SourceElement

SourceElement ::
	Statement
	FunctionDeclaration



[we may offer as much syntax check as we want at
compile time -- that is, on top of the minimum
requirements]

[we may have additional types, values, objects,
properties and functions]




[number conversion -- only necessary if we want to
check strings which we know are to be converted to numbers]

StringNumericLiteral ::
	StrWhiteSpace/opt
	StrWhiteSpace/opt StrNumericLiteral StrWhiteSpace/opt

StrWhiteSpace ::
	StrWhiteSpaceChar StrWhiteSpace/opt

StrWhiteSpaceChar ::
	<TAB>
	<SP>
	<NBSP>
	<FF>
	<VT>
	<CR>
	<LF>
	<LS>
	<PS>
	<USP>

StrNumericLiteral ::
	StrDecimalLiteral
	HexIntegerLiteral

StrDecimalLiteral ::
	StrUnsignedDecimalLiteral
	'+' StrUnsignedDecimalLiteral
	'-' StrUnsignedDecimalLiteral

StrUnsignedDecimalLiteral ::
	'Infinity'
	DecimalDigits '.' DecimalDigits/opt ExponentPart/opt
	'.' DecimalDigits ExponentPart/opt
	DecimalDigits ExponentPart/opt