runtime.s

T-kernel 的extension源代码

/*
 *----------------------------------------------------------------------
 *    T-Kernel / Standard Extension
 *
 *    Copyright (C) 2006 by Ken Sakamura. All rights reserved.
 *    T-Kernel / Standard Extension is distributed 
 *      under the T-License for T-Kernel / Standard Extension.
 *----------------------------------------------------------------------
 *
 *    Version:   1.00.00
 *    Released by T-Engine Forum(http://www.t-engine.org) at 2006/8/11.
 *
 *----------------------------------------------------------------------
 */

/*
 *	@(#)runtime.S (solib) 
 *
 *	Shared object(SO)support library
 *	Run time symbol link entry 
 */

#include <machine.h>

	.text
	.align	2
	.globl	Csym(__so_runtime_resolve)
	.type	Csym(__so_runtime_resolve),@function
	/*
	 *	r0	Target object(DLInfo)
	 *	r1	Relocation table offset
	 *	pr	Return address
	 *	A support in the differenec between SH PICABI and GNU PLT is done already 
	 */
Csym(__so_runtime_resolve):
	mov.l	r2, @-r15
	mov.l	r3, @-r15
	mov.l	r4, @-r15
	mov.l	r5, @-r15
	mov.l	r6, @-r15
	mov.l	r7, @-r15
	mov.l	r12,@-r15
	movt	r3
	mov.l	r3, @-r15
	sts.l	pr, @-r15

	mov	#8, r5
	cmp/gt	r5, r0
	bt	l_1
	mov	r2, r0
l_1:
	mov	r0, r4

	mova	.l_g, r0
	mov.l	.l_g, r5
	add	r5, r0

	mov.l	l_3, r5
	mov.l	@(r0, r5),r5
	jsr	@r5
	mov	r1, r5

	lds.l	@r15+, pr
	mov.l	@r15+, r3
	shar	r3
	mov.l	@r15+, r12
	mov.l	@r15+, r7
	mov.l	@r15+, r6
	mov.l	@r15+, r5
	mov.l	@r15+, r4
	mov.l	@r15+, r3
	jmp	@r0
	mov.l	@r15+, r2

	.align	2
l_3:
	.long   __so_fixup@GOT
.l_g:
	.long	_GLOBAL_OFFSET_TABLE_
	.end