module1.bas

一个比较适合做毕业设计的程序

Attribute VB_Name = "ModuleMain"
Option Explicit
Public UserType As Boolean '如果是true那么是超级用户
Public cn As ADODB.Connection '公共连接对象
Public searchSQL As String
Public IsAdmin As Boolean '判断是否为系统管理员登陆

Public Declare Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long
Public Declare Function ShellExecute Lib "shell32.dll" Alias "ShellExecuteA" (ByVal hwnd As Long, ByVal lpOperation As String, ByVal lpFile As String, ByVal lpParameters As String, ByVal lpDirectory As String, ByVal nShowCmd As Long) As Long

'创建一个连接
Public Function MakeConnection() As String
    Set cn = New ADODB.Connection
    On Error GoTo connecterr
    With cn
        .CursorLocation = adUseClient
     
        '.ConnectionString = " provide=sqloledb:datasourse=学籍.mdb:DefaultDir=" & CheckPath(App.path) & ";ID=;PWD=;PASSWORD=197967yh"
        .ConnectionString = "DRIVER={Microsoft Access Driver (*.mdb)};" & _
                   "DBQ=db5.MDB;" & _
                   "DefaultDir=" & CheckPath(App.path) & ";" & _
                   "UID=;PWD=;"  '数据库密码 ，防止被人用其它软件打开数据库
        .Open
    
    End With
    MakeConnection = "OK"
    Exit Function
connecterr:
    Dim i As Integer
    Dim sError As String
    If cn.Errors.Count > 0 Then
        For i = 0 To cn.Errors.Count - 1
            sError = sError & cn.Errors(i).Number & ":" & cn.Errors(i).Description & vbCrLf
        Next i
    End If
    MakeConnection = sError
    Exit Function
End Function

Public Function AnalyseStdNum(Ustdnum As String, Lstdnum As String) As Integer
    '98076030  “98”是指哪一届；“07”是指市校的代号；
    '“6”是指分校的代号； “0”是指班级号；“30”是指学号
   
    If Len(Ustdnum) <> 8 Or Len(Lstdnum) <> 8 Then
        AnalyseStdNum = -1
    Else
        If Ustdnum = Lstdnum Then '单一学号的查找
            AnalyseStdNum = 8
            Exit Function
        ElseIf Left$(Ustdnum, 6) = Left$(Lstdnum, 6) Then '班级单位查找
            AnalyseStdNum = 6
            Exit Function
        ElseIf Left$(Ustdnum, 5) = Left$(Lstdnum, 5) Then '分校单位查找
            AnalyseStdNum = 5
            Exit Function
        ElseIf Left$(Ustdnum, 4) = Left$(Lstdnum, 4) Then '市校单位查找
            AnalyseStdNum = 4
            Exit Function
        ElseIf Left$(Ustdnum, 2) = Left$(Lstdnum, 2) Then '同届学生查找
            AnalyseStdNum = 2
            Exit Function
        Else
            AnalyseStdNum = 0
        End If
    End If
End Function

Public Sub MakeCenter(frm As Form) '使窗口显示在屏幕中央
    Dim intx2 As Integer, inty2 As Integer
    intx2 = (Screen.Width - frm.Width) / 2
    inty2 = (Screen.Height - frm.Height) / 2
    frm.Left = intx2
    frm.Top = inty2
End Sub

Public Function CheckPath(path As String) As String '检测数据库路径是否以"\"结束
    If Right$(path, 1) = "\" Then
        CheckPath = path
    Else
        CheckPath = path & "\"
    End If
End Function

'程序入口
Sub Main()
    searchSQL = "SELECT * FROM 学生"
    UserType = False
    IsAdmin = False
    Load DlgLogin '载入登陆对话框
    DlgLogin.Show
End Sub