build64.bat

Intel的IPP库的应用例程

@echo off
@rem
@rem Usage: build64.bat  {cl}
@rem

set ARCH=win64
set LINKAGE=dynamic
@rem set LINKAGE=static

@rem
@rem Set-up Micrsoft Platform SDK environment
@rem

set SDK="%ProgramFiles%\Microsoft Platform SDK\setenv.cmd"
if exist %SDK% goto set_sdk_env

set SDK="%ProgramFiles%\Microsoft Platform SDK\setenv.bat"
if not exist %SDK% (
 @echo SDK is not installed!
 exit
)
:set_sdk_env
@call %SDK% /SRV64 /RETAIL

@rem
@rem Set-up compiler environment
@rem Intel Compiler is used by default, but you can use Microsoft Compiler
@rem by specifying cl as command line parameter for this build script
@rem

set ARG=%1

if "%ARG%"=="cl" goto :ms

:default

set COMPILER=icl.exe

for /F "usebackq" %%i in (`dir /ON /B "%ProgramFiles%\Intel\Compiler\C++\10.*"`) do set LASTVERSION=%%i
set TOOL="%ProgramFiles%\Intel\Compiler\C++\%LASTVERSION%\Itanium\Bin\iclvars.bat"
if exist %TOOL% (
@echo Intel C++ Compiler v.%LASTVERSION% for Itanium selected
goto adjust
)


set TOOL="%ProgramFiles%\Intel\Compiler\C++\9.1\Itanium\Bin\iclvars.bat"
if exist %TOOL% goto adjust

set TOOL="%ProgramFiles%\Intel\Compiler\C++\9.0\Itanium\Bin\iclvars.bat"
if exist %TOOL% goto adjust

set TOOL="%ProgramFiles%\Intel\CPP\Compiler80\Itanium\Bin\iclvars.bat"
if exist %TOOL% goto adjust

:ms

set COMPILER=cl.exe

:adjust
@call %TOOL%

@rem
@rem Set-up IPP environment varables (IPPROOT, INCLUDE, LIB, PATH)
@rem

set IPPENV="%IPPROOT%\tools\env\ippenv64.bat"
if exist %IPPENV% goto start

set IPPENV="%ProgramFiles%\Intel\ipp\5.2\itanium\tools\env\ippenv64.bat"
if exist %IPPENV% goto start 

  @echo *************************************************************************
  @echo Intel(R) IPP is not found!
  @echo Please install Intel(R) IPP or set IPPROOT environment variable correctly.
  @echo *************************************************************************
  Exit

:start
@call %IPPENV%

@rem
@rem build sample
@rem

nmake ARCH=%ARCH% clean
nmake ARCH=%ARCH% CC=%COMPILER% LINKAGE=%LINKAGE%