module1.bas

电子书“Visual Basic 6 网络编程实例教程.rar”

Attribute VB_Name = "Module1"
Option Explicit

Public Declare Function InternetGetConnectedState _
   Lib "wininet.dll" (ByRef dwflags As Long, _
   ByVal dwReserved As Long) As Long

'本系统使用调制解调器与因特网相连
Public Const INTERNET_CONNECTION_MODEM As Long = &H1

'本系统通过LAN与因特网相连
Public Const INTERNET_CONNECTION_LAN As Long = &H2

'本系统使用proxy代理服务器与因特网相连
Public Const INTERNET_CONNECTION_PROXY As Long = &H4

'未使用
Public Const INTERNET_CONNECTION_MODEM_BUSY As Long = &H8

Public Const INTERNET_RAS_INSTALLED As Long = &H10
Public Const INTERNET_CONNECTION_OFFLINE As Long = &H20
Public Const INTERNET_CONNECTION_CONFIGURED As Long = &H40

Public Function IsNetConnectViaLAN() As Boolean
   Dim dwflags As Long
  '向API函数传递一个空变量，此时，
  '函数会返回有关连接的标志信息
   Call InternetGetConnectedState(dwflags, 0&)
  '如果是通过LAN的连接，则返回True
   IsNetConnectViaLAN = dwflags And INTERNET_CONNECTION_LAN
End Function

Public Function IsNetConnectViaModem() As Boolean
   Dim dwflags As Long
  '向API函数传递一个空变量，此时，
  '函数会返回有关连接的标志信息
   Call InternetGetConnectedState(dwflags, 0&)
  '如果是通过调制解调器的连接，则返回True
   IsNetConnectViaModem = dwflags And INTERNET_CONNECTION_MODEM
End Function

Public Function IsNetConnectViaProxy() As Boolean
   Dim dwflags As Long
 '向API函数传递一个空变量，此时，
  '函数会返回有关连接的标志信息
   Call InternetGetConnectedState(dwflags, 0&)
  '如果是通过Proxy代理服务器的连接，则返回True
   IsNetConnectViaProxy = dwflags And INTERNET_CONNECTION_PROXY
End Function

Public Function IsNetConnectOnline() As Boolean
  '这里不需要标志值，
  '如果有其它类型的连接，则返回True
   IsNetConnectOnline = InternetGetConnectedState(0&, 0&)
End Function

Public Function IsNetRASInstalled() As Boolean
   Dim dwflags As Long
  '向API函数传递一个空变量，此时，
  '函数会返回有关连接的标志信息
   Call InternetGetConnectedState(dwflags, 0&)
  '如果已安装了RAS，则返回True
   IsNetRASInstalled = dwflags And INTERNET_RAS_INSTALLED
End Function

Public Function GetNetConnectString() As String
   Dim dwflags As Long
   Dim msg As String
  '显示的信息字符串
   If InternetGetConnectedState(dwflags, 0&) Then
      If dwflags And INTERNET_CONNECTION_CONFIGURED Then
         msg = msg & "系统配置了网络连接" & vbCrLf
      End If
      If dwflags And INTERNET_CONNECTION_LAN Then
         msg = msg & "系统通过局域网与因特网相连接"
      End If
      If dwflags And INTERNET_CONNECTION_PROXY Then
            msg = msg & "并使用了Proxy代理服务"
      Else: msg = msg & "."
      End If
      If dwflags And INTERNET_CONNECTION_MODEM Then
         msg = msg & "系统使用调制解调器与因特网相连接"
      End If
      If dwflags And INTERNET_CONNECTION_OFFLINE Then
         msg = msg & "系统当前处于离线状态"
      End If
      If dwflags And INTERNET_CONNECTION_MODEM_BUSY Then
         msg = msg & "系统的调制解调器未连接到因特网"
      End If
      If dwflags And INTERNET_RAS_INSTALLED Then
         msg = msg & "本系统安装了远程访问服务"
      End If
   Else
      msg = "当前未与因特网相连"
   End If
   GetNetConnectString = msg
End Function