logic_board.asp

学习管理 校友录有关的系统 本人学习的结果 与大家共享

<%
''===================================================================
'= ASP FILENAME	: /inc/logic/logic_board.asp
'= CREATED TIME : 2006-5-1
'= LAST MODIFIED: 2006-5-1
'= VERSION INFO : CCASP Framework Ver 2.0.1 ALL RIGHTS RESERVED BY www.cclinux.com
'= DESCRIPTION  : 用户留言处理逻辑
'= Change Log:
'==================================================================='
%>

<%
'== top/comm
Const CONST_BOARD_TOP = 1
Const CONST_BOARD_COMM = 0

''===================================================================
'= Function    : GetBoardsLogic()
'= Time		   : Created At 2006-5-5
'= Input	   : strWhere : 符合条件
'= Return      : boolean
'= Description : 取留言记录集
'==================================================================='
Function GetBoardsLogic(strWhere)
	GBL_objPubDB.Clear()
	GBL_objPubDB.AllSQL = "SELECT BOARD_ID,BOARD_TITLE,BOARD_CONTENT,BOARD_FACE,BOARD_TIME,BOARD_USER_ID,BOARD_STATUS,USER_ACCOUNT,USER_REALNAME FROM CLASS_USER,CLASS_BOARD WHERE BOARD_USER_ID=USER_ID " & strWhere & " ORDER BY BOARD_STATUS DESC,BOARD_ID DESC"
	If Not GBL_objPubDB.SQLRSExecute() Then
		GetBoardsLogic = False
		Exit Function
	End If
	GetBoardsLogic = True
End Function

''===================================================================
'= Function    : GetBoardLogic()
'= Time		   : Created At 2006-5-14
'= Input	   : intBoardId : 留言 id
'= Return      : boolean
'= Description : 取留言记录集
'==================================================================='
Function GetBoardLogic(intBoardId)
	GBL_objPubDB.Clear()
	GBL_objPubDB.AllSQL = "SELECT BOARD_ID,BOARD_TITLE,BOARD_CONTENT,BOARD_FACE,BOARD_TIME,BOARD_USER_ID,BOARD_STATUS,USER_ACCOUNT,USER_REALNAME FROM CLASS_USER,CLASS_BOARD WHERE BOARD_USER_ID=USER_ID AND BOARD_ID=" & intBoardId & " ORDER BY BOARD_STATUS DESC,BOARD_ID DESC"
	If Not GBL_objPubDB.SQLRSExecute() Then
		GetBoardLogic = False
		Exit Function
	End If
	GetBoardLogic = True
End Function

''===================================================================
'= Function    : RemoveBoardsLogic()
'= Time		   : Created At 2006-5-5
'= Input	   : strWhere : 符合条件
'= Return      : boolean
'= Description : 删除留言
'==================================================================='
Function RemoveBoardsLogic(strWhere)
	GBL_objPubDB.Clear()
	GBL_objPubDB.TableName = "CLASS_BOARD"
	GBL_objPubDB.SQLType = "DELETE"
	GBL_objPubDB.Where = " 1=1 " & strWhere
	If Not GBL_objPubDB.SQLRSExecute() Then
		RemoveBoardsLogic = False
		Exit Function
	End If
	RemoveBoardsLogic = True
End Function

''===================================================================
'= Function    : TopBoardsLogic()
'= Time		   : Created At 2006-5-5
'= Input	   : strWhere : 符合条件
'= Input	   : intFlag : 置顶状态:1--top 0--untop
'= Return      : boolean
'= Description : Top/Untop留言
'==================================================================='
Function TopBoardsLogic(strWhere,intFlag)
	GBL_objPubDB.Clear()
	GBL_objPubDB.TableName = "CLASS_BOARD"
	GBL_objPubDB.SQLType = "UPDATE"
	GBL_objPubDB.AddField "BOARD_STATUS",intFlag
	GBL_objPubDB.Where = " 1=1 " & strWhere
	If Not GBL_objPubDB.SQLRSExecute() Then
		TopBoardsLogic = False
		Exit Function
	End If
	TopBoardsLogic = True
End Function

''===================================================================
'= Function    : GetBoardStatusLogic()
'= Time		   : Created At 2006-5-5
'= Input	   : intStatus : 置顶状态:1--top 0--untop
'= Return      : 置顶状态中文含义
'= Description : 取留言状态
'==================================================================='
Function GetBoardStatusLogic(intStatus)
	If intStatus = CONST_BOARD_COMM Then
		GetBoardStatusLogic = "普通"
	Else
		GetBoardStatusLogic = "置顶"
	End If
End Function

''===================================================================
'= Function    : SaveBoardLogic
'= Time		   : Created At 2006-5-14
'= Input	   : objFormData : 表单数据
'= Return      : 
'= Description : 保存用户留言
'==================================================================='
Function SaveBoardLogic(intUserId,strWhere,objFormData)	
	GBL_objPubDB.Clear()
	GBL_objPubDB.TableName = "CLASS_BOARD"
	If strWhere <> "" Then
		GBL_objPubDB.SQLType = "UPDATE"
	Else
		GBL_objPubDB.SQLType = "INSERT"
		GBL_objPubDB.AddField "BOARD_USER_ID",intUserId
	End If
	GBL_objPubDB.AddField "BOARD_TITLE",objFormData.Item("Title")
	GBL_objPubDB.AddField "BOARD_FACE",objFormData.Item("SmileFace")
	GBL_objPubDB.AddField "BOARD_CONTENT",objFormData.Item("Content")
	GBL_objPubDB.AddField "BOARD_TIME",Now()
	GBL_objPubDB.AddField "BOARD_RE_TIME",Now()
	GBL_objPubDB.AddField "BOARD_TIME_LAST",Now()
	If strWhere <> "" Then
		GBL_objPubDB.Where = " 1=1 " & strWhere
	End If
	If Not GBL_objPubDB.SQLExecute() Then
		SaveBoardLogic = False
		Exit Function
	End If

	SaveBoardLogic = True
End Function
%>