logic_album.asp

学习管理 校友录有关的系统 本人学习的结果 与大家共享

<%
''===================================================================
'= ASP FILENAME	: /inc/logic/logic_album.asp
'= CREATED TIME : 2006-5-1
'= LAST MODIFIED: 2006-5-1
'= VERSION INFO : CCASP Framework Ver 2.0.1 ALL RIGHTS RESERVED BY www.cclinux.com
'= DESCRIPTION  : 用户相册处理逻辑
'= Change Log:
'==================================================================='
%>

<%
'== 常/变量定义
Const CONST_ALBUM_UP_STATUS = 0
Const CONST_ALBUM_PASTE_STATUS = 10

''===================================================================
'= Function    : GetAlbumsLogic()
'= Time		   : Created At 2006-5-5
'= Input	   : strWhere : 查询条件
'= Return      : boolean
'= Description : 取相册记录集
'==================================================================='
Function GetAlbumsLogic(strWhere)
	GBL_objPubDB.Clear()
	If Instr(strWhere,"ORDER BY") > 0 Then
		GBL_objPubDB.AllSQL = "SELECT USER_ACCOUNT,USER_REALNAME,ALBUM_STATUS,ALBUM_TITLE,ALBUM_ID,ALBUM_IMG_FILE,ALBUM_HITS,ALBUM_TYPE,ALBUM_REVIEW_NUM,ALBUM_ADD_TIME FROM CLASS_USER,CLASS_ALBUM WHERE ALBUM_OWNER_ID=USER_ID " & strWhere 
	Else
	GBL_objPubDB.AllSQL = "SELECT USER_ACCOUNT,USER_REALNAME,ALBUM_STATUS,ALBUM_TITLE,ALBUM_ID,ALBUM_IMG_FILE,ALBUM_HITS,ALBUM_TYPE,ALBUM_REVIEW_NUM,ALBUM_ADD_TIME FROM CLASS_USER,CLASS_ALBUM WHERE ALBUM_OWNER_ID=USER_ID " & strWhere & " ORDER BY ALBUM_ID DESC"
	End If
	If Not GBL_objPubDB.SQLRSExecute() Then
		GetAlbumsLogic = False
		Exit Function
	End If
	GetAlbumsLogic = True
End Function

''===================================================================
'= Function    : GetAlbumReviewsLogic()
'= Time		   : Created At 2006-5-5
'= Input	   : strWhere : 查询条件
'= Return      : boolean
'= Description : 取相册评论记录集
'==================================================================='
Function GetAlbumReviewsLogic(strWhere)
	GBL_objPubDB.Clear()
	GBL_objPubDB.AllSQL = "SELECT USER_ACCOUNT,USER_ID,USER_REALNAME,ALBUM_REVIEW_ID,ALBUM_REVIEW_OWNER_ID,ALBUM_REVIEW_PHOTO_ID,ALBUM_REVIEW_CONTENT,ALBUM_REVIEW_ADD_TIME FROM CLASS_USER,CLASS_ALBUM_REVIEW WHERE ALBUM_REVIEW_OWNER_ID=USER_ID " & strWhere & " ORDER BY ALBUM_REVIEW_ID DESC"
	If Not GBL_objPubDB.SQLRSExecute() Then
		GetAlbumReviewsLogic = False
		Exit Function
	End If
	GetAlbumReviewsLogic = True
End Function

''===================================================================
'= Function    : GetAlbumLogic()
'= Time		   : Created At 2006-5-5
'= Input	   : intAlbumId : 相册ID
'= Return      : boolean
'= Description : 取相册
'==================================================================='
Function GetAlbumLogic(intAlbumId)
	GBL_objPubDB.Clear()
	GBL_objPubDB.AllSQL = "SELECT USER_ACCOUNT,USER_ID,USER_REALNAME,ALBUM_STATUS,ALBUM_TITLE,ALBUM_ID,ALBUM_IMG_FILE,ALBUM_HITS,ALBUM_TYPE,ALBUM_REVIEW_NUM,ALBUM_ADD_TIME FROM CLASS_USER,CLASS_ALBUM WHERE ALBUM_OWNER_ID=USER_ID AND ALBUM_ID=" & intAlbumId
	If Not GBL_objPubDB.SQLRSExecute() Then
		GetAlbumLogic = False
		Exit Function
	End If
	GetAlbumLogic = True
End Function

''===================================================================
'= Function    : RemoveAlbumsLogic()
'= Time		   : Created At 2006-5-5
'= Input	   : strWhere : 相册删除条件
'= Return      : boolean
'= Description : 删除相册
'==================================================================='
Function RemoveAlbumsLogic(strWhere)
	Dim strSql

	'== 删除相片评论
	strSql = " AND ALBUM_REVIEW_PHOTO_ID IN (SELECT ALBUM_ID FROM CLASS_ALBUM WHERE 1=1 " & strWhere & ")"
	If Not RemoveAlbumReviewsLogic(strSql,0) Then
		RemoveAlbumsLogic = False
		Exit Function
	End If
	
	'== 删除图片文件
	GBL_objPubDB.Clear()
	GBL_objPubDB.TableName = "CLASS_ALBUM"
	GBL_objPubDB.SQLType = "SELECT"
	GBL_objPubDB.AddField  "ALBUM_IMG_FILE",""
	GBL_objPubDB.Where = " ALBUM_STATUS=" & CONST_ALBUM_UP_STATUS & " " & strWhere
	If Not GBL_objPubDB.SQLRSExecute() Then
		RemoveAlbumsLogic = False
		Exit Function
	End If
	While Not GBL_objPubDB.objPubRS.Eof
		Call fsoDeleteFile(GBL_strHomeURL & GBL_strImgAlbum & GBL_objPubDB.objPubRS("ALBUM_IMG_FILE"))
		Response.Write GBL_strHomeURL & GBL_strImgAlbum & GBL_objPubDB.objPubRS("ALBUM_IMG_FILE")
		GBL_objPubDB.objPubRS.MoveNext
	Wend

	'== 删除相册记录
	GBL_objPubDB.Clear()
	GBL_objPubDB.TableName = "CLASS_ALBUM"
	GBL_objPubDB.SQLType = "DELETE"
	GBL_objPubDB.Where = " 1=1 " & strWhere
	If Not GBL_objPubDB.SQLExecute() Then
		RemoveAlbumsLogic = False
		Exit Function
	End If

	RemoveAlbumsLogic = True
