cclienttypes.cls

对客户管理的系统 运行相应EXE文件前

VERSION 1.0 CLASS
BEGIN
  MultiUse = -1  'True
  Persistable = 0  'NotPersistable
  DataBindingBehavior = 0  'vbNone
  DataSourceBehavior  = 0  'vbNone
  MTSTransactionMode  = 0  'NotAnMTSObject
END
Attribute VB_Name = "CTypes"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = True
Attribute VB_PredeclaredId = False
Attribute VB_Exposed = True
Option Explicit

Private mCol As Collection


Public Sub Add(objType As CType)
  mCol.Add objType, "A" & objType.ID
 
End Sub

Public Property Get Item(vntIndexKey As Variant) As CType
  Set Item = mCol(vntIndexKey)
End Property

Public Property Get Count() As Long
  Count = mCol.Count
End Property

Public Sub Remove(vntIndexKey As Variant)
  mCol.Remove vntIndexKey
End Sub

Public Property Get NewEnum() As IUnknown
  
  Set NewEnum = mCol.[_NewEnum]
End Property


Public Sub Clear()
  
  Dim i As Long
  For i = mCol.Count To 1 Step -1
    mCol.Remove i
  Next i
End Sub

Private Sub Class_Initialize()
  Set mCol = New Collection
End Sub

Private Sub Class_Terminate()
  Set mCol = Nothing
End Sub


Public Function Find(Optional lngID As Long = 0, _
                     Optional lngSuperID As Long = -1) As CTypes
  
  Dim strSQL As String
  
  
  strSQL = "Select * from ClientType where "
  If lngID <> 0 Then strSQL = strSQL & "TypeID=" & lngID & " and "
  If lngSuperID <> -1 Then

      strSQL = strSQL & "SuperID=" & lngSuperID & " and "

  End If
  strSQL = strSQL & "TypeID>0"
  
 
  Me.Clear
  
  Dim rs As Recordset
  Set rs = g_Conn.Execute(strSQL)
  
  
  Dim i As Long
  Dim objType As CType
  For i = 1 To rs.RecordCount
    Set objType = New CType
    With objType
      .ID = rs("TypeID").Value
      .TypeName = Trim(rs("TypeName").Value)
      .SuperID = IIf(IsNull(rs("SuperID").Value), 0, rs("SuperID").Value)
    End With
    Me.Add objType
    Set objType = Nothing
    rs.MoveNext
  Next i
  
  Set rs = Nothing
  Set Find = Me
End Function