build32.bat

Intel的IPP库的应用例程

@echo on
@rem
@rem Usage: build32.bat  {cl}
@rem

set ARCH=win32
set LINKAGE=dynamic
@rem set LINKAGE=static

@rem
@rem Set-up compiler environment
@rem Intel Compiler is used by default, but you can use Microsoft Compiler
@rem by specifying cl as command line parameter for this build script
@rem

set ARG=%1

if "%ARG%"=="cl" goto ms

:default

set COMPILER=icl.exe

for /F "usebackq" %%i in (`dir /ON /B "%ProgramFiles%\Intel\Compiler\C++\10.*"`) do set LASTVERSION=%%i
set TOOL="%ProgramFiles%\Intel\Compiler\C++\%LASTVERSION%\IA32\Bin\iclvars.bat"
if exist %TOOL% (
@echo Intel C++ Compiler v.%LASTVERSION% for IA32 selected
goto adjust
)


set TOOL="%ProgramFiles%\Intel\Compiler\C++\9.1\IA32\Bin\iclvars.bat"
if exist %TOOL% goto adjust

set TOOL="%ProgramFiles%\Intel\CPP\Compiler80\Ia32\Bin\iclvars.bat"
if exist %TOOL% goto adjust

:ms

set COMPILER=cl.exe

set TOOL="%ProgramFiles%\Microsoft Visual Studio 8\Common7\Tools\vsvars32.bat"
if exist %TOOL%  goto adjust

set TOOL="%ProgramFiles%\Microsoft Visual Studio .NET 2003\Common7\Tools\vsvars32.bat"
if exist %TOOL%  goto adjust

set TOOL="%ProgramFiles%\Microsoft Visual Studio .NET\Common7\Tools\vsvars32.bat"
if exist %TOOL%   goto adjust

:adjust
@call %TOOL%

@rem
@rem Set-up IPP environment varables (IPPROOT, INCLUDE, LIB, PATH)
@rem

set IPPENV="%IPPROOT%\tools\env\ippenv.bat"
if exist %IPPENV% goto start

set IPPENV="%ProgramFiles%\Intel\ipp\5.2\ia32\tools\env\ippenv.bat"
if exist %IPPENV% goto start 

@rem  @echo *************************************************************************
@rem  @echo Intel(R) IPP is not found!
@rem  @echo Please install Intel(R) IPP or set IPPROOT environment variable correctly.
@rem  @echo *************************************************************************
@rem  Exit

:start
@call %IPPENV%

@rem
@rem build sample
@rem

nmake ARCH=%ARCH% clean
nmake ARCH=%ARCH% CC=%COMPILER% LINKAGE=%LINKAGE%