End Function
''===================================================================
'= Function    : StatisticsAlbumReviewNums()
'= Time		   : Created At 2006-5-7
'= Input	   : strWhere : 符合条件
'= Return      : boolean
'= Description : 重新统计相册的评论数
'==================================================================='
Function StatisticsAlbumReviewNums(strWhere)
	Dim intNum,arrTmp,i,strIds

	'== 取得删除评论所涉及到的相片及其评论数
	GBL_objPubDB.Clear()
	GBL_objPubDB.AllSQL = "SELECT ALBUM_REVIEW_PHOTO_ID,COUNT(ALBUM_REVIEW_ID) FROM CLASS_ALBUM_REVIEW,CLASS_ALBUM WHERE ALBUM_ID=ALBUM_REVIEW_PHOTO_ID AND 1=1 " & strWhere & "  GROUP BY ALBUM_REVIEW_PHOTO_ID" 
	If Not GBL_objPubDB.SQLRSExecute() Then
		StatisticsAlbumReviewNums = False
		Exit Function
	End If
	intNum = GBL_objPubDB.intRsNum

	If intNum > 0 Then
		arrTmp = GBL_objPubDB.objPubRS.GetRows(-1)
		'== 更新相片评论数
		For i = 0 To intNum - 1
			GBL_objPubDB.Clear()
			GBL_objPubDB.AllSQL = "UPDATE CLASS_ALBUM SET ALBUM_REVIEW_NUM=" & arrTmp(1,i) & " WHERE ALBUM_ID=" & arrTmp(0,i)
			If Not GBL_objPubDB.SQLExecute() Then
				StatisticsAlbumReviewNums = False
				Exit Function
			End If
		Next
	End If

	If IsArray(arrTmp) Then Erase arrTmp

	StatisticsAlbumReviewNums = True
End Function

''===================================================================
'= Function    : RemoveAlbumReviewsLogic()
'= Time		   : Created At 2006-5-5
'= Input	   : strWhere : 符合条件
'= Input	   : intAlbumId : 若存在且大于0,则仅对该相片重新统计评论数,若为0则不统计
'= Return      : boolean
'= Description : 删除相册评论
'==================================================================='
Function RemoveAlbumReviewsLogic(strWhere,intAlbumId)
	'== 删除记录
	GBL_objPubDB.Clear()
	GBL_objPubDB.TableName = "CLASS_ALBUM_REVIEW"
	GBL_objPubDB.SQLType = "DELETE"
	GBL_objPubDB.Where = " 1=1 " & strWhere
	If Not GBL_objPubDB.SQLExecute() Then
		RemoveAlbumReviewsLogic = False
		Exit Function
	End If

	'== 更新相册评论数
	If IsNumeric(intAlbumId) And intAlbumId > 0 Then
		If Not StatisticsAlbumReviewNums(" AND ALBUM_ID=" &intAlbumId) Then
			RemoveAlbumReviewsLogic = False
			Exit Function
		End If
	ElseIf intAlbumId = "" Then
		If Not StatisticsAlbumReviewNums("") Then
			RemoveAlbumReviewsLogic = False
			Exit Function
		End If
	End If

	RemoveAlbumReviewsLogic = True
End Function

''===================================================================
'= Function    : GetAlbumImgLogic()
'= Time		   : Created At 2006-5-5
'= Input	   : strImg : 图片文件记录
'= Input	   : strStatus : 图片文件状态(0--本地文件 10--网络文件)
'= Return      : 图片文件地址
'= Description : 取图片文件地址
'==================================================================='
Function GetAlbumImgLogic(strImg,strStatus)
	If strStatus = 10 Then
		GetAlbumImgLogic = strImg
	Else
		GetAlbumImgLogic = GBL_strHomeURL & GBL_strImgAlbum & strImg 
	End If
End Function

''===================================================================
'= Function    : UpLoadAlbumFileLogic()
'= Time		   : Created At 2006-5-5
'= Input	   : strFormName : 文件提交表单名
'= Input	   : strPicName : 图片文件名
'= Input	   : objDataForm : 表单数据
'= Return      : boolean
'= Description : 上传图片文件
'==================================================================='
Function UpLoadAlbumFileLogic(strFormName,ByRef strPicName,ByRef objFormData)
	Dim claUpLoad,objFileUp,iCount,strUpFilePath,intFileMaxSize,strFileType,intNameSet
	Dim intTypeFlag,strAddInfo
	'== 设置文件类型
	strFileType = GBL_strAlbumFileType