frmtp.frm

企业人事管理系统,有考勤,人员管理等功能,值得研究,也是我付费弄来的,绝对超值

VERSION 5.00
Begin VB.Form frmTP 
   Caption         =   "加载托盘"
   ClientHeight    =   735
   ClientLeft      =   60
   ClientTop       =   345
   ClientWidth     =   2235
   Icon            =   "frmTP.frx":0000
   LinkTopic       =   "Form1"
   ScaleHeight     =   49
   ScaleMode       =   3  'Pixel
   ScaleWidth      =   149
   StartUpPosition =   3  '窗口缺省
End
Attribute VB_Name = "frmTP"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = False
Attribute VB_PredeclaredId = True
Attribute VB_Exposed = False
Private Declare Function SetForegroundWindow Lib "User32" (ByVal hWnd As Long) As Long

Private Declare Function Shell_NotifyIcon Lib "shell32.dll" Alias "Shell_NotifyIconA" (ByVal dwMessage As Long, lpData As NOTIFYICONDATA) As Long

Private Declare Function SendMessage Lib "User32" Alias "SendMessageA" (ByVal hWnd As Long, ByVal wMsg As Long, ByVal wParam As Long, lParam As Any) As Long

Private Const WM_SYSCOMMAND = &H112
Private Const SC_RESTORE = &HF120&
'---------- dwMessage可以是以下NIM_ADD、NIM_DELETE、NIM_MODIFY 标识符之一----------
Private Const NIM_ADD = &H0 '在任务栏中增加一个图标
Private Const NIM_DELETE = &H2 '删除任务栏中的一个图标
Private Const NIM_MODIFY = &H1 '修改任务栏中个图标信息

Private Const NIF_MESSAGE = &H1 'NOTIFYICONDATA结构中uFlags的控制信息
Private Const NIF_ICON = &H2
Private Const NIF_TIP = &H4

Private Const WM_MOUSEMOVE = &H200 '当鼠标指针移至图标上

Private Const WM_LBUTTONUP = &H202
Private Const WM_RBUTTONUP = &H205

Private Type NOTIFYICONDATA
  cbSize As Long '该数据结构的大小
  hWnd As Long '处理任务栏中图标的窗口句柄
  uID As Long '定义的任务栏中图标的标识
  uFlags As Long '任务栏图标功能控制，可以是以下值的组合（一般全包括）
  'NIF_MESSAGE 表示发送控制消息；
  'NIF_ICON表示显示控制栏中的图标；
  'NIF_TIP表示任务栏中的图标有动态提示。
  uCallbackMessage As Long '任务栏图标通过它与用户程序交换消息，处理该消息的窗口由hWnd决定
  hIcon As Long '任务栏中的图标的控制句柄
  szTip As String * 64 '图标的提示信息
End Type
Dim mydata As NOTIFYICONDATA

Private Sub Form_Load()
 With mydata
    .cbSize = Len(mydata)
    .hIcon = Me.Icon
    .hWnd = Me.hWnd
    .szTip = "企业人事管理系统" & vbNullChar
    .uCallbackMessage = WM_MOUSEMOVE
    .uFlags = NIF_MESSAGE Or NIF_ICON Or NIF_TIP
    .uID = 0
 End With
  Shell_NotifyIcon NIM_ADD, mydata
   MDIMain.Show
End Sub
 
Private Sub Form_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)
   Select Case CLng(X)
   Case WM_LBUTTONUP
      If MDIMain.WindowState = vbMinimized Then
       MDIMain.WindowState = frmTray.intLastState
        MDIMain.Show
      End If
      'PopupMenu frmTray.mnuTray
   Case WM_RBUTTONUP
         PopupMenu frmTray.mnuTray
   End Select
End Sub

Private Sub Form_Unload(Cancel As Integer)
   Shell_NotifyIcon NIM_DELETE, mydata

End Sub