dbflatspinedit.pas

(***FlatStyle v4.42.8.0 for DELPHI7 by comerose update***)2007.04.30 更新说明1.修正 TFlatListView 标题的平面显示(

unit DBFlatSpinEdit;
{经过修改的一个控件，ww！}

interface

uses
  Windows, Messages, SysUtils, Classes, Controls, StdCtrls, TFlatEditUnit,
  TFlatSpinEditUnit,DBCtrls,db;

type
  TDBFlatSpinEditFloat = class(TFlatSpinEditFloat)
  private
    FDataLink : TFieldDataLink;
    function  GetField      : TField;
    function  GetDataField  : string;
    procedure SetDataField(const Value: string);
    function  GetDataSource : TDataSource ;
    procedure SetDataSource(Value : TDataSource);
    procedure CMExit(var Message:TCMExit);message CM_Exit;
    procedure EditingChange(Sender: TObject);
    procedure DataChange(sender : TObject);
    procedure UpdateData(sender : TObject);
    procedure ActiveChange(sender : TObject);   
  
  protected
    procedure KeyDown(var Key: Word; Shift: TShiftState); override;
    procedure KeyPress(var Key: Char); override;
    procedure DownClick (Sender: TObject); override;
    procedure UpClick (Sender: TObject); override;
    procedure Change; override;   
  public
    property Field: TField read GetField;
    constructor Create(AOwner: TComponent); override;
    destructor Destroy; override;
  published
    property DataField: string read GetDataField write SetDataField;
    property DataSource: TDataSource read GetDataSource write SetDataSource;
  end;


 TDBFlatSpinEditInteger = class (TFlatSpinEditInteger)
  private
    FDataLink : TFieldDataLink;
    function GetDataField : String;
    function GetDataSource : TDataSource;
    function GetReadOnly : Boolean;
    procedure SetReadOnly (aValue : Boolean);
    procedure SetDataSource (aValue : TDataSource);
    procedure SetDataField (const aValue : String);
    procedure DataChange (Sender : TObject);
    procedure UpdateData(Sender: TObject);
    procedure EditingChange(Sender: TObject);
    procedure CMGetDataLink(var Message: TMessage); message CM_GETDATALINK;
    procedure CMExit (var Message: TCMExit); message CM_EXIT;
    procedure WMCut(var Message: TMessage); message WM_CUT;
    procedure WMPaste(var Message: TMessage); message WM_PASTE;
  protected
    procedure Change; override;
    procedure Notification(AComponent: TComponent; Operation: TOperation);override;
    procedure KeyDown(var Key: Word; Shift: TShiftState); override;
    procedure KeyPress(var Key: Char); override;
    procedure DownClick (Sender: TObject); override;
    procedure UpClick (Sender: TObject); override;
  public
    constructor Create(AOwner: TComponent); override;
    destructor Destroy; override;
  published
    property DataSource : TDataSource read GetDataSource write SetDataSource;
    property DataField: string read GetDataField write SetDataField;
    property ReadOnly: Boolean read GetReadOnly write SetReadOnly default False;
  end;
procedure Register;

implementation

procedure TDBFlatSpinEditFloat.EditingChange(Sender: TObject);
begin
  inherited ReadOnly := not FDataLink.Editing;
end;

function TDBFlatSpinEditFloat.GetDataSource: TDataSource;
begin
  Result := FDataLink.DataSource;
end;

procedure TDBFlatSpinEditFloat.SetDataSource(Value: TDataSource);
begin
  if not (FDataLink.DataSourceFixed and (csLoading in ComponentState)) then
    FDataLink.DataSource := Value;
  if Value <> nil then Value.FreeNotification(Self);
  Enabled := FDataLink.Active and (FDataLink.Field <> nil) and
          not FDataLink.Field.ReadOnly ;
end;

function TDBFlatSpinEditFloat.GetField: TField;
begin
  Result := FDataLink.Field;
end;

function TDBFlatSpinEditFloat.GetDataField: string;
begin
  Result := FDataLink.FieldName;
end;

procedure TDBFlatSpinEditFloat.SetDataField(const Value: string);
begin
  FDataLink.FieldName := Value;
end;

constructor TDBFlatSpinEditFloat.Create(AOwner: TComponent);
begin
  inherited Create(AOwner);
  FDataLink := TFieldDataLink.Create;
  FDataLink.Control := Self;
  FDataLink.OnDataChange := DataChange;
  FDataLink.OnEditingChange := EditingChange;
  FDataLink.OnUpdateData := UpdateData;
  FDataLink.OnActiveChange := ActiveChange;
end;

destructor TDBFlatSpinEditFloat.Destroy;
begin
  FDataLink.Free;
  FDataLink := nil;
  inherited Destroy;
end;

procedure TDBFlatSpinEditFloat.DataChange(sender : TObject);
begin
  if (FDataLink.Field <> nil) and
       ((FDataLink.Field is TFloatField) or (FDataLink.Field is TCurrencyField))  then
    value := FDataLink.Field.AsFloat
  else
    value := 0.00;
end;

procedure TDBFlatSpinEditFloat.UpdateData(sender : TObject);
begin
  if (FDataLink.Field <> nil)  and
       ((FDataLink.Field is TFloatField) or (FDataLink.Field is TCurrencyField))  then
    FDataLink.Field.AsFloat :=  value  ;
end;

procedure TDBFlatSpinEditFloat.ActiveChange(sender : TObject);
begin
  Enabled := FDataLink.Active and (FDataLink.Field <> nil);
end;

procedure TDBFlatSpinEditFloat.CMExit(var Message:TCMExit);
begin
  try
    FDataLink.UpdateRecord;
  except
    SelectAll;
    SetFocus;
    raise;
  end;
   inherited;
end;

procedure TDBFlatSpinEditFloat.KeyDown(var Key: Word; Shift: TShiftState);
begin
  inherited KeyDown(Key, Shift);
  if (Key = VK_DELETE) or ((Key = VK_INSERT) and (ssShift in Shift)) then
    FDataLink.Edit;
end;

procedure TDBFlatSpinEditFloat.KeyPress(var Key: Char);
begin
  inherited KeyPress(Key);
  if (Key in [#32..#255]) and (FDataLink.Field <> nil) and
    not FDataLink.Field.IsValidChar(Key) then
  begin
    MessageBeep(0);
    Key := #0;
  end;
  case Key of
    {^H, ^V, ^X,} #48..#57:          
      FDataLink.Edit;
    #27:                              //esc取消
      begin
        FDataLink.Reset;
        SelectAll;
        Key := #0;
      end;
  end;
end;

procedure TDBFlatSpinEditFloat.Change;
begin
  if FDataLink <> nil then
    FDataLink.Modified;
  inherited Change;
end;

procedure TDBFlatSpinEditFloat.DownClick (Sender: TObject);
begin
  inherited DownClick (Sender);
  FDataLink.Edit;
end;

procedure TDBFlatSpinEditFloat.UpClick (Sender: TObject);
begin
  inherited UpClick (Sender);
  FDataLink.Edit;
end;     

//----------------------   TDBFlatSpinEditInteger 开始--------
     
function TDBFlatSpinEditInteger.GetDataField : String;
begin
  Result := FDataLink.FieldName;
end;

function TDBFlatSpinEditInteger.GetDataSource : TDataSource;
begin
  Result := FDataLink.DataSource;
end;

function TDBFlatSpinEditInteger.GetReadOnly : Boolean;
begin
  Result := FDataLink.ReadOnly;
  inherited ReadOnly := Result;
end;

 
procedure TDBFlatSpinEditInteger.SetReadOnly (aValue : Boolean);
begin
  FDataLink.ReadOnly := aValue;
  inherited ReadOnly := aValue;  
end;

 
procedure TDBFlatSpinEditInteger.SetDataSource (aValue : TDataSource);
begin
  FDataLink.DataSource := aValue;
  if aValue <> nil then aValue.FreeNotification(Self);
end;

 
procedure TDBFlatSpinEditInteger.SetDataField (const aValue : String);
begin
  FDataLink.FieldName := aValue;
end;

 
procedure TDBFlatSpinEditInteger.DataChange (Sender : TObject);
begin
  if FDataLink.Field <> nil then
    begin
      if not (csDesigning in ComponentState) then
        begin
          if (FDataLink.Field.DataType = ftInteger) and (MaxLength = 0) then
            MaxLength := FDataLink.Field.Size;
        end;
      if {FFocused and} FDataLink.CanModify then
        begin
          Value := FDataLink.Field.AsInteger;
        end
      else
        begin
          Value := FDataLink.Field.AsInteger;
        end;
    end
end;
 
procedure TDBFlatSpinEditInteger.UpdateData(Sender: TObject);
begin
  FDataLink.Field.AsInteger := Value; { Value, Text }
end;

 
procedure TDBFlatSpinEditInteger.EditingChange(Sender: TObject);
begin
  inherited ReadOnly := not FDataLink.Editing;
end;

 
procedure TDBFlatSpinEditInteger.WMPaste(var Message: TMessage);
begin
  FDataLink.Edit;
  inherited;
end;

 
procedure TDBFlatSpinEditInteger.WMCut(var Message: TMessage);
begin
  FDataLink.Edit;
  inherited;
end;


procedure TDBFlatSpinEditInteger.Change;
begin
  if FDataLink <> nil then
    FDataLink.Modified;
  inherited Change;
end;


procedure TDBFlatSpinEditInteger.Notification(AComponent: TComponent; Operation: TOperation);
begin
  inherited Notification(AComponent, Operation);
  if (Operation = opRemove) and (FDataLink <> nil) and
    (AComponent = DataSource) then DataSource := nil;
end;

 
procedure TDBFlatSpinEditInteger.CMGetDataLink(var Message: TMessage);
begin
  Message.Result := Integer(FDataLink);
end;     

procedure TDBFlatSpinEditInteger.CMExit(var Message: TCMExit);
begin
  try
    FDataLink.UpdateRecord;
  except
    SelectAll;
    SetFocus;
    raise;
  end;
end;

procedure TDBFlatSpinEditInteger.KeyDown(var Key: Word; Shift: TShiftState);
begin
  inherited KeyDown(Key, Shift);
  if (Key = VK_DELETE) or ((Key = VK_INSERT) and (ssShift in Shift)) then
    FDataLink.Edit;
end;

procedure TDBFlatSpinEditInteger.KeyPress(var Key: Char);
begin
  inherited KeyPress(Key);
  if (Key in [#32..#255]) and (FDataLink.Field <> nil) and
    not FDataLink.Field.IsValidChar(Key) then
  begin
    MessageBeep(0);
    Key := #0;
  end;
  case Key of
    {^H, ^V, ^X,} #48..#57:
      FDataLink.Edit;
    #27:
      begin
        FDataLink.Reset;
        SelectAll;
        Key := #0;
      end;
  end;
end;

procedure TDBFlatSpinEditInteger.DownClick (Sender: TObject);
begin
  inherited DownClick (Sender);
  FDataLink.Edit;
end;

procedure TDBFlatSpinEditInteger.UpClick (Sender: TObject);
begin
  inherited UpClick (Sender);
  FDataLink.Edit;
end;

constructor TDBFlatSpinEditInteger.Create(AOwner: TComponent);
begin
  inherited Create (AOwner);
  inherited ReadOnly := True;
  ControlStyle:=ControlStyle-[csReplicatable];
  FDataLink := TFieldDataLink.Create;
  FDataLink.Control := Self;
  FDataLink.OnDataChange := DataChange;
  FDataLink.OnEditingChange := EditingChange;
  FDataLink.OnUpdateData := UpdateData;
end;

destructor TDBFlatSpinEditInteger.Destroy;
begin
  FDataLink.Free;
  FDataLink := nil;
  inherited Destroy;
end;

//-------     Register--------------
procedure Register;
begin
  RegisterComponents('DBFlatStyle', [TDBFlatSpinEditFloat]);
  RegisterComponents('DBFlatStyle', [TDBFlatSpinEditInteger]);
end;

end.