function.asp

简简单单的客户管理系统-This a simple customer management systems

<%

'// 数据库操作

Function DB(Byval Sqlstr,Byval DBType)
	'Response.Write SqlStr & "<BR>"
	Select Case DBType
	Case 0
		Conn.Execute(Sqlstr)
	Case 1
		Set DB = Conn.Execute(Sqlstr)
	Case 2
		Set DB = Server.CreateObject("Adodb.Recordset")
		DB.Open Sqlstr,Conn,1,1
	Case 3
		Set DB = Server.CreateObject("Adodb.Recordset")
		DB.Open Sqlstr,Conn,1,3
	End Select
End Function

'// 分页函数

Function PageList(Byval PageCount,Byval Page,Byval RecordCount,Byval PageSize,Byval Url)
	RecordCount = int(RecordCount)
	PageSize = int(PageSize)
	PageCount = int(PageCount)
	Page = int(Page)
	
	dim loopnum1,loopnum2
	loopnum1 = 4	' 前面数量
	loopnum2 = 5	' 后面数量
	
	Tempstr = "{<<} {循环} {>>}"
	Tempstr = replace(Tempstr, "{总页数}", PageCount)
	Tempstr = replace(Tempstr, "{总条数}", RecordCount)
	Tempstr = replace(Tempstr, "{每页条数}", PageSize)
	Tempstr = replace(Tempstr, "{当前页}", Page)
	Tempstr = replace(Tempstr, "{首页}", "<a href=" & replace(Url,"{p}",1) & " class='page'>首页</a>")
	Tempstr = replace(Tempstr, "{<<}", "<a href=" & replace(Url,"{p}",1) & " class='page'><<</a>")
	Tempstr = replace(Tempstr, "{尾页}", "<a href=" & replace(Url,"{p}",PageCount) & " class='page'>尾页</a>")
	Tempstr = replace(Tempstr, "{>>}", "<a href=" & replace(Url,"{p}",PageCount) & " class='page'>>></a>")
	if Page > 1 then
		Tempstr = replace(Tempstr, "{上一页}", "<a href=" & replace(Url,"{p}",Page-1) & " class='page'>上一页</a>")
		Tempstr = replace(Tempstr, "{<}", "<a href=" & replace(Url,"{p}",Page-1) & " class='page'><</a>")
	else
		Tempstr = replace(Tempstr, "{上一页}", "上一页")
		Tempstr = replace(Tempstr, "{<}", "<span class='page'><</span>")
	end if
	if Page < PageCount then
		Tempstr = replace(Tempstr, "{下一页}", "<a href=" & replace(Url,"{p}",Page+1) & " class='page'>下一页</a>")
		Tempstr = replace(Tempstr, "{>}", "<a href=" & replace(Url,"{p}",Page+1) & " class='page'>></a>")
	else
		Tempstr = replace(Tempstr, "{下一页}", "下一页")
		Tempstr = replace(Tempstr, "{>}", "<span class='page'>></span>")
	end if
	
	dim jumpurl,i,j
	jumpurl = "<select name='jumpurl' onchange='location.href=this.options[this.selectedIndex].value;'>"
	for i = 1 to PageCount
		if i = Page then
			jumpurl = jumpurl & vbcrlf & "<option value='" & replace(Url,"{p}",i) & "' selected>" & i & "</option>"
		else
			jumpurl = jumpurl & vbcrlf & "<option value='" & replace(Url,"{p}",i) & "'>" & i & "</option>"
		end if
	next
	jumpurl = jumpurl & "</select>"
	Tempstr = replace(Tempstr, "{跳转}", jumpurl)
	
	' 循环
	dim loopurl
	i = Page - loopnum1
	j = Page + loopnum2
	if i < 1 then
		j = j + (1-i)
		i = 1
	end if
	if j > PageCount then 
		i = i + (PageCount-j)
		j = PageCount
		if i < 1 then i = 1
	end if
	dim m
	for m=i to j
		if m = Page then
			loopurl = loopurl & " <a href=" & replace(Url,"{p}",m) & " class='pagein'>" & m & "</a>"
		else
			loopurl = loopurl & " <a href=" & replace(Url,"{p}",m) & " class='page'>" & m & "</a>"
		end if
	next
	Tempstr = replace(Tempstr, "{循环}", loopurl)
	
	PageList = Tempstr
end function


'// 提示信息
Function Alert(Byval Msgstr,Byval Url)

	If Len(Url) > 0 Then
		If Conn.State = 1 Then Conn.Close ' 关闭数据库链接
		If Len(Msgstr) > 0 Then
			Response.Write "<Script>alert('" & Msgstr & "');</Script>" '// 提示
		End If
		Response.Write "<Script>location.href='" & Url & "';</Script>" '// 跳转
		Response.End
	Else
		If Len(Msgstr) > 0 Then
			Response.Write "<Script>alert('" & Msgstr & "');</Script>" '// 提示
		End if
	End If
End Function

%>