setjmp.s

来自「标准c库代码,可以应用于各个系统提供了大量的基本函数」· S 代码 · 共 127 行

/* This is a simple version of setjmp and longjmp for the PowerPC.
   Ian Lance Taylor, Cygnus Support, 9 Feb 1994.  */

	.globl	setjmp
setjmp:
	stw	13,0(3)
	stwu	14,4(3)
	stwu	15,4(3)
	stwu	16,4(3)
	stwu	17,4(3)
	stwu	18,4(3)
	stwu	19,4(3)
	stwu	20,4(3)
	stwu	21,4(3)
	stwu	22,4(3)
	stwu	23,4(3)
	stwu	24,4(3)
	stwu	25,4(3)
	stwu	26,4(3)
	stwu	27,4(3)
	stwu	28,4(3)
	stwu	29,4(3)
	stwu	30,4(3)
	stwu	31,4(3)
	stfdu	14,4(3)
	stfdu	15,8(3)
	stfdu	16,8(3)
	stfdu	17,8(3)
	stfdu	18,8(3)
	stfdu	19,8(3)
	stfdu	20,8(3)
	stfdu	21,8(3)
	stfdu	22,8(3)
	stfdu	23,8(3)
	stfdu	24,8(3)
	stfdu	25,8(3)
	stfdu	26,8(3)
	stfdu	27,8(3)
	stfdu	28,8(3)
	stfdu	29,8(3)
	stfdu	30,8(3)
	stfdu	31,8(3)
	mflr	4
	stwu	4,8(3)
	mfctr	4
	stwu	4,4(3)
	mfxer	4
	stwu	4,4(3)
	mfcr	4
	stwu	4,4(3)

	/* This requires a total of 19 * 4 + 18 * 8 + 4 + 4 + 4 + 4
	   bytes == 59 * 4 bytes == 236 bytes.  */

	li	3,0
	blr
LT..setjmp:
	.long	0
	.byte	0,12,34,64,0,0,1,0
	.long	0
	.long	LT..setjmp-setjmp
	.short	6
	.ascii	"setjmp"


	.globl	longjmp
longjmp:
	lwz	13,0(3)
	lwzu	14,4(3)
	lwzu	15,4(3)
	lwzu	16,4(3)
	lwzu	17,4(3)
	lwzu	18,4(3)
	lwzu	19,4(3)
	lwzu	20,4(3)
	lwzu	21,4(3)
	lwzu	22,4(3)
	lwzu	23,4(3)
	lwzu	24,4(3)
	lwzu	25,4(3)
	lwzu	26,4(3)
	lwzu	27,4(3)
	lwzu	28,4(3)
	lwzu	29,4(3)
	lwzu	30,4(3)
	lwzu	31,4(3)
	lfdu	14,4(3)
	lfdu	15,8(3)
	lfdu	16,8(3)
	lfdu	17,8(3)
	lfdu	18,8(3)
	lfdu	19,8(3)
	lfdu	20,8(3)
	lfdu	21,8(3)
	lfdu	22,8(3)
	lfdu	23,8(3)
	lfdu	24,8(3)
	lfdu	25,8(3)
	lfdu	26,8(3)
	lfdu	27,8(3)
	lfdu	28,8(3)
	lfdu	29,8(3)
	lfdu	30,8(3)
	lfdu	31,8(3)
	lwzu	5,8(3)
	mtlr	5
	lwzu	5,4(3)
	mtctr	5
	lwzu	5,4(3)
	mtxer	5
	lwzu	5,4(3)
	mtcrf	255,5

	mr	3,4
	cmpi	1,3,0
	bne	1f
	li	3,1
1:
	blr
LT..longjmp:
	.long	0
	.byte	0,12,34,64,0,0,1,0
	.long	0
	.long	LT..longjmp-longjmp
	.short	7
	.ascii	"longjmp"