t8254-1.asm

8254计数试验程序

;T8254-1.asm
;8254计数应用实验

;***************根据CHECK配置信息修改下列符号值*******************
INTR_IVADD     EQU   01CCH        ;INTR对应的中断矢量地址
INTR_OCW1      EQU   0A1H         ;INTR对应PC机内部8259的OCW1地址
INTR_OCW2      EQU   0A0H         ;INTR对应PC机内部8259的OCW2地址
INTR_IM        EQU   0F7H         ;INTR对应的中断屏蔽字
PCI_INTCSR     EQU   9438H        ;PCI卡中断控制寄存器地址
IOY0           EQU   9C00H
;*****************************************************************
MY8254_COUNT0  EQU   IOY0+00H*4   ;8254计数器0端口地址
MY8254_COUNT1  EQU   IOY0+01H*4   ;8254计数器1端口地址
MY8254_COUNT2  EQU   IOY0+02H*4   ;8254计数器2端口地址
MY8254_MODE    EQU   IOY0+03H*4   ;8254控制寄存器端口地址
                              
STACK1 SEGMENT STACK
        DW 256 DUP(?)
STACK1 ENDS

DATA SEGMENT 
CS_BAK   DW  ?                    ;保存INTR原中断处理程序入口段地址的变量
IP_BAK   DW  ?                    ;保存INTR原中断处理程序入口偏移地址的变量
IM_BAK   DB  ?                    ;保存INTR原中断屏蔽字的变量
STR1     DB  'COUNT: $'           ;显示的字符串
DATA ENDS

CODE SEGMENT
        ASSUME CS:CODE,DS:DATA

START: MOV AX,DATA
       MOV DS,AX
       CLI

       MOV DX,PCI_INTCSR
       SUB DX,19H
       IN  AL,DX 
       MOV DX,PCI_INTCSR          ;初始化PCI卡中断控制寄存器
       MOV AX,1F00H               ;向PCI_INTCSR中写入003F1F00H
       OUT DX,AX
       ADD DX,2
       MOV AX,003FH
       OUT DX,AX

       MOV AX,0000H               ;替换INTR的中断矢量
       MOV ES,AX
       MOV DI,INTR_IVADD          
       MOV AX,ES:[DI]
       MOV IP_BAK,AX              ;保存INTR原中断处理程序入口偏移地址
       MOV AX,OFFSET MYISR
       MOV ES:[DI],AX             ;设置当前中断处理程序入口偏移地址

       ADD DI,2
       MOV AX,ES:[DI]
       MOV CS_BAK,AX              ;保存INTR原中断处理程序入口段地址
       MOV AX,SEG MYISR
       MOV ES:[DI],AX             ;设置当前中断处理程序入口段地址

       MOV DX,INTR_OCW1           ;设置中断屏蔽寄存器，打开INTR的屏蔽位
       IN  AL,DX
       MOV IM_BAK,AL              ;保存INTR原中断屏蔽字
       AND AL,INTR_IM
       OUT DX,AL

       STI
       MOV DX,OFFSET STR1         ;显示字符串
       MOV AH,9
       INT 21H

       MOV DX,MY8254_MODE         ;初始化8254工作方式
       MOV AL,10H                 ;计数器0，方式0  
       OUT DX,AL             

       MOV DX,MY8254_COUNT0       ;装入计数初值
       MOV AL,4
       OUT DX,AL

WAIT1: MOV AH,1                   ;判断是否有按键按下
       INT 16H
       JZ  WAIT1                  ;无按键则跳回继续等待，有则退出

QUIT:  CLI
       MOV DX,PCI_INTCSR          ;恢复PCI卡中断控制寄存器
       MOV AX,0000H
       OUT DX,AX

       MOV AX,0000H               ;恢复INTR原中断矢量
       MOV ES,AX
       MOV DI,INTR_IVADD  
       MOV AX,IP_BAK              ;恢复INTR原中断处理程序入口偏移地址
       MOV ES:[DI],AX
       ADD DI,2
       MOV AX,CS_BAK              ;恢复INTR原中断处理程序入口段地址
       MOV ES:[DI],AX

       MOV DX,INTR_OCW1           ;恢复INTR原中断屏蔽寄存器的屏蔽字
       MOV AL,IM_BAK
       OUT DX,AL
       STI

       MOV AX,4C00H               ;返回到DOS
       INT 21H

MYISR PROC NEAR                   ;中断处理程序MYISR
       MOV AL,35H
       MOV AH,0EH
       INT 10H
       MOV AL,20H
       INT 10H

       MOV DX,MY8254_COUNT0       ;重装计数初值
       MOV AL,4
       OUT DX,AL

OVER:  MOV DX,PCI_INTCSR          ;清PCI卡中断控制寄存器标志位
       SUB DX,19H
       IN  AL,DX
       MOV DX,PCI_INTCSR
       ADD DX,2
       MOV AX,003FH
       OUT DX,AX

       MOV DX,INTR_OCW2           ;向PC机内部8259发送中断结束命令
       MOV AL,20H
       OUT DX,AL
       MOV AL,20H
       OUT 20H,AL
       IRET
MYISR ENDP
       
CODE ENDS
     END START