orderroom.cls

酒店管理系统 基于VB和SQL的一个很好的程序 可以实现酒店的日常管理工作

VERSION 1.0 CLASS
BEGIN
  MultiUse = -1  'True
  Persistable = 0  'NotPersistable
  DataBindingBehavior = 0  'vbNone
  DataSourceBehavior  = 0  'vbNone
  MTSTransactionMode  = 0  'NotAnMTSObject
END
Attribute VB_Name = "OrderRoom"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = True
Attribute VB_PredeclaredId = False
Attribute VB_Exposed = False
'1 OrderId int  预定编号，作为表OrderRoom的主键
'2 CustId Varchar 40 客户编号
'3 FirstPay  int  押金
'4 OrderDate date  预定日期
'5 UserName  varchar(40)  经办人的用户名

Public OrderId As Integer
Public CustId As String
Public FirstPay As Single
Public OrderDate As String
Public UserName As String

Public Sub Init()
  OrderId = 0
  CustId = ""
  FirstPay = 0
  InDate = ""
  OrderDate = ""
  UserName = ""
End Sub

'生成新的预定编号，规则是最大的编号加1
Public Function CreateNewId() As Long
  Dim rs As New ADODB.Recordset
  
  '设置SELECT语句
  SqlStmt = "Select Max(OrderId) FROM OrderRoom"
  '将结果集读取到rs中
  Set rs = QueryExt(SqlStmt)

  If IsNull(rs.Fields(0)) Then
    '如果结果集为空，则初始化
    CreateNewId = 1
  Else
    CreateNewId = rs.Fields(0) + 1
  End If
End Function

'取消预定
Public Sub Delete(ByVal TmpId As Integer)
  '取消预定信息的同时删除其详细预定信息
  SqlStmt = "DELETE FROM OrderRoom WHERE OrderId=" + Trim(TmpId)
  SQLExt (SqlStmt)
End Sub

Public Function GetInfo(ByVal TmpId As Integer) As Boolean
  Dim rs As New ADODB.Recordset
  
  If TmpId <= 0 Then
    Init
    GetInfo = False
    Exit Function
  End If
  '设置SELECT语句
  SqlStmt = "SELECT * FROM OrderRoom WHERE OrderId=" + Trim(TmpId)
  '将结果集读取到rs中
  Set rs = QueryExt(SqlStmt)

  If rs.EOF = True Then
    '如果结果集为空，则初始化
    Init
    GetInfo = False
  Else
    '将结果集中的数据赋值到成员变量中
    OrderId = rs.Fields(0)
    If IsNull(rs.Fields(1)) Then
      CustId = ""
    Else
      CustId = rs.Fields(1)
    End If
    If IsNull(rs.Fields(2)) Then
      FirstPay = 0
    Else
      FirstPay = rs.Fields(2)
    End If

    If IsNull(rs.Fields(3)) Then
      OrderDate = ""
    Else
      OrderDate = rs.Fields(3)
    End If
    UserName = Trim(rs.Fields(4))
    
    GetInfo = True
  End If
End Function

'插入新的记录编号，其他记录的保存为update
Public Sub Insert()
  SqlStmt = "INSERT INTO OrderRoom(OrderId, UserName) VALUES(" _
          + Trim(OrderId) + ",'" + Trim(UserName) + "')"
  SQLExt (SqlStmt)
End Sub

'更新预定信息
Public Sub Update(ByVal TmpId As Integer)
  SqlStmt = "UPDATE OrderRoom SET CustId='" + Trim(CustId) + "', FirstPay=" _
          + Trim(FirstPay) + ", OrderDate='" + Trim(OrderDate) _
          + "',UserName='" + Trim(UserName) + "' WHERE OrderId=" + Trim(TmpId)
  SQLExt (SqlStmt)
End Sub