cstart.s

来自「qnx powerpc MPC8245的 BSP源文件」· S 代码 · 共 71 行

#  
# Copyright 2007, QNX Software Systems. 
#  
# Licensed under the Apache License, Version 2.0 (the "License"). You 
# may not reproduce, modify or distribute this software except in 
# compliance with the License. You may obtain a copy of the License 
# at: http://www.apache.org/licenses/LICENSE-2.0 
#  
# Unless required by applicable law or agreed to in writing, software 
# distributed under the License is distributed on an "AS IS" basis, 
# WITHOUT WARRANTIES OF ANY KIND, either express or implied.
# 
# This file may contain contributions from others, either as 
# contributors under the License or as licensors under other terms.  
# Please review this entire file for other proprietary rights or license 
# notices, as well as the QNX Development Suite License Guide at 
# http://licensing.qnx.com/license-guide/ for other information.
# 
# cstart.s
#	Initial code to get Neutrino started
#
	.data
	.globl	stack
	.globl	boot_args
boot_args:
	.ascii	"ddpvbskr"	# signature for mkifs 
stack_end:
	.space	3*1024
stack:
	.space	16
	
boot_regs:
	.space	32*4

	.text

	.extern	_SDA_BASE_
	.extern	_SDA2_BASE_
	.extern	_main
	.globl	_start
	.globl	boot_regs

_start:
	#
	# save initial boot register values
	#
	mtspr	0x1a,%r31
	lis		%r31,boot_regs@ha
	la		%r31,boot_regs@l(%r31)
	stmw	%r0,0(%r31)
	mfspr	%r0,0x1a
	stw		%r0,31*4(%r31)
	#
	# disable interrupts
	#
	mfmsr	%r0
	rlwinm	%r0,%r0,0,17,15
	mtmsr	%r0
	#
	# Get SP and SDA's set up, and then on to C
	#
	lis		%r1,stack@ha	
	la  	%r1,stack@l(%r1)
	lis		%r13,_SDA_BASE_@ha				
	la		%r13,_SDA_BASE_@l(%r13)
	lis		%r2,_SDA2_BASE_@ha				
	la		%r2,_SDA2_BASE_@l(%r2)
	
	b		_main